1

以下の xml ドキュメントは、2、2、および 2 の 3 つの数字を表します。ノード<s>は数字としてカウントされ、 で終わり<zero/>ます。

    <?xml version="1.0" encoding="UTF-8"?>
    <nat xmlns:xsi="http://www.w3.org/2001/XMLSchema-instance" xsi:noNamespaceSchemaLocation="nat.xsd">
      <s>
        <s>
          <zero/>
        </s>
      </s>
      <s>
        <s>
          <zero/>
        </s>
      </s>
      <s>
        <s>
          <zero/>
        </s>
      </s>
    </nat>

xslt の学習を始めたばかりで、これは再帰の演習の 1 つです。すべての数値を合計するためにプラスを再帰的に実行することもできますが、この 2 を超える数値の乗算は私の心を吹き飛ばします。やり方がわかりません。

上記の xml doc の予想される答えは 8s です (形式は無視してください) :

<s><s><s><s><s><s><s><s><zero/></s></s></s></s></s></s></s></s> 私の考えはこれでした.2つの数値を加算することで乗算を行うテンプレートを持つことができます. したがって、この 2x2x2 では、4 を返す 2 番目の 2 倍の 3 番目の 2 を実行し、最後に 2*4 を実行します。ただし、java やスキームとは異なり、呼び出しテンプレートは xslt で値を返さないため、ヒントやヘルプをいただければ幸いです。

更新: Dimitre の回答に印刷テンプレートを追加して回答を得ました。ここにあります：

    <xsl:template name="print">
    <xsl:param name="pAccum"/>
        <xsl:choose>
            <xsl:when test="$pAccum > 0">
                <s>
                    <xsl:call-template name="print">
                        <xsl:with-param name="pAccum" select="$pAccum - 1"/>
                    </xsl:call-template>
                </s>
             </xsl:when>
             <xsl:otherwise>
                <zero/>
            </xsl:otherwise>    
        </xsl:choose>
</xsl:template>
4

2 に答える 2

1

この変換:

<xsl:stylesheet version="1.0"
 xmlns:xsl="http://www.w3.org/1999/XSL/Transform">
 <xsl:output omit-xml-declaration="yes" indent="yes"/>

 <xsl:template match="/">
  <xsl:call-template name="product">
   <xsl:with-param name="pArgs" select="//zero"/>
  </xsl:call-template>
 </xsl:template>

 <xsl:template name="product">
  <xsl:param name="pAccum" select="1"/>
  <xsl:param name="pArgs" select="/.."/>

  <xsl:choose>
   <xsl:when test="not($pArgs)">
    <xsl:value-of select="$pAccum"/>
   </xsl:when>
   <xsl:otherwise>
    <xsl:call-template name="product">
     <xsl:with-param name="pAccum"
          select="$pAccum * count($pArgs[1]/ancestor::s)"/>
     <xsl:with-param name="pArgs" select="$pArgs[position() > 1]"/>
    </xsl:call-template>
   </xsl:otherwise>
  </xsl:choose>
 </xsl:template>
</xsl:stylesheet>

提供された XML ドキュメントに適用した場合:

<nat>
    <s>
        <s>
            <zero/>
        </s>
    </s>
    <s>
        <s>
            <zero/>
        </s>
    </s>
    <s>
        <s>
            <zero/>
        </s>
    </s>
</nat>

必要な正しい結果が生成されます。

8

説明:

停止条件付きのプリミティブ再帰 -- 空の引数ノード セットとアキュムレータ - 現在蓄積されている結果を次の再帰呼び出しに渡すためのパラメーター。

于 2012-07-31T04:26:27.370 に答える
1

XSLT 2.0 では、関数のペアから始めます。

<xsl:function name="f:toNumber" as="xs:integer">
  <xsl:param name="z" as="element(zero)"/>
  <xsl:sequence select="count($z/ancestor::*)"/>
</xsl:function>

<xsl:function name="f:fromNumber" as="element()>
  <xsl:param name="z" as="xs:integer"/>
  <xsl:choose>
   <xsl:when test="$z=0"><zero/></xsl:when>
   <xsl:otherwise><s><xsl:sequence select="f:fromNumber($z - 1)"/>
</xsl:function>

それはあなたの数値表現の奇妙さに取り組みます。

ここで必要なのは、数列の積を計算する関数だけです。

<xsl:function name="f:product" as="xs:integer">
  <xsl:param name="in" as="xs:integer"/>
  <xsl:sequence select="if (count($in) = 1) then $in[1] else $in * f:product($in[position()>1])"/>
</xsl:function>

残りは子供の遊びです...

于 2012-07-31T16:19:00.123 に答える