1

一部を無視したいファイルがあります。Lexer では、ゲーテッド セマンティック述語を使用して、ファイルの重要でない部分のトークンを作成しないようにしています。私のルールは次のようなものです。

A 
: {!ignore}?=> 'A' 
;
START_IGNORE
: 'foo' {ignore = true; skip();}
;
END_IGNORE
: 'oof' {ignore = false; skip();}
;
IGNORE
: {ignore}?=> . {skip();}
;    

ただし、(以下のように) セマンティック述語も使用するように START と END を変更しない限り、機能しません。

A 
: {!ignore}?=> 'A' 
;
START_IGNORE
: {true}?=> 'foo' {ignore = true; skip();}
;
END_IGNORE
: {true}?=> 'oof' {ignore = false; skip();}
;    
IGNORE
: {ignore}?=> . {skip();}
;  

なぜ述語を追加する必要があるのですか?

編集:私はantlr-3.4を使用しています

4

1 に答える 1

1

なぜ述語を追加する必要があるのですか?

あなたはそうしない。少なくとも、ANTLR v3.3 は使用していません。どのようにテストしているのか正確にはわかりませんが、ANTLRWorks のインタープリターや Eclipse ANTLR IDE プラグインは使用しないでください。常にコマンド ラインから少しテストを行います。

grammar T;

@parser::members {
  public static void main(String[] args) throws Exception {
    TLexer lexer = new TLexer(new ANTLRStringStream("A foo A B C oof A"));
    TParser parser = new TParser(new CommonTokenStream(lexer));
    parser.parse();
  }
}

@lexer::members {
  private boolean ignore = false;
}

parse
 : (t=. 
     {System.out.printf("[\%02d] type=\%s text='\%s'\n", $t.getCharPositionInLine(), tokenNames[$t.type], $t.text);}
   )* EOF
 ;

A 
 : {!ignore}?=> 'A' 
 ;

START_IGNORE
 : 'foo' {ignore = true; skip();}
 ;

END_IGNORE
 : 'oof' {ignore = false; skip();}
 ;

IGNORE
 : {ignore}?=> . {skip();}
 ;    

SPACE
 : ' ' {skip();}
 ;

次のように実行します。

java -cp antlr-3.3.jar org.antlr.Tool Tg
javac -cp antlr-3.3.jar *.java
java -cp .:antlr-3.3.jar TParser

次のように出力されます。

[00] タイプ=A テキスト='A'
[16] type=A text='A'

つまり、入力"A foo A B C oof A"から次のようになり"foo A B C oof"ますskip

于 2012-07-09T18:54:38.920 に答える