2

私はIndyソケットを介してパケット文字列をストリーミングして作業しており、クライアント側には、から着信データを読み取り、TIdTCPClientこのデータを単一の文字列バッファーの最後に継続的に追加するスレッドがあります。このバッファを最初から継続的に読み取り、必要に応じてデータをコピー（および削除）する別のスレッドがあります（一度に1つの完全なパケット）。

いずれにせよ、同じ変数にアクセスする2つのスレッドは危険である可能性があることを私は知っています。しかし、これは文字列にも当てはまりますか？それともオブジェクトだけですか？2つの異なるスレッドからの同じ文字列のこの読み取り/書き込みで安全に感じることができますか？そうでない場合は、この文字列を保護するために何をすべきですか？これは、と呼ばれるプレーンな文字列FBufferです。

私は次のように最後にデータを追加しています：

procedure TListenThread.CheckForData;
begin
  if FClientSocket.Connected then begin
    FClientSocket.IOHandler.CheckForDataOnSource(5000);
    if not FClientSocket.IOHandler.InputBufferIsEmpty then
      FBuffer:= FBuffer + FClientSocket.IOHandler.InputBufferAsString;
  end;
end;

そして、他のスレッドはそれを次のように読んでいます：

procedeure TPacketThread.CheckForPacket;
var
  P: Integer; //Deliminator position
  T: String;  //Temp copying string
  Z: Integer; //Expected packet size
begin
  P:= Pos('#', FBuffer);
  if P > 0 then begin //Is the deliminator found?
    T:= Copy(FBuffer, 1, P-1); //Copy up to deliminator...
    Z:= StrToIntDef(T, 0); //Convert packet size to integer...
    if Z > 0 then begin
      //Is there a full packet waiting in buffer?
      if Length(FBuffer) >= Z then begin
        //First, delete size definition and deliminator...
        Delete(FBuffer, 1, P);
        //Now grab the rest of it up to the packet size...
        T:= Copy(FBuffer, 1, Z);
        //Delete what we just copied...
        Delete(FBuffer, 1, Z);
        //Finally, pass this packet string for further processing...
        ProcessPacket(T);
      end;
    end;
  end;
end;

このコードは、で行う必要のあるすべての作業を示すために、コードを簡略化したものですFBuffer。

4

2 に答える 2

5

はい、文字列バッファを同時アクセスから保護する必要があります。Indyには、TIdThreadSafeStringその目的で使用できるクラスがあります。例：

FBuffer: TIdThreadSafeString;
// make sure to Create() and Free() as needed..

。

procedure TListenThread.CheckForData; 
begin 
  if FClientSocket.Connected then begin 
    FClientSocket.IOHandler.CheckForDataOnSource(5000); 
    if not FClientSocket.IOHandler.InputBufferIsEmpty then 
      FBuffer.Append(FClientSocket.IOHandler.InputBufferAsString);
  end; 
end;

。

procedure TPacketThread.CheckForPacket; 
var 
  P: Integer; //Deliminator position 
  T: String;  //Temp copying string 
  Z: Integer; //Expected packet size 
begin 
  FBuffer.Lock;
  try
    P:= Pos('#', FBuffer.Value); 
    if P > 0 then begin //Is the deliminator found? 
      T := Copy(FBuffer.Value, 1, P-1); //Copy up to deliminator... 
      Z := StrToIntDef(T, 0); //Convert packet size to integer... 
      if Z > 0 then begin 
        //Is there a full packet waiting in buffer? 
        if Length(FBuffer.Value) >= Z then begin 
          //First, delete size definition and deliminator... 
          FBuffer.Value := Copy(FBuffer.Value, P+1, MaxInt); 
          //Now grab the rest of it up to the packet size... 
          T := Copy(FBuffer.Value, 1, Z); 
          //Delete what we just copied... 
          FBuffer.Value := Copy(FBuffer.Value, Z+1, MaxInt); 
          //Finally, pass this packet string for further processing... 
          ProcessPacket(T); 
        end; 
      end; 
    end; 
  finally
    FBuffer.Unlock;
  end;
end;

そうは言っても、パケットのフォーマットについてあなたが示したことを考えると、代わりに別の戦術を取ります。

FBuffer: TIdThreadSafeStringList;
// make sure to Create() and Free() as needed..

。

procedure TListenThread.CheckForData; 
var 
  T: String;  //Temp copying string 
  Z: Integer; //Expected packet size 
begin 
  if FClientSocket.Connected then begin 
    if FClientSocket.IOHandler.InputBufferIsEmpty then begin
      FClientSocket.IOHandler.CheckForDataOnSource(5000);
      if FClientSocket.IOHandler.InputBufferIsEmpty then Exit;
    end; 
    // data is available, keep reading as long as packets are present...
    repeat
      T := FClientSocket.IOHandler.ReadLn('#');
      Z := StrToIntDef(T, 0);
      if Z > 0 then begin 
        T := FClientSocket.IOHandler.ReadString(Z); 
        FBuffer.Add(T); 
      end; 
    until FClientSocket.IOHandler.InputBufferIsEmpty;
  end; 
end;

。

procedure TPacketThread.CheckForPacket; 
var 
  L: TStringList;
  T: String;
begin 
  L := FBuffer.Lock;
  try
    if L.Count = 0 then Exit;
    T := L[0];
    L.Delete(0);
  finally
    FBuffer.Unlock;
  end;
  ProcessPacket(T); 
end;
于 2012-06-20T22:47:57.727 に答える
5

はい、複数のスレッドからアクセスする場合は文字列を保護する必要があります。これは、重要なセクションを使用して行うことができます。EnterCriticalSection、LeaveCriticalSection、InitializeCriticalSection、およびDeleteCriticalSection関数を見てください。

于 2012-06-20T21:47:50.453 に答える