5

簡単な手順 (クラスのメソッドではありません) 内でデータベース接続オブジェクトをプログラムで作成しています。

mydb:= TUniConnection.Create(nil);
mydb.Database:= knowledge_db_name;
mydb.LoginPrompt:= False;
mydb.Username:= aaa;
mydb.Password:= bbb;

ここで、他の手順でエラーと切断を処理する必要があります。私がやろうとすると：

mydb.OnError:= OnConnectionError;
mydb.OnConnectionLost:= OnConnectionLost;

コンパイラが教えてくれる

[DCC Error] test.pas(373): E2009 Incompatible types: 'method pointer and regular procedure'

どうすればこれを回避できますか? イベント プロシージャの定義は次のとおりです。

procedure OnConnectionError(Sender: TObject; E: EDAError; var Fail: Boolean);
procedure OnConnectionLost(Sender: TObject; Component: TComponent; ConnLostCause: TConnLostCause; var RetryMode: TRetryMode);
4

4 に答える 4

19

イベント ハンドラを配置する適切なクラスがない場合は、ダミー クラスを定義して、イベント ハンドラをclass procedures にすることができます。次に、クラスのインスタンスを作成する必要はありませんが、割り当てることができmydb.OnError:= TMyDummyEventHandlerClass.OnConnectionError;ます。

ここに例があります - 私は持っていないがTUniConnection、すべてがコンパイルされることを確認したいので、異なるイベントを使用します。:-)

type
  // Dummy class to hold event handlers:
  TXMLEventHandlers = class
    // Event handlers:
    class procedure OnBeforeOpen(Sender: TObject);
    class procedure OnAfterOpen(Sender: TObject);
  end;

class procedure TXMLEventHandlers.OnBeforeOpen(Sender: TObject);
begin
  MessageBox(0, PChar(ClassName + '.OnBeforeOpen'), nil, 0)
end;

class procedure TXMLEventHandlers.OnAfterOpen(Sender: TObject);
begin
  MessageBox(0, PChar(ClassName + '.OnAfterOpen'), nil, 0)
end;

procedure Test;
var
  xml: TXMLDocument;
begin
  xml := TXMLDocument.Create(nil);
  try
    // Note: No instance of `TXMLEventHandlers` must be created:
    xml.AfterOpen := TXMLEventHandlers.OnAfterOpen;
    xml.BeforeOpen := TXMLEventHandlers.OnBeforeOpen;

    xml.Active := True; // Calls the two event handlers
  finally
    xml.Free;
  end;
end;
于 2012-06-18T14:10:56.777 に答える
4

ヒープ上のクラスのインスタンスをインスタンス化したくない場合は、recordメソッドを使用できます。ヒープの使用を避けるために時々そうしますが、そのアプローチはあなたのニーズに便利かもしれません。

type
  TMyEventHandler = record
    procedure OnConnectionError(Sender: TObject; E: EDAError; var Fail: Boolean);
    procedure OnConnectionLost(Sender: TObject; Component: TComponent; ConnLostCause: TConnLostCause; var RetryMode: TRetryMode);
  end;

procedure TMyEventHandler.OnConnectionError(Sender: TObject; E: EDAError; var Fail: Boolean);
begin
  ....
end;

procedure TMyEventHandler.OnConnectionLost(Sender: TObject; Component: TComponent; ConnLostCause: TConnLostCause; var RetryMode: TRetryMode);
begin
  ....
end;

var
  EventHandler: TEventHandler;//global variable

......

mydb.OnError := EventHandler.OnConnectionError;
mydb.OnConnectionLost := EventHandler.OnConnectionLost;
于 2012-06-18T13:30:24.460 に答える
0

2つのイベントプロシージャは、ローカル/グローバルプロシージャではなく、クラスのメソッドである必要があります。例えば：

procedure TForm1.OnConnectionError(Sender: TObject; E: EDAError; var Fail: Boolean);
于 2012-06-18T12:58:46.757 に答える