c# - 管理者権限のあるプロセスから管理者権限のない新しいプロセスを開始する方法は?

Question

アプリケーションの自動アップデーターを作成しています。アプリケーションはユーザーによって開始され、管理者権限なしで実行されます。autoupdater は管理者権限で開始され、新しいファイルをダウンロードする前にアプリケーションを強制終了します。

autoupdater が終了した後に、更新されたアプリケーションを起動したいときに問題が発生します。通常の System.Diagnostics.Process.Start(file) を使用すると、アプリケーションも管理者権限で開始され、意図したとおりに動作するには現在のユーザーで実行する必要があります。

では、管理者ではなく現在のユーザーとして autoupdater にアプリケーションを起動させるにはどうすればよいでしょうか?

私は以下を使用してみました：

var pSI = new ProcessStartInfo() { 
    UseShellExecute = false, 
    UserName = Environment.UserName, 
    FileName = file 
};
System.Diagnostics.Process.Start(pSI);

しかし、これは「無効なユーザー名またはパスワード」というエラーをスローします。ユーザー名が正しいことを確認しましたが、パスワードが含まれていないため、パスワードがおそらく無効であることを理解しています。ただし、アプリケーションを自動的に起動する理由はすべて、ユーザーにとって簡単にするためであるため、ユーザーにパスワードの入力を求めるオプションはありません。

助言がありますか？

score 15 · Accepted Answer

あなたが達成しようとしていることは、非常に簡単に行うことができず、サポートされていません。ただし、わずかなハッキングを使用することは可能です。Aaron Margosis は、1 つの手法を説明する記事を書きました。

関連セクションを引用するには、次の手順を実行する必要があります。

現在のトークンで SeIncreaseQuotaPrivilege を有効にする

デスクトップシェルを表す HWND を取得する (GetShellWindow)

そのウィンドウに関連付けられているプロセスのプロセス ID (PID) を取得します (GetWindowThreadProcessId)

そのプロセスを開く (OpenProcess)

そのプロセスからアクセストークンを取得する (OpenProcessToken)

そのトークンでプライマリトークンを作成します (DuplicateTokenEx)

そのプライマリトークン (CreateProcessWithTokenW) で新しいプロセスを開始します。

この記事には、デモ C++ ソースのダウンロードリンクが含まれており、そこから C# に変換するのに十分なほど単純なはずです。

score 6 · Accepted Answer

アプリケーションを終了するのではなく、正常にシャットダウンするようにアプリケーションに通知していると仮定し、アップデータをリリースする前にアプリケーションに変更を加えることができる場合、1 つの簡単な解決策は、終了する前にアプリケーションに中間プロセスを起動させることです。暫定プロセスの実行可能ファイルを一時的な場所に作成できます。更新が終了したら、中間プロセスにシグナルを送り、アプリケーションを再起動して終了します。そうすれば、すべてが自然に起こり、いじる必要はありません。

別のオプションはOpenProcess、、OpenProcessToken、およびを使用DuplicateTokenして、アプリケーションを強制終了する前にアプリケーションのセキュリティトークンのコピーを取得することです。CreateProcessAsUserその後、元のコンテキストでアプリケーションを再起動するために使用できます。

これらのアプローチはどちらも、アップデーターが別のアカウントで実行されている場合やアプリケーションとの別のセッションで実行されている場合でも機能するはずです。

score 4 · Accepted Answer

ユーザーアカウント制御ヘルパーと呼ばれるcodeplex上のプロジェクトがあります。

このプロジェクトは、UACメカニズムと対話するためのライブラリを提供します。

ライブラリには、というクラスがありますUserAccountControl。CreateProcessAsStandardUserこのクラスには、標準のユーザー権限を持つ昇格されたプロセスからプロセスを開始するために呼び出される静的メソッドがあります。

つまり、関数はデスクトップシェルプロセスのプロセストークンを開きます。次に、そのトークンを複製してプライマリトークンを取得します。このトークンは、ログオンしたユーザーの下で新しいプロセスを開始するために使用されます。

詳細については、AaronMargosisの次のブログ投稿をお読みください。

score 2 · Accepted Answer

昇格された親プロセスからデフォルトのシェル権限でプロセスを開始するための実用的な VB.NET コード

#Region "References"

Imports System.Runtime.InteropServices

#End Region

Public Class LaunchProcess

#Region "Native Methods"

    <DllImport("User32.dll", SetLastError:=True)> Private Shared Function GetShellWindow() As IntPtr
    End Function

    <DllImport("advapi32.dll", SetLastError:=True)> Private Shared Function OpenProcessToken(ByVal ProcessHandle As IntPtr, ByVal DesiredAccess As Integer, ByRef TokenHandle As IntPtr) As Boolean
    End Function

    <DllImport("user32.dll", SetLastError:=True)> Private Shared Function GetWindowThreadProcessId(ByVal hwnd As IntPtr, ByRef lpdwProcessId As IntPtr) As Integer
    End Function

    <DllImport("kernel32.dll")> Private Shared Function OpenProcess(ByVal dwDesiredAccess As UInteger, <MarshalAs(UnmanagedType.Bool)> ByVal bInheritHandle As Boolean, ByVal dwProcessId As IntPtr) As IntPtr
    End Function

    <DllImport("advapi32.dll", SetLastError:=True)> _
    Private Shared Function DuplicateTokenEx( _
    ByVal ExistingTokenHandle As IntPtr, _
    ByVal dwDesiredAccess As UInt32, _
    ByRef lpThreadAttributes As SECURITY_ATTRIBUTES, _
    ByVal ImpersonationLevel As Integer, _
    ByVal TokenType As Integer, _
    ByRef DuplicateTokenHandle As System.IntPtr) As Boolean
    End Function

    <DllImport("advapi32.dll", SetLastError:=True)> Private Shared Function LookupPrivilegeValue(lpSystemName As String, lpName As String, ByRef lpLuid As LUID) As Boolean
    End Function

    <DllImport("advapi32.dll", SetLastError:=True)> _
    Private Shared Function AdjustTokenPrivileges( _
    ByVal TokenHandle As IntPtr, _
    ByVal DisableAllPrivileges As Boolean, _
    ByRef NewState As TOKEN_PRIVILEGES, _
    ByVal BufferLengthInBytes As Integer, _
    ByRef PreviousState As TOKEN_PRIVILEGES, _
    ByRef ReturnLengthInBytes As Integer _
  ) As Boolean
    End Function

    <DllImport("advapi32", SetLastError:=True, CharSet:=CharSet.Unicode)> Private Shared Function CreateProcessWithTokenW(hToken As IntPtr, dwLogonFlags As Integer, lpApplicationName As String, lpCommandLine As String, dwCreationFlags As Integer, lpEnvironment As IntPtr, lpCurrentDirectory As IntPtr, ByRef lpStartupInfo As STARTUPINFO, ByRef lpProcessInformation As PROCESS_INFORMATION) As Boolean
    End Function

#End Region

#Region "Structures"

    <StructLayout(LayoutKind.Sequential)> Private Structure SECURITY_ATTRIBUTES

        Friend nLength As Integer
        Friend lpSecurityDescriptor As IntPtr
        Friend bInheritHandle As Integer

    End Structure

    Private Structure TOKEN_PRIVILEGES

        Friend PrivilegeCount As Integer
        Friend TheLuid As LUID
        Friend Attributes As Integer

    End Structure

    Private Structure LUID

        Friend LowPart As UInt32
        Friend HighPart As UInt32

    End Structure

    <StructLayout(LayoutKind.Sequential, CharSet:=CharSet.Unicode)> Private Structure STARTUPINFO

        Friend cb As Integer
        Friend lpReserved As String
        Friend lpDesktop As String
        Friend lpTitle As String
        Friend dwX As Integer
        Friend dwY As Integer
        Friend dwXSize As Integer
        Friend dwYSize As Integer
        Friend dwXCountChars As Integer
        Friend dwYCountChars As Integer
        Friend dwFillAttribute As Integer
        Friend dwFlags As Integer
        Friend wShowWindow As Short
        Friend cbReserved2 As Short
        Friend lpReserved2 As Integer
        Friend hStdInput As Integer
        Friend hStdOutput As Integer
        Friend hStdError As Integer

    End Structure

    Private Structure PROCESS_INFORMATION

        Friend hProcess As IntPtr
        Friend hThread As IntPtr
        Friend dwProcessId As Integer
        Friend dwThreadId As Integer

    End Structure

#End Region

#Region "Enumerations"

    Private Enum TOKEN_INFORMATION_CLASS

        TokenUser = 1
        TokenGroups
        TokenPrivileges
        TokenOwner
        TokenPrimaryGroup
        TokenDefaultDacl
        TokenSource
        TokenType
        TokenImpersonationLevel
        TokenStatistics
        TokenRestrictedSids
        TokenSessionId
        TokenGroupsAndPrivileges
        TokenSessionReference
        TokenSandBoxInert
        TokenAuditPolicy
        TokenOrigin
        TokenElevationType
        TokenLinkedToken
        TokenElevation
        TokenHasRestrictions
        TokenAccessInformation
        TokenVirtualizationAllowed
        TokenVirtualizationEnabled
        TokenIntegrityLevel
        TokenUIAccess
        TokenMandatoryPolicy
        TokenLogonSid
        MaxTokenInfoClass

    End Enum

#End Region

#Region "Constants"

    Private Const SE_PRIVILEGE_ENABLED = &H2L
    Private Const PROCESS_QUERY_INFORMATION = &H400
    Private Const TOKEN_ASSIGN_PRIMARY = &H1
    Private Const TOKEN_DUPLICATE = &H2
    Private Const TOKEN_IMPERSONATE = &H4
    Private Const TOKEN_QUERY = &H8
    Private Const TOKEN_QUERY_SOURCE = &H10
    Private Const TOKEN_ADJUST_PRIVILEGES = &H20
    Private Const TOKEN_ADJUST_GROUPS = &H40
    Private Const TOKEN_ADJUST_DEFAULT = &H80
    Private Const TOKEN_ADJUST_SESSIONID = &H100
    Private Const SecurityImpersonation = 2
    Private Const TokenPrimary = 1
    Private Const SE_INCREASE_QUOTA_NAME = "SeIncreaseQuotaPrivilege"

#End Region

#Region "Methods"

    Friend Shared Sub LaunchFile(ByVal FilePath As String, ByVal IsWaitToFinish As Boolean)

        Try

            'Enable the SeIncreaseQuotaPrivilege in current token
            Dim HPrcsToken As IntPtr = Nothing
            OpenProcessToken(Process.GetCurrentProcess.Handle, TOKEN_ADJUST_PRIVILEGES, HPrcsToken)

            Dim TokenPrvlgs As TOKEN_PRIVILEGES
            TokenPrvlgs.PrivilegeCount = 1
            LookupPrivilegeValue(Nothing, SE_INCREASE_QUOTA_NAME, TokenPrvlgs.TheLuid)
            TokenPrvlgs.Attributes = SE_PRIVILEGE_ENABLED

            AdjustTokenPrivileges(HPrcsToken, False, TokenPrvlgs, 0, Nothing, Nothing)

            'Get window handle representing the desktop shell
            Dim HShellWnd As IntPtr = GetShellWindow()

            'Get the ID of the desktop shell process
            Dim ShellPID As IntPtr
            GetWindowThreadProcessId(HShellWnd, ShellPID)

            'Open the desktop shell process in order to get the process token
            Dim HShellPrcs As IntPtr = OpenProcess(PROCESS_QUERY_INFORMATION, False, ShellPID)
            Dim HShellPrcSToken As IntPtr = Nothing
            Dim HPrimaryToken As IntPtr = Nothing

            'Get the process token of the desktop shell
            OpenProcessToken(HShellPrcs, TOKEN_DUPLICATE, HShellPrcSToken)

            'Duplicate the shell's process token to get a primary token
            Dim TokenRights As UInteger = TOKEN_QUERY Or TOKEN_ASSIGN_PRIMARY Or TOKEN_DUPLICATE Or TOKEN_ADJUST_DEFAULT Or TOKEN_ADJUST_SESSIONID
            DuplicateTokenEx(HShellPrcSToken, TokenRights, Nothing, SecurityImpersonation, TokenPrimary, HPrimaryToken)

            Dim StartInfo As STARTUPINFO = Nothing
            Dim PrcsInfo As PROCESS_INFORMATION = Nothing

            StartInfo.cb = Marshal.SizeOf(StartInfo)
            Dim IsSuccessed As Boolean = CreateProcessWithTokenW(HPrimaryToken, 1, FilePath, "", 0, Nothing, Nothing, StartInfo, PrcsInfo)

            If IsSuccessed = True Then

                If IsWaitToFinish = True Then

                    Try

                        Dim Prcs As Process = Process.GetProcessById(PrcsInfo.dwProcessId)
                        Prcs.WaitForExit()

                    Catch ex As Exception
                    End Try

                End If

            Else

                'Could not launch process with shell token may be the process needs admin rights to launch, we will try to launch it with default parent process permissions.

                Dim Prcs As New Process
                Prcs.StartInfo.FileName = FilePath
                Prcs.Start()

                If IsWaitToFinish = True Then Prcs.WaitForExit()

            End If

        Catch ex As Exception
        End Try

    End Sub

#End Region

End Class

LaunchProcess クラスの使用法

LaunchProcess.LaunchFile("C:\Program Files\Test\text.exe", False)

コードを C# に変換するには、Telerik コードコンバーターを使用できますhttp://converter.telerik.com/

score 0 · Accepted Answer

ライターが説明するように、この問題は解決されません。私は今、同じ問題を抱えています。これをどのように解決したかを説明したいと思います。

ご存じのとおり、これは簡単なことではありませんが、最善の解決策は、別の非管理者プロセスによってコンピュータに「*.exe」ファイルを強制的に起動させることです。私がしたことは、タスクスケジューラwithout Highest Privilegeパラメータでタスクを作成することでした。これは、時間を作成するか、このタスクを手動で実行することを意味します。

ばかげているようですが、仕方がないようです。

Windowsタスクスケジューラ/で新しいタスクを作成する方法を説明するこのリンクを見ることができます

score 0 · Accepted Answer

CreateProcessWithLogonW 関数または同様のCreateProcessAsUserおよびCreateProcessWithTokenWを使用できます。

c# - 管理者権限のあるプロセスから管理者権限のない新しいプロセスを開始する方法は?

10 に答える 10

Related

Reference