0

Perl で入力ファイルから値を読み取ろうとしています。入力ファイルは次のようになります。

1-sampledata1 This is a sample test
              and data for this continues
2-sampledata2 This is sample test 2
              Data for this also is on second line

上記のデータを読み込んで、 for のデータ1-sampledata1が入り@array1、 for のデータ2-sampledata2が入り@array2ます。このようなセクションが約 50 あります。のように50-sampledata50。

編集: 名前は常に X-sampledataX ではありません。たとえば、私はちょうどそれをしました。したがって、名前をループにすることはできません。手動で入力する必要があると思います

私はこれまでのところ次のものを持っています（これは機能します）。しかし、私はこれを行うためのより効率的な方法を探しています..

foreach my $line(@body){
        if ($line=~ /^1-sampledata1\s/){
                $line=~ s/1-ENST0000//g;
                $line=~ s/\s+//g;
                push (@array1, $line);
          #using splitarray because i want to store data as one character each
          #for ex: i wana store 'This' as T H I S in different elements of array
                @splitarray1= split ('',$line);
        last if ($line=~ /2-sampledata2/);
        }
}
foreach my $line(@body){
        if ($line=~ /^2-sampledata2\s/){
                $line=~ s/2-ENSBTAP0//g;
                $line=~ s/\s+//g;
                @splitarray2= split ('',$line);
        last if ($line=~ /3-sampledata3/);
        }
}

ご覧のとおり、セクションごとに異なる配列と、セクションごとに異なる for ループがあります。これまでのアプローチに従えば、50 個の for ループと 50 個の配列になってしまいます。

これを行う別のより良い方法はありますか？最終的には、50 個の配列で終了したいのですが、50 個の for ループを書きたくありません。そして、プログラムの後半で 50 個の配列をループするので、それらを配列に格納することはできますか? 私はPerlを初めて使用するので、ちょっと圧倒されます...

4

4 に答える 4

4

最初に気付くのは、変数名に整数のサフィックスを付けようとしているということです: 使用しないでください。自分がやりたいと思ったときはいつでも配列を使用してください。第 2 に、ファイルの内容を何度も読み取る必要はなく、1 回だけ読み取る必要があります。第三に、通常、Perl では文字列を文字の配列として扱う正当な理由はありません。

更新:このバージョンのコードは、先頭のスペースの存在を使用して何をすべきかを決定します。参考までに以前のバージョンも残しておきます。

#!/usr/bin/perl

use strict;
use warnings;

my @data;

while ( my $line = <DATA> ) {
    chomp $line;
    if ( $line =~ s/^ +/ / ) {
        push @{ $data[-1] }, split //, $line;
    }
    else {
        push @data, [ split //, $line ];
    }
}

use Data::Dumper;
print Dumper \@data;

__DATA__
1-sampledata1 This is a sample test
              and data for this continues
2-sampledata2 This is sample test 2
              Data for this also is on second line

前のバージョン：

#!/usr/bin/perl

use strict;
use warnings;

my @data;

while ( my $line = <DATA> ) {
    chomp $line;
    $line =~ s/\s+/ /g;
    if ( $line =~ /^[0-9]+-/ ) {
        push @data, [ split //, $line ];
    }
    else {
        push @{ $data[-1] }, split //, $line;
    }
}

use Data::Dumper;
print Dumper \@data;

__DATA__
1-sampledata1 This is a sample test
              and data for this continues
2-sampledata2 This is sample test 2
              Data for this also is on second line
于 2009-07-11T14:39:29.490 に答える
1 
#! /usr/bin/env perl
use strict;
use warnings;

my %data;
{
  my( $key, $rest );
  while( my $line = <> ){
    unless( ($rest) = $line =~ /^     \s+(.*)/x ){
      ($key, $rest) = $line =~ /^(.*?)\s+(.*)/;
    }
    push @{ $data{$key} }, $rest;
  }
}
于 2009-07-11T14:57:00.600 に答える
1

以下のコードは、 @Brad Gilbertおよび@Sinan Unurのソリューションと非常によく似ています。

#!/usr/bin/perl
use strict;
use warnings;    
use Data::Dumper;

my (%arrays, $label);
while (my $line = <DATA>) 
{
    ($label, $line) = ($1, $2) if $line =~ /^(\S+)(.*)/; # new data block

    $line =~ s/^\s+//; # strip whitespaces from the begining
    # append data for corresponding label
    push @{$arrays{$label}}, split('', $line) if defined $label;
}

print $arrays{'1-sampledata1'}[2], "\n";     # 'i'
print join '-', @{$arrays{'2-sampledata2'}}; # 'T-h-i-s- -i-s- -s-a-m-p-l
print Dumper \%arrays;

__DATA__
1-sampledata1 This is a sample test
              and data for this continues
2-sampledata2 This is sample test 2
              Data for this also is on second line

出力

i
T-h-i-s- -i-s- -s-a-m-p-l-e- -t-e-s-t- -2-D-a-t-a- -f-o-r- -t-h-i-s- -a-l-s-o- -i-s- -o-n- -s-e-c-o-n-d- -l-i-n-e-
$VAR1 = {
          '2-sampledata2' => [
                               'T',
                               'h',
                               'i',
                               's',
                               ' ',
                               'i',
                               's',
                               ' ',
                               's',
                               'a',
                               'm',
                               'p',
                               'l',
                               'e',
                               ' ',
                               't',
                               'e',
                               's',
                               't',
                               ' ',
                               '2',
                               'D',
                               'a',
                               't',
                               'a',
                               ' ',
                               'f',
                               'o',
                               'r',
                               ' ',
                               't',
                               'h',
                               'i',
                               's',
                               ' ',
                               'a',
                               'l',
                               's',
                               'o',
                               ' ',
                               'i',
                               's',
                               ' ',
                               'o',
                               'n',
                               ' ',
                               's',
                               'e',
                               'c',
                               'o',
                               'n',
                               'd',
                               ' ',
                               'l',
                               'i',
                               'n',
                               'e',
                               '
'
                             ],
          '1-sampledata1' => [
                               'T',
                               'h',
                               'i',
                               's',
                               ' ',
                               'i',
                               's',
                               ' ',
                               'a',
                               ' ',
                               's',
                               'a',
                               'm',
                               'p',
                               'l',
                               'e',
                               ' ',
                               't',
                               'e',
                               's',
                               't',
                               'a',
                               'n',
                               'd',
                               ' ',
                               'd',
                               'a',
                               't',
                               'a',
                               ' ',
                               'f',
                               'o',
                               'r',
                               ' ',
                               't',
                               'h',
                               'i',
                               's',
                               ' ',
                               'c',
                               'o',
                               'n',
                               't',
                               'i',
                               'n',
                               'u',
                               'e',
                               's',
                               '
'
                             ]
        };
于 2009-07-11T16:11:06.513 に答える
0

代わりに、配列へのハッシュマップを使用する必要があります。

この正規表現パターンを使用して、インデックスを取得します。

/^(\d+)-sampledata(\d+)/

そして、でmy %arrays、次のようにします。

push($arrays{$index}), $line;

その後、。を使用してアレイにアクセスできます$arrays{$index}。

于 2009-07-11T14:34:42.197 に答える