2

LFすべての文字をタグに変換<br />して HTML ページに表示する方法は?

次の XML ファイルの例があります。

<?xml version="1.0" encoding="utf-8"?>
<?xml-stylesheet type="text/xsl" href="data.xslt"?>
<data>
<lines>
Line 1
Line 2
Line 3
Line 4
Line 5
Line 6
</lines>
</data>

HTMLページのすべての行を表示したい。このために、次の XSLT 変換を使用します。

<?xml version="1.0" encoding="UTF-8"?>
<xsl:stylesheet version="2.0" xmlns:xsl="http://www.w3.org/1999/XSL/Transform">
    <xsl:output method="html" version="1.0" encoding="utf-8" indent="yes"/>
    <xsl:template match="/">
        <html>
            <head>
                <meta http-equiv="Content-Type" content="text/html; charset=utf-8"/>
            </head>
            <body>
                <xsl:variable name="filtered">
                    <xsl:call-template name="replace">
                        <xsl:with-param name="string" select="./data/lines"/>
                        <xsl:with-param name="search" select="'&#xA;'"/>
                        <xsl:with-param name="new"><br /></xsl:with-param>
                    </xsl:call-template>
                </xsl:variable>
                <td align="left">
                    <xsl:value-of select="$filtered" disable-output-escaping="yes"/>
                </td>
            </body>
        </html>
    </xsl:template>
    <xsl:template name="replace">
        <xsl:param name="string"/>
        <xsl:param name="search"/>
        <xsl:param name="new"/>
        <xsl:choose>
            <xsl:when test="contains($string, $search)">
                <xsl:value-of select="substring-before($string, $search)"/>
                <xsl:value-of select="$new"/>
                <xsl:call-template name="replace">
                    <xsl:with-param name="string" select="substring-after($string, $search)"/>
                    <xsl:with-param name="search" select="$search"/>
                    <xsl:with-param name="new" select="$new"/>
                </xsl:call-template>
            </xsl:when>
            <xsl:otherwise>
                <xsl:value-of select="$string"/>
            </xsl:otherwise>
        </xsl:choose>
    </xsl:template>
</xsl:stylesheet>


その XML ファイルを Firefox で開くと (ブラウザーを使用して XSLT 変換を表示します)、次の結果が表示されます。

Line 1Line 2Line 3Line 4Line 5Line 6

ご覧のとおり、文字はタグLFに置き換えられていません。<br />


しかし、たとえば、他の文字列を使用する場合EOL:

<xsl:with-param name="new">EOL</xsl:with-param>

期待される結果が表示されます：

EOLLine 1EOLLine 2EOLLine 3EOLLine 4EOLLine 5EOLLine 6EOL


問題は convert/display<br />タグにあります。

4

5 に答える 5

3

の場合と同様に、ノード フラグメントをパラメータ値として渡すことができますが<xsl:with-param name="new"><br /></xsl:with-param>、それをテンプレートの要素として出力するには、 ではなくbrを使用する必要があります。<xsl:copy-of select="$new"/>xsl:value-of

[編集] ここに例があります: http://home.arcor.de/martin.honnen/xslt/test2012062801.xml . スタイルシートはhttp://home.arcor.de/martin.honnen/xslt/test2012062801.xslにあります。以下にも含めます。

<?xml version="1.0" encoding="UTF-8"?>
<xsl:stylesheet version="1.0" xmlns:xsl="http://www.w3.org/1999/XSL/Transform">
    <xsl:output method="html" version="4.01" encoding="utf-8" indent="yes"/>
    <xsl:template match="/">
        <html>
            <head>
              <title>Example</title>
            </head>
            <body>
                <xsl:variable name="filtered">
                    <xsl:call-template name="replace">
                        <xsl:with-param name="string" select="data/lines"/>
                        <xsl:with-param name="search" select="'&#xA;'"/>
                        <xsl:with-param name="new"><br /></xsl:with-param>
                    </xsl:call-template>
                </xsl:variable>
                <div>
                    <xsl:copy-of select="$filtered"/>
                </div>
            </body>
        </html>
    </xsl:template>
    <xsl:template name="replace">
        <xsl:param name="string"/>
        <xsl:param name="search"/>
        <xsl:param name="new"/>
        <xsl:choose>
            <xsl:when test="contains($string, $search)">
                <xsl:value-of select="substring-before($string, $search)"/>
                <xsl:copy-of select="$new"/>
                <xsl:call-template name="replace">
                    <xsl:with-param name="string" select="substring-after($string, $search)"/>
                    <xsl:with-param name="search" select="$search"/>
                    <xsl:with-param name="new" select="$new"/>
                </xsl:call-template>
            </xsl:when>
            <xsl:otherwise>
                <xsl:value-of select="$string"/>
            </xsl:otherwise>
        </xsl:choose>
    </xsl:template>
</xsl:stylesheet>
于 2012-06-27T10:50:45.160 に答える
1

私見、 xsl:anaylze-string はこの問題に最適です。この XSLT 2.0 スタイルシートは、Saxon で動作します ...

<?xml version="1.0" encoding="utf-8"?>
<xsl:stylesheet version="2.0"
  xmlns:xsl="http://www.w3.org/1999/XSL/Transform"
  xmlns:fn="http://www.w3.org/2005/xpath-functions"
  xmlns:xs="http://www.w3.org/2001/XMLSchema"
  xmlns:so="http://stackoverflow.com/questions/11222334"
  xmlns:x="http://www.w3.org/1999/xhtml"
  xmlns="http://www.w3.org/1999/xhtml"
  exclude-result-prefixes="xsl fn xs so x">

<xsl:output method="xhtml" encoding="utf-8" indent="yes"
            doctype-system="http://www.w3.org/TR/xhtml1/DTD/xhtml1-transitional.dtd"
            doctype-public="-//W3C//DTD XHTML 1.0 Transitional//EN"
            omit-xml-declaration="yes" />

<xsl:template match="/">
 <html>
  <head><meta http-equiv="Content-Type" content="text/html; charset=utf-8"/></head>
  <body>
   <xsl:apply-templates select="data/lines"/>
  </body>
 </html> 
</xsl:template>

<xsl:template match="lines">
    <xsl:analyze-string select="." regex="\n">
        <xsl:matching-substring>
          <br />
          <xsl:value-of select="'&#x0A;'" />
        </xsl:matching-substring>
        <xsl:non-matching-substring>
          <xsl:value-of select="."/>
        </xsl:non-matching-substring>
      </xsl:analyze-string>
</xsl:template>

</xsl:stylesheet>

... この入力ドキュメントに適用すると ...

<?xml version="1.0" encoding="utf-8"?>
<data>
<lines>
Line 1
Line 2
Line 3
Line 4
Line 5
Line 6
</lines>
</data>

... この html ページを生成します ...

<!DOCTYPE html
  PUBLIC "-//W3C//DTD XHTML 1.0 Transitional//EN" "http://www.w3.org/TR/xhtml1/DTD/xhtml1-transitional.dtd">
<html xmlns="http://www.w3.org/1999/xhtml">
   <head>
      <meta http-equiv="Content-Type" content="text/html; charset=utf-8" />
   </head>
   <body><br />
      Line 1<br />
      Line 2<br />
      Line 3<br />
      Line 4<br />
      Line 5<br />
      Line 6<br />

   </body>
</html>
于 2012-06-27T10:05:44.663 に答える
1

パラメータ値に余分な引用符があります。ラインを変えてみる…

<xsl:with-param name="search" select="'&#xA;'"/>

に...

<xsl:with-param name="search" select="&#xA;"/>

アップデート

OPで指摘されているように、上記は正しくなく、XSLT変換エラーが発生します。
@banana の答えが正しいと思います。

于 2012-06-27T09:05:49.850 に答える
0

置き換えてみてください:

<xsl:with-param name="new"><br /></xsl:with-param>

と：

<xsl:with-param name="new">&lt;br /&gt;</xsl:with-param>
于 2012-06-27T09:11:30.357 に答える
0

これは現在のノード値を書き込み、\n を <br/> に置き換えます

<xsl:value-of select="replace(., '\n', '&lt;br/&gt;')"/>
于 2012-06-27T09:14:34.430 に答える