2

この XML を変換しようとしています :-

<list>
  <unit>
    <data1>a</data1>
    <data2>b</data2>
    <data3>c</data3>
  </unit>
</list>

これに:-

<list>
  <unit>
    <category1>
      <data1>a</data1>
      <data2>b</data2>
    </category1>
    <category2>
      <data3>c</data3>
    </category2>
  </unit>
</list>

XSL を使用します。私は次のXSLを使用しています:-

<xsl:stylesheet version="1.0" xmlns:xsl="http://www.w3.org/1999/XSL/Transform"
 xmlns:s="some_namespace">


<xsl:template match="@*|node()">
  <xsl:copy>
    <xsl:apply-templates select="@*|node()" />
  </xsl:copy>
</xsl:template>

<xsl:template match="//s:unit" xml:space="preserve">
  <xsl:copy>
  <category1>
    <xsl:apply-templates select="./s:data1"/>
    <xsl:apply-templates select="./s:data2"/>
  </category1>
  <category2>
    <xsl:apply-templates select="./s:data3"/>
  </category2>
  </xsl:copy>
</xsl:template>

</xsl:stylesheet>

さて、これはインデントを保持しますが、リストを完全に台無しにします。これは私が得るものです:-

  <list>
<unit>
  <category1>
    <data1>a</data1>
    <data2>b</data2>
  </category1>
  <category2>
    <data3>c</data3>
  </category2>
</unit>
  </list>

ここで何が欠けていますか？

4

1 に答える 1

5

ここで何が欠けていますか？

XSLT プロセッサのデフォルトのインデントをいじるべきではないと思います。

ほとんどの場合、良好なインデントを得るには、 と の組み合わせで十分です<xsl:output indent="yes"/>。<xsl:strip-space elements="*"/>

この変換:

<xsl:stylesheet version="1.0"
 xmlns:xsl="http://www.w3.org/1999/XSL/Transform">
 <xsl:output omit-xml-declaration="yes" indent="yes"/>
 <xsl:strip-space elements="*"/>

 <xsl:template match="node()|@*">
  <xsl:copy>
   <xsl:apply-templates select="node()|@*"/>
  </xsl:copy>
 </xsl:template>

 <xsl:template match="unit">
  <unit>
      <category1>
       <xsl:apply-templates select="*[not(position() >2)]"/>
      </category1>
      <category2>
       <xsl:apply-templates select="*[position() >2]"/>
      </category2>
  </unit>
 </xsl:template>
</xsl:stylesheet>

提供された XML ドキュメントに適用した場合:

<list>
      <unit>
        <data1>a</data1>
        <data2>b</data2>
        <data3>c</data3>
      </unit>
</list>

必要な、十分にインデントされた結果を生成します。

<list>
  <unit>
    <category1>
      <data1>a</data1>
      <data2>b</data2>
    </category1>
    <category2>
      <data3>c</data3>
    </category2>
  </unit>
</list>

次の 7 つの XSLT プロセッサのいずれかで変換を実行すると、これと同じ結果が生成されます。

  • AltovaXML (XML-SPY)。

  • .NET XslCompiledTransform.

  • .NET XslTransform.

  • サクソン 6.5.4。

  • Saxon 9.1.05 (XSLT 2.0 プロセッサ)。

  • XQSharp/XMLPrime (XSLT 2.0 プロセッサ)。

  • AltovaXml (XSLT 2.0 用)。

MSXML3/4/6 の場合はより複雑です。これらの XSLT プロセッサのインデントは改行文字だけで構成されているため、すべての要素が改行されますが、行の先頭に表示されます。

これらの XSLT プロセッサでは、次の 2 パス処理を使用します。最初のパスは上記の変換であり、2 番目のパスは最初のパスの結果に適用されます。Nikolai Grigoriev によって提案され、維持されているXSLT FAQサイトで利用可能なXML プリティ プリンターの 1 つです。デイブ・ポーソン著：

<xsl:stylesheet version="1.0"
 xmlns:xsl="http://www.w3.org/1999/XSL/Transform"
 xmlns:ext="urn:schemas-microsoft-com:xslt"
 exclude-result-prefixes="ext">
 <xsl:output method="xml"/>
 <xsl:strip-space elements="*"/>

 <xsl:param name="indent-increment" select="'   '" />

 <xsl:variable name="vrtfPass1">
  <xsl:apply-templates select="/*"/>
 </xsl:variable>

 <xsl:variable name="vPass1" select="ext:node-set($vrtfPass1)"/>

 <xsl:template match="node()|@*">
  <xsl:copy>
   <xsl:apply-templates select="node()|@*"/>
  </xsl:copy>
 </xsl:template>

 <xsl:template match="/">
  <xsl:apply-templates select="$vPass1/*" mode="pass2"/>
 </xsl:template>


 <xsl:template match="unit">
  <unit>
      <category1>
       <xsl:apply-templates select="*[not(position() >2)]"/>
      </category1>
      <category2>
       <xsl:apply-templates select="*[position() >2]"/>
      </category2>
  </unit>
 </xsl:template>

  <xsl:template match="*" mode="pass2">
     <xsl:param name="indent" select="'&#xA;'"/>

     <xsl:value-of select="$indent"/>
     <xsl:copy>
       <xsl:copy-of select="@*" />
       <xsl:apply-templates mode="pass2">
         <xsl:with-param name="indent"
              select="concat($indent, $indent-increment)"/>
       </xsl:apply-templates>
       <xsl:value-of select="$indent"/>
     </xsl:copy>
  </xsl:template>

  <xsl:template match="comment()|processing-instruction()" mode="pass2">
     <xsl:copy />
  </xsl:template>

  <!-- WARNING: this is dangerous. Handle with care -->
  <xsl:template match="text()[normalize-space(.)='']" mode="pass2"/>

</xsl:stylesheet>

この変換が同じ (提供された) XML ドキュメント (上記) に対して実行されると、生成された結果には目的のインデントが含まれます。

<?xml version="1.0" encoding="UTF-16"?>
<list>
   <unit>
      <category1>
         <data1>a
         </data1>
         <data2>b
         </data2>
      </category1>
      <category2>
         <data3>c
         </data3>
      </category2>
   </unit>
</list>

これらはすべて、コンピューターに搭載されている XSLT プロセッサです。最後の変換を試してみることをお勧めします。Xalan-C で必要な結果が得られる可能性があります。

注意してください:

最後の変換では、MSXML 固有の名前空間に属する MSXML 固有の拡張関数 xxx:node-set() を使用します。

xmlns:ext="urn:schemas-microsoft-com:xslt"

Xalan の場合、これを次のように置き換える必要があります。

xmlns:ext="http://exslt.org/common"

または、EXSLT がサポートされていない場合は、ネイティブの Xalan 名前空間:

xmlns:ext="http://xml.apache.org/xalan

この最後のケースでは、ext:node-set()関数の呼び出しを次の呼び出しに置き換える必要がありますext:nodeset()(ダッシュがないことに注意してください)。

 <xsl:variable name="vPass1" select="ext:nodeset($vrtfPass1)"/>
于 2012-07-12T02:47:58.020 に答える