6

範囲の列数を返そうとしています。1つの範囲が必要な場合もありますが、複数の範囲が必要な場合もあります。

複数の範囲を選択できるように、オプションの範囲を設定しました。スプレッドシートで提供していない関数プロトタイプの範囲を参照すると、＃Valueが得られます。エラー。

オプションの範囲がnull、void emptyなどであるかどうかを確認する方法が必要なので、範囲を参照する必要はありません。

これはVBA関数プロトタイプです：-

Function GetColoumnCount(ARange1 As Range, Optional ARange2 As Range, Optional ARange3 As Range, Optional ARange4 As Range) As Integer

    Dim Result As Integer
    Result = 0

    Result = ARange1.Columns.Count ' This works
    Result = ARange1.Columns.Count + ARange2.Columns.Count ' This doesn't work

    GetColoumnCount = Result    
End Function

私のスプレッドシートでは、関数を機能させるためにこれをセルに入力する必要があります。
=GetColoumnCount(BC34:BK34, BC35:BD35, BE35:BF35, BG35:BH35)
これは、オプションの引数を持つという目的を無効にします。

4

2 に答える 2

3

このようにしてみてください

Function GetColoumnCount(ARange1 As Range, Optional ARange2 As Range, Optional ARange3 As Range, Optional ARange4 As Range) As Long  
    Dim Result As Long
    Result = 0

    Result = ARange1.Columns.Count ' This works
    If Not ARange2 Is Nothing Then
        Result = Result + ARange2.Columns.Count
    End If

    GetColoumnCount = Result    
End Function
于 2012-07-19T02:54:32.603 に答える
1

引数に ParamArray キーワードを使用すると、可変数の引数を指定できます。

Public Function GetColumnCount(ParamArray Ranges() As Variant) As Long

    Dim lReturn As Long
    Dim i As Long
    Dim rResult As Range
    Dim rArea As Range

    'Loop through the Ranges array supplied by ParamArray
    For i = LBound(Ranges) To UBound(Ranges)
        'Only work with those array members that are ranges
        If TypeName(Ranges(i)) = "Range" Then
            'Use Union to combine all the ranges
            If rResult Is Nothing Then
                Set rResult = Ranges(i)
            Else
                Set rResult = Application.Union(rResult, Ranges(i))
            End If
        End If
    Next i

    'Loop through the Areas and add up the columns
    If Not rResult Is Nothing Then
        For Each rArea In rResult.Areas
            lReturn = lReturn + rArea.Columns.Count
        Next rArea
    End If

    GetColumnCount = lReturn

End Function

使用するには:

=getcolumncount(E2:K18) = 7
=getcolumncount(D4:L14,N4:P14) =12 (9+3)
=getcolumncount(C7:F15,H7:L15,K7:N15) =11 (omits double counting overlap)
于 2012-07-19T13:29:12.903 に答える