2

これが私のXMLです： 

<section>
  <para>part1 <breakline/> part2
    <list>
      <para>list1 </para>
      <para>list2 </para>
    </list> 
  </para>
<para>before_line_break <breakline/> after</para>
<para>para3</para>
</section>

期待される出力：

part1 
part2
before_line_break 
after
para3

「part2」は必要ですが、「list1」と「list2」は必要ありません

同等のHTMLファイルは次のようになります。

<html>
  <body>
    part1 <br/>
    part2 <br/>
    before_line_break <br/>
    after <br/>
    para3 <br/>
  </body>
</html>

xslファイルで多くのことを試しました。これは単なる例です（もちろん機能しません）：

<?xml version="1.0" encoding="ISO-8859-1"?>
<xsl:stylesheet version="1.0" xmlns:xsl="http://www.w3.org/1999/XSL/Transform">
<xsl:template match="/">
<html>
  <body>
    <xsl:for-each select="section/para">
      <xsl:value-of select="."/>
      <br/>
    </xsl:for-each>
  </body>
</html>
</xsl:template>
</xsl:stylesheet>

期待される出力を得るには、XSLファイルをどのように変更する必要がありますか？よろしくお願いします。

4

3 に答える 3

2

これを出発点としてください。

<xsl:stylesheet version="1.0" xmlns:xsl="http://www.w3.org/1999/XSL/Transform">

    <xsl:template match="/">
        <html>
            <body>
                <xsl:apply-templates select="section/para"/>
            </body>
        </html>
    </xsl:template>

    <xsl:template match="para">
        <xsl:apply-templates select="text()|breakline"/>
    </xsl:template>

    <xsl:template match="text()">
        <xsl:value-of select="."/>
        <!-- print br if text() is at end of para -->
        <xsl:if test="position()=last()">
            <br/>
        </xsl:if>
    </xsl:template>

    <!-- replace breakline with br -->
    <xsl:template match="breakline">
        <br/>
    </xsl:template>

    <!-- mute list -->
    <xsl:template match="list/para"/>

</xsl:stylesheet>
于 2012-06-19T21:25:52.040 に答える
2

これがおそらく最短の解決策です。2つのテンプレートのみ、条件なし、なしxsl:for-each：

<xsl:stylesheet version="1.0" xmlns:xsl="http://www.w3.org/1999/XSL/Transform">
 <xsl:output omit-xml-declaration="yes" indent="yes"/>

 <xsl:template match="/*">
  <html>
   <body>
     <xsl:apply-templates select="para/text()[normalize-space()]"/>
   </body>
  </html>
 </xsl:template>    
 <xsl:template match="para/text()">
  <xsl:value-of select="concat('&#xA;', normalize-space(.))"/><br />
 </xsl:template>
</xsl:stylesheet>

この変換が提供されたXMLドキュメントに適用される場合：

<section>
  <para>part1 <breakline/> part2
    <list>
      <para>list1 </para>
      <para>list2 </para>
    </list>
  </para>
<para>before_line_break <breakline/> after</para>
<para>para3</para>
</section>

必要な正しい結果が生成されます。

<html>
   <body>
      part1<br>
      part2<br>
      before_line_break<br>
      after<br>
      para3<br>
   </body>
</html>
于 2012-06-20T02:16:30.877 に答える
0 
<?xml version="1.0" encoding="ISO-8859-1"?>
<xsl:stylesheet version="1.0" xmlns:xsl="http://www.w3.org/1999/XSL/Transform">
  <xsl:output method="html" encoding="utf-8" indent="yes" />
  <xsl:template match="/section">
    <html>
      <body>
        <xsl:for-each select="para/text()">
          <xsl:value-of select="."/>
          <br/>
        </xsl:for-each>
      </body>
    </html>
  </xsl:template>
</xsl:stylesheet>
于 2012-06-19T21:35:01.297 に答える