delphi - Windows領域（HRGN）の面積をピクセル単位で計算するにはどうすればよいですか？

Question

任意のWindows領域の領域を取得する最速の方法は何ですか？

長方形の境界のすべての点を列挙して関数を呼び出すことができることは知っていPtInRegion()ますが、それほど速くはないようです。多分あなたはいくつかのより速い方法を知っていますか？

Answer 1

を呼び出すとGetRegionData、領域を構成する重複しない長方形のリストが表示されます。次のように、領域を合計します。

function GetRegionArea(rgn: HRgn): Cardinal;
var
  x: DWord;
  Data: PRgnData;
  Header: PRgnDataHeader;
  Rects: PRect;
  Width, Height: Integer;
  i: Integer;
begin
  x := GetRegionData(rgn, 0, nil);
  Win32Check(x <> 0);
  GetMem(Data, x);
  try
    x := GetRegionData(rgn, x, Data);
    Win32Check(x <> 0);
    Header := PRgnDataHeader(Data);
    Assert(Header.iType = rdh_Rectangles);

    Assert(Header.dwSize = SizeOf(Header^));
    Rects := PRect(Cardinal(Header) + Header.dwSize);
    // equivalent: Rects := PRect(@Data.Buffer);

    Result := 0;
    for i := 0 to Pred(Header.nCount) do begin
      Width := Rects.Right - Rects.Left;
      Height := Rects.Bottom - Rects.Top;
      Inc(Result, Width * Height);
      Inc(Rects);
    end;
  finally
    FreeMem(Data);
  end;
end;