xslt - XSLTカウントコンマ値カウント

Question

xmlにinteger="1,2,3,4,5"のような値があります。XSLTを使用して総数をカウントするにはどうすればよいですか。出力が私に5のカウントを与えるように

よろしく、サム

Answer 1

カンマ区切り値をカウントしたいが、個々のアイテムを参照することもできる場合は、そのような再帰テンプレートを使用できます。

このXSLT1.0スタイルシートは、コンマ区切り値をノードに変換してから、それらをカウントします...

<xsl:stylesheet version="1.0"
  xmlns:xsl="http://www.w3.org/1999/XSL/Transform"
  xmlns:msxsl="urn:schemas-microsoft-com:xslt">
<xsl:output method="text"/>

<xsl:template match="/">
 <xsl:variable name="as-nodes"> 
  <xsl:call-template name="parse-comma-separated-values">
   <xsl:with-param name="csv" select="t/@csv" />
  </xsl:call-template>
  </xsl:variable>
  <xsl:value-of select="count(msxsl:node-set($as-nodes)/*)" />
</xsl:template>

<xsl:template name="parse-comma-separated-values">
 <xsl:param name="csv" />
 <xsl:choose>
   <xsl:when test="$csv = ''"/>
   <xsl:when test="not( contains( $csv, ','))">
     <value-node value="{$csv}" /> 
   </xsl:when>  
   <xsl:otherwise>
     <value-node value="{substring-before($csv,',')}" /> 
     <xsl:call-template name="parse-comma-separated-values">
      <xsl:with-param name="csv" select="substring-after($csv,',')"/>
     </xsl:call-template>  
   </xsl:otherwise>  
  </xsl:choose>  
</xsl:template>

</xsl:stylesheet>

...この入力ドキュメントに適用された場合..。

 <t csv="1,2,3,4,5"/>

...生成します...

 5

Answer 2

これが1つの方法です（他の方法があるかもしれません）。すべてのコンマを空の文字列に変換し、文字列の長さの違いを比較するだけです。

<xsl:value-of 
   select="string-length(@integer) 
           - string-length(translate(@integer, ',', '')) + 1" />

空の文字列を処理する必要がある場合は、代わりにこれを試してください

<xsl:value-of 
  select="string-length(@integer) 
          - string-length(translate(@integer, ',', '')) 
          + 1 * (string-length(@integer) != 0)" />