1

ここでは、6 つのハッシュのキーを比較して、すべてのハッシュに共通するキーを見つけます。次に、各ハッシュの値を新しいハッシュの 1 つの値に結合します。私がやりたいことは、これをスケーラブルにすることです。コードに戻って変更することなく、3 つのハッシュを 100 と簡単に比較できるようにしたいと考えています。これを達成する方法について何か考えはありますか？コードの残りの部分は、さまざまな入力量に対して既に正常に機能していますが、これは私が立ち往生している部分の 1 つです。

my $comparison = List::Compare->new([keys %{$posHashes[0]}], [keys %{$posHashes[1]}], [keys %{$posHashes[2]}], [keys %{$posHashes[3]}], [keys %{$posHashes[4]}], [keys %{$posHashes[5]}]);
my %comboHash;
for ($comparison->get_intersection) {
$comboHash{$_} = ($posHashes[0]{$_} . $posHashes[1]{$_} . $posHashes[2]{$_} . $posHashes[3]{$_} . $posHashes[4]{$_} . $posHashes[5]{$_});
}
4

4 に答える 4

1 
my %all;
for my $posHash (@posHashes) {
   for my $key (keys(%$posHash)) {
      push @{ $all{$key} }, $posHash->{$key};
   }
}

my %comboHash;
for my $key (keys(%all)) {
   next if @{ $all{$key} } != @posHashes;
   $comboHash{$key} = join('', @{ $all{$key} });
}
于 2012-07-03T23:20:29.620 に答える
0

サブルーチンを作成してハッシュ参照を渡すだけです

my $combination = combine(@posHashes);

sub combine {
    my @hashes = @_;
    my @keys;
    for my $href (@hashes) {
        push @keys, keys %$href;
    }
    # Insert intersection code here..
    # .....
    my %combo;
    for my $href (@hashes) {
        for my $key (@intersection) {
            $combo{$key} .= $href->{$key};
        }
    }
    return \%combo;
}
于 2012-07-03T23:21:02.973 に答える
0

非常に簡単な解決策があります：

sub merge {
    my $first = shift;
    my @hashes = @_;
    my %result;
    KEY:
    for my $key (keys %$first) {
        my $accu = $first->{$key};
        for my $hash (@hashes) {
            next KEY unless exists $hash->{$key};
            $accu .= $hash->{$key};
        }
        $result{$key} = $accu;
    }
    return \%result;
}

ハッシュへの参照でそれを呼び出す必要があり、ハッシュ参照も返します。

my $comboHashRef = merge(@posHashes);
于 2012-07-04T21:04:36.570 に答える
0

サブルーチンを作成します。

sub combine_hashes {
  my %result = ();
  my @hashes = @_;
  my $first = shift @hashes;
  for my $element (keys %$first) {
    my $count = 0;
    for my $href (@hashes) {
      $count += (grep {$_ eq $element} (keys %$href));
    }
    if ($count > $#hashes) {
      $result{$element} = $first->{$element};
      $result{$element} .= $_->{$element} for @hashes;
    }
  }
  \%result;
}

そしてそれを次のように呼び出します：

my %h = %{combine_hashes(\%h1, \%h2, \%h3)};

...または次のように:

my %h = %{combine_hashes(@posHashes)};
于 2012-07-03T23:06:29.677 に答える