0

というファイルがありますlistofvalues.txt。ファイルには 1000 行以上、5 列あります。

1,232,3434,54343,434343  
1,232,100,4546,3456  
1,122,45454,4546,3456  
2,212,334,5555,4654  
...  
...

列 1 と 2 が等しい場合、3 列目の値を合計し、次のように結果をファイルに出力したい

1,232,3534,54343,434343  
1,122,45454,4546,3456  
2,212,334,5555,4654  
....  
.........  
.........  
......

どうすれば Perl でできると思いますか? 私は Perl を初めて使用するので、実行するのが難しいと感じています。

4

4 に答える 4

3

このプログラムは、一意のキー@dataを持つすべてのレコードのリストを含む配列を維持することによって機能します。column1|column2ファイルで初めて新しいキーが検出されると、完全なレコードがスタックにプッシュされます。その後の各エンカウンターは、レコードの3番目のフィールドを元の値に追加するだけです。

ハッシュは、キーのそれぞれの異なる値に対応する%data要素への参照を維持します。@data

use strict;
use warnings;

open my $fh, '<', 'listofvalues.txt' or die $!;

my @data;
my %data;

while (<$fh>) {
  chomp;
  my @record = split /,/;
  my $key = join '|', @record[0,1];
  if ($data{$key}) {
    $data{$key}[2] += $record[2];
  }
  else {
    push @data, ($data{$key} = \@record);
  }
}

print join(',', @$_), "\n" for @data;

出力

1,232,3534,54343,434343  
1,122,45454,4546,3456  
2,212,334,5555,4654

アップデート

ワンラインソリューション

perl -F, -ane '$k="@F[0,1]";$s{$k}?$s{$k}[2]+=$F[2]:do{push@d,$k;$s{$k}=[@F]};END{$\"=',';print"@{$s{$_}}"for@d}' listofvalues.txt
于 2012-07-15T16:16:30.560 に答える
1

ここに別のワンライナーがあります：

  perl -F, -lane '

  BEGIN { $, = "," }

  if(defined(@A)) {
    if($A[0] == $F[0] and $A[1] == $F[1]) {
      $A[3] +=  $F[3];
    } else {
      print @A;
      @A = (@F);
    }
  } else {
    @A = (@F);
  }

  END { print @A }' listofvalues.txt

perlrun(1)スイッチの意味については、を参照してください。

于 2012-07-15T17:11:14.947 に答える
0

col4 または col5 を処理しませんが、データベース アプローチを試すことができます。

#!/usr/bin/perl
use strict;
use warnings;
use DBI;

my $dbh = DBI->connect("DBI:CSV:");
$dbh->{'csv_tables'}->{'data'} = { 'file' => 'o33.txt',
    'col_names' => [qw/col1 col2 col3 col4 col5/]};

my $sql = <<SQL;
select col1, col2, SUM(col3)
from data
group by col1, col2
order by col1, col2
SQL

my $sth = $dbh->prepare( $sql );
$sth->execute;

{
    local $" = ',';
    while ( my $row = $sth->fetchrow_arrayref ) {
        print "@$row\n";
    }
}

__END__
C:\Old_Data\perlp>type o33.txt
1,232,3434,54343,434343
1,232,100,4546,3456
1,122,45454,4546,3456
2,212,334,5555,4654

C:\Old_Data\perlp>perl t3.pl
1,122,45454
1,232,3534
2,212,334
于 2012-07-15T20:29:11.017 に答える
0

ワンライナーでできるからといって、そうするべきだというわけではありません;）

$ perl -F',' -lane '
push @order, [ @F[0,1] ]
  unless $seen{$F[0]}{$F[1]}++; # Preserve order
$total{$F[0]}{$F[1]} += $F[2];  # Sum up
$value{$F[0]}{$F[1]} = join ',' => @F[0,1], $total{$F[0]}{$F[1]}, @F[3..$#F];
} END {
    print $value{$_->{0]}{$_->[1]} for @order;
' file.txt
于 2012-07-15T16:23:48.400 に答える