0

プロキシを使用して、インターネットをサーフィンしている IP を autoit ブラウザでマスクしたいと思います。これは私のコードです:

#NoTrayIcon
#include <GUIConstants.au3>
#Include <IE.au3>
#include <GUIConstantsEx.au3>
GUICreate("Web Browser By EMP£!!",800,600)
GUISetBkColor(0x808080)
GUISetState(@SW_SHOW)
$Edit=GUICtrlCreateInput("http://www.whatismyip.com/",20,20,500,20)
$Vai=GUICtrlCreateButton("SURF!!!",600,10,150,50)
$oIE = ObjCreate("Shell.Explorer.2")
GUICtrlCreateObj($oIE, 10, 90,780, 500)
$ret = HttpSetProxy(2,"61.163.78.51:3128")
If $ret == 0 Then
    MsgBox(0, "Proxy", "Proxy Error")
    Exit
EndIf
While 1
 $msg=GUIGetMsg()
     Switch $msg
     Case $Vai
$Link=GUICtrlRead($Edit)
_IENavigate($oIE,($Link))
   GUICtrlSetData($Edit,$Link)
  Case $GUI_EVENT_CLOSE
   Exit
       EndSwitch
WEnd

http://www.whatismyip.com/にアクセスすると、実際の IP アドレスが表示されます。プロキシを非表示にしたい！

4

1 に答える 1

1

このHttpSetProxy機能は でのみ使用できInetGetます。Internet Explorer の設定とは関係ありません。Internet Explorer ウィンドウのプロキシを作成するには、Internet Explorer の設定を変更する必要があります。

私がそれを行う方法は次のようなものです：

#include <GUIConstants.au3>
#include <IE.au3>
#include <GUIConstantsEx.au3>

Global Const $sInetSettingsKey = "HKCU\Software\Microsoft\Windows\CurrentVersion\Internet Settings"

GUICreate("Web Browser By EMP£!!", 800, 600)
GUISetBkColor(0x808080)
GUISetState(@SW_SHOW)
$Edit = GUICtrlCreateInput("http://www.whatismyip.com/", 20, 20, 500, 20)
$Vai = GUICtrlCreateButton("SURF!!!", 600, 10, 150, 50)
$oIE = ObjCreate("Shell.Explorer.2")
GUICtrlCreateObj($oIE, 10, 90, 780, 500)

MySetProxy("61.163.78.51:3128")

While 1
    $msg = GUIGetMsg()
    Switch $msg
        Case $Vai
            $Link = GUICtrlRead($Edit)
            _IENavigate($oIE, ($Link))
            GUICtrlSetData($Edit, $Link)
        Case $GUI_EVENT_CLOSE
            ExitLoop
    EndSwitch
WEnd

MySetProxy()

Func MySetProxy($sProxy = "", $fEnable = True)
    Local Static $sPrev = ""
    Local Static $fWasEnabled = False

    If $sProxy = "" Then
        If $sPrev <> "" Then __setProxyInfo($fWasEnabled, $sPrev)
    Else
        If $sPrev = "" Then
            $sPrev = RegRead($sInetSettingsKey, "ProxyServer")
            $fWasEnabled = RegRead($sInetSettingsKey, "ProxyEnable")
        EndIf

        __setProxyInfo($fEnable, $sProxy)
    EndIf
EndFunc

Func __setProxyInfo($fEnabled, $sProxy)
    RegWrite($sInetSettingsKey, "ProxyEnable", "REG_DWORD", 1)
    RegWrite($sInetSettingsKey, "ProxyServer", "REG_SZ", $sProxy)
EndFunc

whatismyip.comあまり好きではありませんでしたが。しかし、IP アドレスは確実に変更されました。

于 2012-07-01T15:53:43.813 に答える