0

さて、私はExcelにユーザーフォームがあり、フォームに「IMEITextBox」というテキストボックスがあります。在庫のあるColoum BにIMEI番号が記載された在庫シートがあります。IMEITextBoxにIMEI番号を入力すると、保存時にそのIMEI番号を含む行をシート「在庫」から削除したい。私はこれを何日も何度も研究してきました。私のために働くものを見つけることができないようです。お手伝いできますか？

Sub DeleteRows(IMEI)

Dim ws As Worksheet
Dim lastRow As Long, i As Long
Dim strSearch As String
Dim aCell As Range

On Error GoTo Err
Set ws = Sheets("Inventory")
lastRow = ws.Range("IMEIRange" & Rows.Count).End(xlUp).Row
strSearch = IMEITextBox.Value
Set aCell = ws.Range("IMEIRange" & lastRow).Find(What:=strSearch, LookIn:=xlValues, _
LookAt:=xlPart, SearchOrder:=xlByRows, SearchDirection:=xlNext, _
MatchCase:=False, SearchFormat:=False)
If Not aCell Is Nothing Then
  ws.Rows(lastRow).Delete
End If
Exit Sub
Err:
MsgBox Err.Description

End Sub
4

1 に答える 1

1

コードを理解するのに問題がないように、コードにコメントを付けました...コードを見た後、あなたは非常に親しかったことに気付くでしょう;)

Option Explicit

Sub DeleteRows()
    Dim ws As Worksheet
    Dim strSearch As String
    Dim aCell As Range

    On Error GoTo Err

    '~~> Set the sheet where you want to search the IMEI
    Set ws = Sheets("Inventory")

    With ws
        '~~> Get the value which you want to search
        strSearch = IMEITextBox.Value

        '~~> Column A is Column 1 so Column B is 2. This is where we are searching
        '~~> xlWhole is used in the code below so that we find a complete match
        '~~> xlPart is supposed to be used when you are finding a partial match.
        Set aCell = .Columns(2).Find(What:=strSearch, LookIn:=xlValues, _
        LookAt:=xlWhole, SearchOrder:=xlByRows, SearchDirection:=xlNext, _
        MatchCase:=False, SearchFormat:=False)

        '~~> Check if we found the value
        If Not aCell Is Nothing Then
            '~~> get the row of the cell where we found the match and delete it
            .Rows(aCell.Row).Delete
        Else '<~~ If not found
            MsgBox "IMEI Number not Found"
        End If
    End With

    Exit Sub
Err:
    MsgBox Err.Description
End Sub
于 2012-06-29T21:02:40.597 に答える