1

リストがあります

<nodes>
<node attr='1'/>
<node attr='0'/>
<node attr='1'/>
<node attr='1'/>
</nodes>

適用する必要があります-すべてのノードをテンプレート化し、カウントします：

<xsl:apply-templates select='nodes/node'>
<xsl:if test='@attr=1'>
<xsl:number/>
</xsl:if>
</xsl:apply-templates>

しかし、結果は123ではなく、結果は134です。xslt-1.0で修正するにはどうすればよいですか？それに番号を設定する別の方法はありますか？position（）は役に立たず、

<xsl:apply-templates select='nodes/node[@attr=1]'>
<xsl:if test='@attr=1'>
<xsl:number/>
</xsl:if>
</xsl:apply-templates>

=（（（

4

3 に答える 3

3

まず、XSLTにエラーがあります

<xsl:apply-templates select='nodes/node'> 
   <xsl:if test='@attr=1'> <xsl:number/>     
   </xsl:if>
</xsl:apply-templates>

xsl：apply-templates内にxsl：ifを含めることはできません。一致するxsl：templateが必要で、そこにコードを配置します...

<xsl:apply-templates select="nodes/node" />

<xsl:template match="node">
   <xsl:if test='@attr=1'>
      <xsl:number/>     
   </xsl:if>
<xsl:template>

実際、ここでxsl：ifを廃止して、テンプレートのテストを一致させることができます。

<xsl:template match="node[@attr=1]">
    <xsl:number/>     
<xsl:template>

ただし、質問に答えるには、 xsl：number要素のcount属性を使用して、必要な要素のみをカウントする必要があります。

<xsl:number count="node[@attr=1]"/>

これが完全なXSLTです

<xsl:stylesheet version="1.0" xmlns:xsl="http://www.w3.org/1999/XSL/Transform">
   <xsl:output method="xml" indent="yes"/>

   <xsl:template match="/">
      <xsl:apply-templates select="nodes/node"/>
   </xsl:template>

   <xsl:template match="node[@attr=1]">
      <xsl:number count="node[@attr=1]"/>
   </xsl:template>

   <xsl:template match="node"/>
</xsl:stylesheet>

XMLに適用すると、結果は123になります。

于 2012-06-29T08:34:31.057 に答える
2

これは123と言います-これはあなたが求めていたものですか？

<xsl:for-each select="nodes/node[@attr='1']">
  <xsl:value-of select="position()"/>
</xsl:for-each>
于 2012-06-29T08:14:40.693 に答える
0

何を達成しようとしているのかは明確ではありません。属性が1に設定されているノードの数をカウントする必要があると思います。その場合は、カウント関数を使用してください。

<xsl:value-of select="count(nodes/node[@attr='1'])" />

条件に一致するサブセット内の目的のノードの位置を出力する必要がある場合は、for-eachおそらく次の方法になります。

<xsl:for-each select="nodes/node[@attr='1']">
    <xsl:value-of select="position()" />
</xsl:for-each>
于 2012-06-29T08:14:56.287 に答える