4

こんにちは私は次のコードを書きました。

私の目的は、コマンドラインパラメーターが1つの要素を持つ配列であり、その要素が整数であるかどうかをチェックするgetWoeidという関数を作成することでした。

私のコードは機能します...しかし、TryParseメソッドを2回呼び出しています...これを1回だけ呼び出す方法があるのではないかと思います。

また、コマンドラインパラメータの検証にパターンマッチングを使用するこの方法が正しいかどうかを確認できますか？

open System;
open System.Xml;

let getWoeid args =   
  let retVal = 0
  match args with      
  | [|a|] when fst (Int32.TryParse(a)) = true -> 
      printfn "%s" "Starting the processing for woeid "
      Some(snd (Int32.TryParse(a)))      
  | _ -> failwith "Usage XmlRead WOEID"       

[<EntryPoint>]
let main args = 
  let woeid= 
    try   
      getWoeid args          
    with
      | Failure (msg) -> printfn "%s" msg; None

  0
4

2 に答える 2

13

アクティブなパターンを定義できます。

let (|Int|_|) s = 
    match System.Int32.TryParse s with
    | true, v -> Some v
    | _ -> None

let getWoeid args = 
    match args with
    | [|Int v|] -> Some v
    | _ -> None
于 2012-08-05T21:07:36.927 に答える
8

TryParseタプライズする代わりに、byrefパラメーターをに渡すこともできます。

let getWoeid args = 
  let mutable i = 0
  match args with
  | [|s|] when Int32.TryParse(s, &i) -> Some i
  | _ -> None
于 2012-08-06T14:13:41.007 に答える