2

xslt を使用して、GPX ファイル (XML) 内の要素nameとcmtの値を交換しようとしています。

<?xml version="1.0" encoding="UTF-8" standalone="no"?>
<gpx xmlns="http://www.topografix.com/GPX/1/1" creator="GPS TrackMaker" version="1.1" xmlns:xsi="http://www.w3.org/2001/XMLSchema-instance" xsi:schemaLocation="http://www.topografix.com/GPX/1/1 http://www.topografix.com/GPX/1/1/gpx.xsd">
    <metadata>
        <link href="http://www.trackmaker.com">
            <text>Geo Studio Tecnology Ltd</text>
        </link>
        <time>2012-06-29T21:53:25Z</time>
        <bounds minlat="37.772562" minlon="-124.550080" maxlat="49.323978" maxlon="-122.404474"/>
    </metadata>
    <wpt lat="46.189580000" lon="-123.824460000">
        <ele>0.000000</ele>
        <name>G02010</name>
        <cmt>Columbia River Maritime Museum</cmt>
        <desc>Columbia River Maritime Museum</desc>
        <sym>Museum</sym>
    </wpt>
    <wpt lat="46.189010000" lon="-123.824370000">
        <ele>0.000000</ele>
        <name>G02020</name>
        <cmt>Marine Dr/17th St</cmt>
        <desc>Marine Dr/17th St</desc>
        <sym>Waypoint</sym>
    </wpt>
</gpx>

変換後:

...
<name>Columbia River Maritime Museum</name>
<cmt>G02010</cmt>
...

誰かがこれの正しい xslt を表示できますか? ありがとう。

4

1 に答える 1

2

これらの要素の値をオーバーライドして、Identity Transform を使用します。

<xsl:stylesheet version="1.0" xmlns:xsl="http://www.w3.org/1999/XSL/Transform"
    xmlns:gpx="http://www.topografix.com/GPX/1/1">
    <xsl:template match="@*|node()">
        <xsl:copy>
            <xsl:apply-templates select="@*|node()"/>
        </xsl:copy>
    </xsl:template>
    <xsl:template match="gpx:name/text()">
        <xsl:value-of select="../../gpx:cmt/text()"/>
    </xsl:template>
    <xsl:template match="gpx:cmt/text()">
        <xsl:value-of select="../../gpx:name/text()"/>
    </xsl:template>
</xsl:stylesheet>

text()実際のニーズ (またはソース入力) がより複雑な場合は、要素を直接 (の代わりに) 一致させることもできることに注意してください。

それは次のようになります。

<xsl:stylesheet version="1.0" xmlns:xsl="http://www.w3.org/1999/XSL/Transform"
    xmlns:gpx="http://www.topografix.com/GPX/1/1">
    <xsl:template match="@*|node()">
        <xsl:copy>
            <xsl:apply-templates select="@*|node()"/>
        </xsl:copy>
    </xsl:template>
    <xsl:template match="gpx:name">
        <xsl:copy>
            <xsl:apply-templates select="@*|../gpx:cmt/text()"/>
        </xsl:copy>
    </xsl:template>
        <xsl:template match="gpx:cmt">
        <xsl:copy>
            <xsl:apply-templates select="@*|../gpx:name/text()"/>
        </xsl:copy>
    </xsl:template>
</xsl:stylesheet>

これはもう少し一般的な解決策ですが、提供された入力を考えると、最初の解決策で十分です。

于 2012-06-30T03:35:21.880 に答える