2

私の入力XMLは、次のもので構成されています。

<root>
    <entry>
        <type>U</type>
        <value>111</value>
    </entry>
    <entry>
        <type>X</type>
        <value>222</value>
    </entry>
    <entry>
        <type>E</type>
        <value>333</value>
    </entry>
    <entry>
        <type>Q</type>
        <value>444</value>
    </entry>
    <entry>
        <value>555</value>
    </entry>
    <entry>
        <value>666</value>
    </entry>
</root>

出力が必要です、

<ROOT>
    <ENTRY>
        <SLNO>1</SLNO>
        <VALUE>111</VALUE>
    </ENTRY>
    <ENTRY>
        <SLNO>1</SLNO>
        <VALUE>222</VALUE>
    </ENTRY>
    <ENTRY>
         <SLNO>1</SLNO>
         <VALUE>333</VALUE>
    </ENTRY>
    <ENTRY>
        <SLNO>2</SLNO>
        <VALUE>444</VALUE>
    </ENTRY>
    <ENTRY>
        <SLNO>3</SLNO>
        <VALUE>555<VALUE>
    </ENTRY>
    <ENTRY>
        <SLNO>4</SLNO>
        <VALUE>666</VALUE>
    </ENTRY>
</ROOT>

要件は、X、E、Y、およびK以外のタイプに対して、またタイプタグ自体が欠落している場合に、新しいSLNOを生成することです。他のすべてのタイプについては、新しいシリアル番号を表示する必要があります。

別の値でさらに処理を行う必要があるため、for-each to for the sameを作成しました。したがって、for-eachは必須です。

どうすればこれを達成できますか？

私のサンプルXSLコードは次のとおりです。

<xsl:for-each select="/ROOT/ENTRY">
    <xsl:if test="(TYPE != 'X') and (TYPE != 'E')">             
        <xsl:text><![CDATA[<SLNO>]]></xsl:text>


        <xsl:if test="((type != 'X') and (type != 'E') and (type != 'Y') and (type != 'K'))">
            <xsl:value-of select="count(preceding::type[((. != 'X' and . != 'E' and . != 'Y' and . !='K') or . ='')]) + 1" /> 
        </xsl:if>                                                               

        <xsl:if test="(type = 'X') or (type = 'E') or (type = 'Y') or (type = 'K')">
            <xsl:value-of select="count(preceding::type[(. != 'X' and . != 'E' and . != 'Y' and . !='K')])" />                                                        
        </xsl:if>



        <xsl:text><![CDATA[</SLNO>]]></xsl:text>
    </xsl:if>
    <!-- Printing remaining values -->
</xsl:for-each>

このコードの問題は、typeタグがないエントリのSLNOを取得できないことです。

助けてください。

4

3 に答える 3

3

警告：

この質問で提供されているコードは、構文的に正当なXSLTではありません<xsl:type-of>。この言語にはXSLT命令はありません。

また、このコードは、要素タグを開いたり閉じたりするように見えるテキストを生成します。

要素を生成したいときは、そのようなことは絶対にしないでください-テストはマークアップではありません-それはただ...テキストです。; 生成された出力は、希望どおりではありません。

解決策：

この変換：

<xsl:stylesheet version="1.0"
 xmlns:xsl="http://www.w3.org/1999/XSL/Transform">
 <xsl:output omit-xml-declaration="yes" indent="yes"/>
 <xsl:strip-space elements="*"/>

 <xsl:template match="node()|@*">
     <xsl:copy>
       <xsl:apply-templates select="node()|@*"/>
     </xsl:copy>
 </xsl:template>

 <xsl:template match="entry">
  <entry>
   <slno>
    <xsl:value-of select=
     "count((.
            |
              preceding-sibling::entry)
               [not(type)
               or
                not(contains('+X+E+Y+K+', concat('+', type, '+')))
                ]
            )"/>
    </slno>
    <xsl:apply-templates select="node()[not(self::type)]"/>
  </entry>
 </xsl:template>
</xsl:stylesheet>

提供されたXMLドキュメントに適用した場合：

<root>
    <entry>
        <type>U</type>
        <value>111</value>
    </entry>
    <entry>
        <type>X</type>
        <value>222</value>
    </entry>
    <entry>
        <type>E</type>
        <value>333</value>
    </entry>
    <entry>
        <type>Q</type>
        <value>444</value>
    </entry>
    <entry>
        <value>555</value>
    </entry>
    <entry>
        <value>666</value>
    </entry>
</root>

必要な正しい結果を生成します。

<root>
   <entry>
      <slno>1</slno>
      <value>111</value>
   </entry>
   <entry>
      <slno>1</slno>
      <value>222</value>
   </entry>
   <entry>
      <slno>1</slno>
      <value>333</value>
   </entry>
   <entry>
      <slno>2</slno>
      <value>444</value>
   </entry>
   <entry>
      <slno>3</slno>
      <value>555</value>
   </entry>
   <entry>
      <slno>4</slno>
      <value>666</value>
   </entry>
</root>
于 2012-07-02T12:45:06.833 に答える
1
  • XML要素の出力に使用しないでください。<xsl:text><![CDATA[<SLNO>]]></xsl:text>これまで。これは悪いことと間違っていることです（そしてそれは醜いですが、醜いことはここでは議論すらありません）。
  • 使用しないでください<xsl:for-each>。使用<xsl:template>/<xsl:apply-templates>
  • 有利に使用できtranslate()ます。以下を参照してください。警告このショートカットは、1文字のタイプがある場合にのみ機能します。
  • これらの要素名を本当に大文字にする必要があるかどうかを考えてください。これは私には必要な変更のようには見えません。IDテンプレートを使用できるため、元のケースを保持する方がはるかに簡単です。Dimitreの回答も参照してください。

このスタイルシート：

<xsl:stylesheet version="1.0" xmlns:xsl="http://www.w3.org/1999/XSL/Transform"> 
  <xsl:output indent="yes" />

  <xsl:template match="root">
    <ROOT>
      <xsl:apply-templates select="entry" />
    </ROOT>
  </xsl:template>

  <xsl:template match="entry">
    <ENTRY>
      <SLNO>
        <xsl:value-of select="
          count(
            (. | preceding-sibling::entry)[not(type and translate(type, 'EKXY', '') = '')]
          )
        " />
      </SLNO>
      <xsl:apply-templates select="value" />
    </ENTRY>
  </xsl:template>

  <xsl:template match="value">
    <VALUE>
      <xsl:value-of select="." />
    </VALUE>
  </xsl:template>
</xsl:stylesheet>

生成：

<ROOT>
  <ENTRY>
    <SLNO>1</SLNO>
    <VALUE>111</VALUE>
  </ENTRY>
  <ENTRY>
    <SLNO>1</SLNO>
    <VALUE>222</VALUE>
  </ENTRY>
  <ENTRY>
    <SLNO>1</SLNO>
    <VALUE>333</VALUE>
  </ENTRY>
  <ENTRY>
    <SLNO>2</SLNO>
    <VALUE>444</VALUE>
  </ENTRY>
  <ENTRY>
    <SLNO>3</SLNO>
    <VALUE>555</VALUE>
  </ENTRY>
  <ENTRY>
    <SLNO>4</SLNO>
    <VALUE>666</VALUE>
  </ENTRY>
</ROOT>
于 2012-07-02T12:45:49.970 に答える
0

あなたの小切手で

(TYPE != 'X') and (TYPE != 'E')

TYPEノードを持たないENTRYノードには「OR」ステートメントを含める必要があります。

何かのようなもの

((TYPE != 'X') and (TYPE != 'E')) or count(TYPE) = 0
于 2012-07-02T12:16:01.473 に答える