6

私はさまざまな学校のプロジェクトで、Java、javaEE、c ++、python、PHP用のEclipseプラットフォームを使用しています。もう少し慣れてきたので、設定方法についてもう少し正確な手順を説明したいと思います。私はwindows7を使用しています-日食自体をDropboxにドロップし、必要に応じてワークスペースを作成しましたが、これはあちこちに広がる設定の混乱とさまざまなバグ（Junoに更新しようとしたときに表示されました-現在の機能テンプレートのように壊れています）。

では、さまざまな言語で日食を設定するための推奨される方法は何ですか？最新のリリースをダウンロードし、必要なプラグイン（cdt、pdtなど）を追加してから、言語ごとに異なるワークスペース（eclipse_python、eclipse_java、eclipse_javaEEなど）を作成する必要がありますか？Eclipseをどのように設定しますか？

4

1 に答える 1

4

私は約6年間、Eclipseを集中的に使用しています。最大で、1つまたは2つの異なるプログラミング言語用に個別のEclipseインストールをセットアップすることをお勧めします。その理由は、プラグインが多すぎると、Eclipseがメモリやプロセッサ時間を消費しすぎて（もちろん、プラグインがバックグラウンドで何をするかなどによって）、UIが応答しなくなる可能性があるためです。

また、異なる構成/インストールが互いに干渉しないように、Eclipseのインストールごとに別々のワークスペースを使用することをお勧めします。

ポータブルドライブ（ホームとポータブルの2つのモードをサポート）で使用するためにワークスペースの.metadataディレクトリを切り替えることができる小さなコマンドラインスクリプトを作成しました。

@ECHO OFF

REM This Script is used to ease using eclipse in a portable manner
REM The script allows to easily switch between several workspace metadata

REM arg1: eclipse runnable
REM arg2: workspace dir
REM arg3: metadata mode (portable or home)

:CHECK_ARG_ONE
IF %1 == "" GOTO :HELP
IF /i %1 == "/h" GOTO :HELP
IF /i %1 == "/?" GOTO :HELP
IF /i %1 == "/help" GOTO :HELP
IF /i %1 == "-h" GOTO :HELP
IF /i %1 == "-?" GOTO :HELP
IF /i %1 == "-help" GOTO :HELP
IF /i %1 == "--h" GOTO :HELP
IF /i %1 == "--?" GOTO :HELP
IF /i %1 == "--help" GOTO :HELP


:CHECK_ARG_TWO
IF %2 == "" GOTO :ERROR_ARG_TWO


:CHECK_ARG_THREE
IF %3 == "" GOTO :ERROR_ARG_THREE


:PREPARE
SET "ECLIPSE_RUNNABLE=%1"
SET "WORKSPACE_DIR=%2"
ECHO Working Dir: %CD%
ECHO Eclipse Runnable: %ECLIPSE_RUNNABLE%
ECHO Workspace Dir: %WORKSPACE_DIR%
SET "MD=.metadata"
SET "MD_HOME=.metadata_home"
SET "MD_PORTABLE=.metadata_portable"
PUSHD %WORKSPACE_DIR%
IF /i %3 == home GOTO :HOME
IF /i %3 == portable GOTO :PORTABLE
GOTO :ERROR_ARG_THREE_WRONG


:HOME
ECHO Starting home version
IF EXIST %MD% (
    IF EXIST %MD_HOME% (
        IF EXIST %MD_PORTABLE% (
            GOTO :ERROR_MD_PORTABLE_EXISTS_ALREADY
        ) ELSE (
            REN %MD% %MD_PORTABLE%
            REN %MD_HOME% %MD%
        )
    )
) ELSE (
    IF NOT EXIST %MD_HOME% (
        GOTO :ERROR_MD_HOME_EXISTS_NOT
    ) ELSE (
        REN %MD_HOME% %MD%
    )
)
GOTO :RUN


:PORTABLE
ECHO Starting portable version
IF EXIST "%MD%" (
    IF EXIST "%MD_PORTABLE%" (
        IF EXIST "%MD_HOME%" (
            GOTO :ERROR_MD_HOME_EXISTS_ALREADY
        ) ELSE (
            REN "%MD%" %MD_HOME%
            REN "%MD_PORTABLE%" %MD%
        )
    )
) ELSE (
    IF NOT EXIST "%MD_PORTABLE%" (
        GOTO :ERROR_MD_PORTABLE_EXISTS_NOT
    ) ELSE (
        REN "%MD_PORTABLE%" %MD%
    )
)
GOTO :RUN


:ERROR_ARG_TWO
ECHO No second argument supplied (workspace dir)
GOTO :END_ERROR


:ERROR_ARG_THREE
ECHO No third argument supplied (metadata mode - home ^| portable)
GOTO :END_ERROR


:ERROR_ARG_THREE_WRONG
ECHO Supplied third argument (metadata mode) must match (home ^| portable)
GOTO :HELP


:ERROR_MD_HOME_EXISTS_ALREADY
ECHO Trying to rename "%MD%", but the metadata directory "%MD_HOME%" already exists!
GOTO :END_ERROR


:ERROR_MD_HOME_EXISTS_NOT
ECHO Neither "%MD%" nor "%MD_HOME%" exist!
GOTO :END_ERROR


:ERROR_MD_PORTABLE_EXISTS_ALREADY
ECHO Trying to rename "%MD%", but the metadata directory "%MD_PORTABLE%" already exists!
GOTO :END_ERROR


:ERROR_MD_PORTABLE_EXISTS_NOT
ECHO Neither "%MD%" nor "%MD_PORTABLE%" exist!
GOTO :END_ERROR


:HELP
ECHO.
ECHO Eclipse starter script to switch between home and portable metadata
ECHO ©Till Kolditz 2011 (till.kolditz@googlemail.com)
ECHO.
ECHO This Script is used to ease using eclipse in a portable manner.
ECHO It allows to easily switch between portable and "home" or stationary
ECHO workspace metadata.
ECHO.
ECHO Usage: run.bat (eclipse_runnable) (workspace_dir) (home ^| portable)
ECHO.
ECHO Example1: run.bat eclipse\eclipse.exe workspace home
ECHO Example2: run.bat "eclipse (x64)\eclipse.exe" workspace_special portable
GOTO :END


:RUN
POPD
START "Eclipse" %ECLIPSE_RUNNABLE% -data %WORKSPACE_DIR%
GOTO :END


:END_ERROR
POPD
REM PAUSE for debugging
PAUSE
GOTO :END


:END
GOTO :EOF
于 2012-07-29T14:29:56.053 に答える