7

数週間前、私は ops グループのために SNMP リレイヤーを書きました。彼らは単一の IP にしかトラップを送信できないいくつかのダム デバイスを持っており、可用性のために複数の IP をリッスンする監視システムがあります。コードは非常にシンプルで、基本的には次のとおりです。

while (recv($packet)) {
  foreach $target (@targets) {
    send($target, $packet);
  }
}

基本的には機能しましたが、発信元IPが含まれていないという明らかな欠点が問題になっています(明らかに、デバイスの最初のクラスにはvarbindとして情報が含まれていましたが、一部の新しいクラスには含まれていません)。

私がやりたいことは、コードを次のように変更することです。

while ($server->recv($packet)) {
  my $obj = decompile($packet)
  if (!$obj->{varbind}{snmpTrapAddress}) {
    $obj->{varbind}{snmpTrapAddress} = inet_ntoa($server->peeraddr());
  }
  $packet = compile($obj);
  foreach $target (@targets) {
    send($target, $packet);
  }
}

つまり、送信者に snmpTrapAddress が含まれていない場合は、追加します。問題は、私が調べた Perl 用のすべての SNMP パッケージが、トラップを受信して​​ get を実行するインフラストラクチャに非常に重点を置いているように見えることです。

だから：「これはsnmpトラップを表すデータのブロブです。それを簡単に操作できるものにデコードし、ネットワーク経由でスローできるブロブに再コンパイルしてください」と言うことができる単純なPerlモジュールはありますか？

あなたの答えが「SNMPダミーを使用する」である場合、その例を挙げていただけますか? 私は目が見えないだけかもしれませんが、perldoc SNMPの出力からは、この方法でそれを使用する方法が明らかではありません。

編集：

「SNMPエンコーディング」が実際にはASN.1 BER（Basic Encoding Rules）であることが少しわかりました。これに基づいて、私は Convert::BER を試しています。SNMP の簡単な分解/編集/再構築のヒントを歓迎します。

4

3 に答える 3

8

これに対する完璧な解決策は見つかりませんでした。Net::SNMP::Message ( Net::SNMPの一部) はこれを許可するかもしれませんが、公的に定義されたインターフェースを持っていないようで、特に関連する Net::SNMP インターフェースはありませんでした。 NSNMPは私が探していたものの精神に最も近いものですが、脆弱であり、箱から出してすぐに使用したパケットでは機能しませんでした。脆弱なコードをサポートする場合、それは私自身の脆弱なコードになるでしょう =)。

Mon::SNMPも私が探していたものに近づきましたが、それも箱から出して壊れていました。2001 年の最後のリリースと 2002 年の開発者の最後の CPAN リリースで、放棄されたようです。当時は気づきませんでしたが、Convert::BER へのインターフェイスの変更のために壊れていると思います。使用するモジュール。

Mon::SNMP はConvert::BERを指し示してくれました。Convert::BER POD、Mon::SNMP ソース、およびRFC 1157 (特に 4.1.6、"The Trap-PDU") を数千回読み取り、概念実証としてこのコードを思いつきました。私がしたいことをしてください。これは単なる概念実証 (コードの後で詳しく説明します) であるため、完全ではないかもしれませんが、この分野で働く将来の Perl の人々にとって役立つ参考になるかもしれないと考えたので、以下に示します。

#!/usr/bin/perl

use Convert::BER;
use Convert::BER qw(/^(\$|BER_)/);

my $ber = Convert::BER->new();

# OID I want to add to the trap if not already present
my $snmpTrapAddress = '1.3.6.1.6.3.18.1.3';

# this would be from the incoming socket in production
my $source_ip = '10.137.54.253';

# convert the octets into chars to match SNMP standard for IPs
my $source_ip_str = join('', map { chr($_); } split(/\./, $source_ip));

# Read the binary trap data from STDIN or ARGV.  Normally this would
# come from the UDP receiver
my $d = join('', <>);

# Stuff my trap data into $ber
$ber->buffer($d);

print STDERR "Original packet:\n";
$ber->dump();

# Just decode the first two fields so we can tell what version we're dealing with
$ber->decode(
                SEQUENCE => [
                    INTEGER => \$version,
                    STRING => \$community,
                    BER => \$rest_of_trap,
                ],
) || die "Couldn't decode packet: ".$ber->error()."\n";

if ($version == 0) {
  #print STDERR "This is a version 1 trap, proceeding\n";

  # decode the PDU up to but not including the VARBINDS
  $rest_of_trap->decode(
    [ SEQUENCE => BER_CONTEXT | BER_CONSTRUCTOR | 0x04 ] =>
      [
        OBJECT_ID => \$enterprise_oid,
        [ STRING => BER_APPLICATION | 0x00 ] => \$agentaddr,
        INTEGER => \$generic,
        INTEGER => \$specific,
        [ INTEGER => BER_APPLICATION | 0x03 ] => \$timeticks,
        SEQUENCE => [ BER => \$varbind_ber, ],
      ],
  ) || die "Couldn't decode packet: ".$extra->error()."\n";;

  # now decode the actual VARBINDS (just the OIDs really, to decode the values
  # We'd have to go to the MIBs, which I neither want nor need to do
  my($r, $t_oid, $t_val, %varbinds);
  while ($r = $varbind_ber->decode(
    SEQUENCE => [
      OBJECT_ID => \$t_oid,
      ANY       => \$t_val,
    ], ))
  {
    if (!$r) {
      die "Couldn't decode SEQUENCE: ".$extra->error()."\n";
    }
    $varbinds{$t_oid} = $t_val;
  }

  if ($varbinds{$snmpTrapAddress} || $varbinds{"$snmpTrapAddress.0"}) {
    # the original trap already had the data, just print it back out
    print $d;
  } else {
    # snmpTrapAddress isn't present, create a new object and rebuild the packet
    my $new_trap = new Convert::BER;
    $new_trap->encode(
      SEQUENCE => [
        INTEGER => $version,
        STRING => $community,
        [ SEQUENCE => BER_CONTEXT | BER_CONSTRUCTOR | 0x04 ] =>
          [
            OBJECT_ID => $enterprise_oid,
            [ STRING => BER_APPLICATION | 0x00 ] => $agentaddr,
            INTEGER => $generic,
            INTEGER => $specific,
            [ INTEGER => BER_APPLICATION | 0x03 ] => $timeticks,
            SEQUENCE => [
              BER => $varbind_ber,
              # this next oid/val is the only mod we should be making
              SEQUENCE => [
                OBJECT_ID => "$snmpTrapAddress.0",
                [ STRING => BER_APPLICATION | 0x00 ] => $source_ip_str,
              ],
            ],
          ],
      ],
    );
    print STDERR "New packet:\n";
    $new_trap->dump();
    print $new_trap->buffer;
  }
} else {
  print STDERR "I don't know how to decode non-v1 packets yet\n";
  # send back the original packet
  print $d;  
}

それで、それだけです。これがキッカーです。私は彼らがトラップで元の送信者の IP を取得していないという彼らの言葉に反対しました。この例に取り組んでいるうちに、少なくとも彼らがくれた例では、元の IP がトラップの agent-addr フィールドにあることがわかりました。これと、ツールの API のどこでこれを使用していることが公開されているかを示した後、彼らは自分たちの側で変更を加えようとしました。私は実際にパケットをいじる必要があるものを彼らが私に尋ねたときに、上記のコードを作成していますが、今のところ、上記は厳密にテストされていない概念実証コードのままです. いつか誰かの役に立てば幸いです。

于 2009-07-15T18:49:41.067 に答える
2

NSNMPを試しましたか？

于 2009-07-15T10:05:10.770 に答える
2

必ずSNMP_Sessionをチェックしてください。

http://code.google.com/p/snmp-session/

いくつかの例がある古い配布サイトへのリンクを必ずたどってください。

私は基本的に、Mon::SNMP、Convert::BER、TCP/IP Illustrated などを通じて同じ道をたどりました。SNMP_Session は、私が機能させることができた唯一のものです。仕事では、UDP ポート 162 で SNMP トラップを受け入れ、それをログに相当する文字列にデコードし、いくつかの車輪を再発明する必要はありません。私は受信トラップ機能のみを使用していますが、あなたが望むこともできると思います。

ただし、CPAN ではなく Google Code にあるため、見つけるのは少し難しいです。

于 2009-10-31T10:27:46.020 に答える