2

この XML を使用して、項目を 1 つのカテゴリに表示し、グループの見出しの下にグループ化する必要があります。空のグループは表示されません (たとえば、カテゴリが x に等しい場合、グループ C の見出しは表示されません。カテゴリ z とグループ A および B も同様です)。

<group name="A">
  <item name="A1" category="x"/>
  <item name="A2" category="x"/>
  <item name="A3" category="y"/>
</group>
<group name="B">
  <item name="B1" category="x"/>
</group>
<group name="C">
  <item name="C1" category="y"/>
  <item name="C2" category="z"/>
</group>

空のグループを表示することはできないため、項目を $items に既にフィルター処理しています。このセットは、グループ化をレンダリングするテンプレートにパラメーターとして渡します (以下を参照)。このテンプレートでは、グループ化ごとにテンプレートを呼び出して、現在のグループ内の項目をレンダリングする必要があります。

<xsl:template name="groups">

  <!-- This is already filtered by category -->
  <xsl:param name="items" />

  <!-- Select only the groups that should be displayed -->
  <xsl:for-each select="$items/parent::group">
    <h1><xsl:value-of select="./@name"/></h1>

    <!-- Display all filtered items in this group -->
    <div class="items">
      <xsl:call-template name="items">
        <!-- How can I get the items from $items for the current group? -->
        <xsl:with-param name="partners" select="$items..."/>
      </xsl:call-template>
    </div>

  </xsl:for-each>
</xsl:template>

テンプレートparamに渡すには何を選択すればよいですか?items

すべてのアイテムを表示するテンプレート:

<xsl:template name="items">
  <xsl:param name="items" />

  <xsl:for-each select=".">
    <div class="item">
      <xsl:value-of select="./@name" />
    </div>
  </xsl:for-each>
</xsl:template>

カテゴリ z でフィルタリングした場合の最終結果は次のようになります。

<h1>C</h1>
<div class="items">
  <div class="item">C2</div>
</div>
4

1 に答える 1

0

この変換により、すべてのカテゴリで望ましい結果が得られます。

<xsl:stylesheet version="1.0"
 xmlns:xsl="http://www.w3.org/1999/XSL/Transform">
 <xsl:output omit-xml-declaration="yes" indent="yes"/>
 <xsl:strip-space elements="*"/>

 <xsl:key name="kCatByVal" match="@category" use="."/>
 <xsl:key name="kGroupByCat" match="group" use="item/@category"/>
 <xsl:key name="kItemByGroupAndCat" match="item"
  use=" concat(generate-id(..), '+', @category)"/>

 <xsl:variable name="vDistCats" select=
  "/*/*/*/@category
            [generate-id() = generate-id(key('kCatByVal', .)[1])]"/>

 <xsl:template match="/*">
   <xsl:apply-templates select="$vDistCats"/>
 </xsl:template>

 <xsl:template match="@category">
 <h1>Category <xsl:value-of select="."/></h1>
  <xsl:apply-templates select="key('kGroupByCat', .)">
   <xsl:with-param name="pCat" select="."/>
  </xsl:apply-templates>
 </xsl:template>

 <xsl:template match="group">
  <xsl:param name="pCat"/>
  <h1><xsl:value-of select="@name"/></h1>
  <div class="items">
   <xsl:apply-templates select=
    "item
      [generate-id()
      =
       generate-id(key('kItemByGroupAndCat',
                        concat(generate-id(..), '+', $pCat)
                        )
                    )]"/>
  </div>
 </xsl:template>

 <xsl:template match="item">
  <div class="item"><xsl:value-of select="@name"/></div>
 </xsl:template>
</xsl:stylesheet>

提供された XML ドキュメントに適用すると (すべての重大な不正が修正された状態で):

<t>
    <group name="A">
        <item name="A1" category="x"/>
        <item name="A2" category="x"/>
        <item name="A3" category="y"/>
    </group>
    <group name="B">
        <item name="B1" category="x"/>
    </group>
    <group name="C">
        <item name="C1" category="y"/>
        <item name="C2" category="z"/>
    </group>
</t>

必要な正しい結果が生成されます。

<h1>Category x</h1>
<h1>A</h1>
<div class="items">
   <div class="item">A1</div>
</div>
<h1>B</h1>
<div class="items">
   <div class="item">B1</div>
</div>
<h1>Category y</h1>
<h1>A</h1>
<div class="items">
   <div class="item">A3</div>
</div>
<h1>C</h1>
<div class="items">
   <div class="item">C1</div>
</div>
<h1>Category z</h1>
<h1>C</h1>
<div class="items">
   <div class="item">C2</div>
</div>

これはブラウザに次のように表示されます。

カテゴリ x

あ

A1

B

B1

カテゴリy

あ

A3

ハ

C1

カテゴリーz

ハ

C2
于 2012-07-27T12:44:14.577 に答える