83 
Sub test()

thesentence = InputBox("Type the filename with full extension", "Raw Data File")

Range("A1").Value = thesentence

If Dir("thesentence") <> "" Then
    MsgBox "File exists."
Else
    MsgBox "File doesn't exist."
End If

End Sub

これで、入力ボックスからテキスト値を取得すると、機能しません。"the sentence"ただし、 Ifから削除Dir()してコード内の実際の名前に置き換えると、機能します。誰かが助けることができますか？

4

9 に答える 9

147

コードに含まれている必要があることに注意してDir("thesentence")くださいDir(thesentence)。

コードをこれに変更します

Sub test()

thesentence = InputBox("Type the filename with full extension", "Raw Data File")

Range("A1").Value = thesentence

If Dir(thesentence) <> "" Then
    MsgBox "File exists."
Else
    MsgBox "File doesn't exist."
End If

End Sub
于 2012-07-20T06:31:26.213 に答える
19

OfficeFileDialogオブジェクトを使用して、ユーザーにファイルシステムからファイルを選択させます。VBプロジェクトまたはVBAエディターに参照を追加してMicrosoft Office Library、ヘルプを参照してください。これは、人々にフルパスを入力させるよりもはるかに優れています。

msoFileDialogFilePickerこれは、ユーザーが複数のファイルを選択できるようにするために使用する例です。を使用することもできますmsoFileDialogOpen。

'Note: this is Excel VBA code
Public Sub LogReader()
    Dim Pos As Long
    Dim Dialog As Office.FileDialog
    Set Dialog = Application.FileDialog(msoFileDialogFilePicker)

    With Dialog
        .AllowMultiSelect = True
        .ButtonName = "C&onvert"
        .Filters.Clear
        .Filters.Add "Log Files", "*.log", 1
        .Title = "Convert Logs to Excel Files"
        .InitialFileName = "C:\InitialPath\"
        .InitialView = msoFileDialogViewList

        If .Show Then
            For Pos = 1 To .SelectedItems.Count
                LogRead .SelectedItems.Item(Pos) ' process each file
            Next
        End If
    End With
End Sub

たくさんのオプションがあるので、可能なことすべてを理解するために完全なヘルプファイルを見る必要があります。Office 2007のFileDialogオブジェクトから始めることができます（もちろん、使用しているバージョンの正しいヘルプを見つける必要があります）。

于 2012-07-20T07:19:07.450 に答える
18

@UberNubIsTrueからのfileExistsの修正：

Function fileExists(s_directory As String, s_fileName As String) As Boolean

  Dim obj_fso As Object, obj_dir As Object, obj_file As Object
  Dim ret As Boolean
   Set obj_fso = CreateObject("Scripting.FileSystemObject")
   Set obj_dir = obj_fso.GetFolder(s_directory)
   ret = False
   For Each obj_file In obj_dir.Files
     If obj_fso.fileExists(s_directory & "\" & s_fileName) = True Then
        ret = True
        Exit For
      End If
   Next

   Set obj_fso = Nothing
   Set obj_dir = Nothing
   fileExists = ret

 End Function

編集：短縮版

' Check if a file exists
Function fileExists(s_directory As String, s_fileName As String) As Boolean

    Dim obj_fso As Object

    Set obj_fso = CreateObject("Scripting.FileSystemObject")
    fileExists = obj_fso.fileExists(s_directory & "\" & s_fileName)

End Function
于 2013-05-29T19:14:21.173 に答える
6

それらのスピーチマークを取り除くだけです

Sub test()

Dim thesentence As String

thesentence = InputBox("Type the filename with full extension", "Raw Data File")

Range("A1").Value = thesentence

If Dir(thesentence) <> "" Then
    MsgBox "File exists."
Else
    MsgBox "File doesn't exist."
End If

End Sub

これは私が好きなものです：

Option Explicit

Enum IsFileOpenStatus
    ExistsAndClosedOrReadOnly = 0
    ExistsAndOpenSoBlocked = 1
    NotExists = 2
End Enum


Function IsFileReadOnlyOpen(FileName As String) As IsFileOpenStatus

With New FileSystemObject
    If Not .FileExists(FileName) Then
        IsFileReadOnlyOpen = 2  '  NotExists = 2
        Exit Function 'Or not - I don't know if you want to create the file or exit in that case.
    End If
End With

Dim iFilenum As Long
Dim iErr As Long
On Error Resume Next
    iFilenum = FreeFile()
    Open FileName For Input Lock Read As #iFilenum
    Close iFilenum
    iErr = Err
On Error GoTo 0

Select Case iErr
    Case 0: IsFileReadOnlyOpen = 0 'ExistsAndClosedOrReadOnly = 0
    Case 70: IsFileReadOnlyOpen = 1 'ExistsAndOpenSoBlocked = 1
    Case Else: IsFileReadOnlyOpen = 1 'Error iErr
End Select

End Function    'IsFileReadOnlyOpen
于 2012-07-21T13:52:19.590 に答える
6 
Function FileExists(fullFileName As String) As Boolean
    FileExists = VBA.Len(VBA.Dir(fullFileName)) > 0
End Function

ほとんど、私のサイトでは非常にうまく機能します。空の文字列を""で呼び出すと、Dirは" connection.odc "を返します!! あなたたちがあなたの結果を共有することができれば素晴らしいでしょう。

とにかく、私はこれが好きです：

Function FileExists(fullFileName As String) As Boolean
  If fullFileName = "" Then
    FileExists = False
  Else
    FileExists = VBA.Len(VBA.Dir(fullFileName)) > 0
  End If
End Function
于 2015-10-22T11:12:25.500 に答える
4 
Function FileExists(fullFileName As String) As Boolean
    FileExists = VBA.Len(VBA.Dir(fullFileName)) > 0
End Function
于 2015-06-14T02:09:10.607 に答える
3

特にコードの何が問題になっているのかはわかりませんが、オンラインで見つけたこの関数（コメントのURL）を使用して、ファイルが存在するかどうかを確認します。 

Private Function File_Exists(ByVal sPathName As String, Optional Directory As Boolean) As Boolean
    'Code from internet: http://vbadud.blogspot.com/2007/04/vba-function-to-check-file-existence.html
    'Returns True if the passed sPathName exist
    'Otherwise returns False
    On Error Resume Next
    If sPathName <> "" Then

        If IsMissing(Directory) Or Directory = False Then

            File_Exists = (Dir$(sPathName) <> "")
        Else

            File_Exists = (Dir$(sPathName, vbDirectory) <> "")
        End If

    End If
End Function
于 2012-07-20T06:31:32.290 に答える
1

非常に古い投稿ですが、いくつかの変更を加えた後、それが私を助けてくれたので、私は共有したいと思いました。ディレクトリが存在するかどうかを確認する場合は、vbDirectory引数をDir関数に追加する必要があります。追加しない場合は、0毎回戻ります。（編集：これはロイの答えに応えたものですが、私は誤ってそれを通常の答えにしました。）

Private Function FileExists(fullFileName As String) As Boolean
    FileExists = Len(Dir(fullFileName, vbDirectory)) > 0
End Function
于 2018-12-19T03:55:27.877 に答える
1

ここでの他の回答に基づいて、dirsとfilesで機能するはずのワンライナーを共有したいと思います：

  • Len(Dir(path)) > 0 or Or Len(Dir(path, vbDirectory)) > 0  'version 1 - ... <> "" should be more inefficient generally
    • （Len(Dir(path))ディレクトリでは機能しませんでした（Excel 2010 / Win7））
  • CreateObject("Scripting.FileSystemObject").FileExists(path)  'version 2 - could be faster sometimes, but only works for files (tested on Excel 2010/Win7)

関数としてPathExists(path)：

Public Function PathExists(path As String) As Boolean
    PathExists = Len(Dir(path)) > 0 Or Len(Dir(path, vbDirectory)) > 0
End Function
于 2019-08-12T09:21:58.347 に答える