10

任意のモジュールがあるとします

module Foo where
foo :: Moo -> Goo
bar :: Car -> Far
baz :: Can -> Haz

、foo、barおよびbazが正しく実装されている場合など。

このモジュールを、自動生成されたデータ型と対応するオブジェクトに具体化したいと思います。

import Foo (Moo, Goo, Car, Far, Can, Haz)
import qualified Foo

data FooModule = Foo
  { foo :: Moo -> Goo
  , bar :: Car -> Far
  , baz :: Can -> Haz
  }

_Foo_ = Foo
  { foo = Foo.foo
  , bar = Foo.bar
  , baz = Foo.baz
  }

名前は元のモジュールと正確に同じでなければなりません。

これを手動で行うこともできますが、それは非常に面倒なので、このタスクを実行するためのコードを書きたいと思います。

そのようなタスクにアプローチする方法がよくわかりません。Template Haskell はモジュールを検査する方法を提供しますか? GHC api にフックする必要がありますか? それとも、ハドック ページをスクレイピングするなど、よりアドホックなアプローチでうまくいくでしょうか?

4

1 に答える 1

3

(これは GHC-7.4.2 用です。おそらく HEAD や 7.6 ではコンパイルされないでしょう。これは、いくつかの変更が原因ですOutputable)。THでモジュールを検査するものは何も見つかりませんでした。

{-# LANGUAGE NoMonomorphismRestriction #-}
{-# OPTIONS -Wall #-}
import GHC
import GHC.Paths -- ghc-paths package
import Outputable
import GhcMonad

main :: IO ()
main = runGhc (Just libdir) $ goModule "Data.Map"

goModule :: GhcMonad m => String -> m ()
goModule modStr = do
  df <- getSessionDynFlags
  _ <- setSessionDynFlags df  
  -- ^ Don't know if this is the correct way, but it works for this purpose

  setContext [IIDecl (simpleImportDecl (mkModuleName modStr))]
  infos <- mapM getInfo =<< getNamesInScope 
  let ids = onlyIDs infos
  liftIO . putStrLn . showSDoc . render $ ids 

onlyIDs :: [Maybe (TyThing, Fixity, [Instance])] -> [Id]
onlyIDs infos = [ i | Just (AnId i, _, _) <- infos ] 

render :: [Id] -> SDoc
render ids = mkFields ids $$ text "------------" $$ mkInits ids 

mkFields :: [Id] -> SDoc
mkFields = vcat . map (\i ->
  text "," <+> pprUnqual i <+> text "::" <+> ppr (idType i))

mkInits :: [Id] -> SDoc
mkInits = vcat . map (\i ->
  text "," <+> pprUnqual i <+> text "=" <+> ppr i)


-- * Helpers

withUnqual :: SDoc -> SDoc
withUnqual  = withPprStyle (mkUserStyle neverQualify AllTheWay)

pprUnqual :: Outputable a => a -> SDoc
pprUnqual = withUnqual . ppr
于 2012-07-20T12:35:53.310 に答える