0

Weekdayから特定のまでにどれくらいの時間がかかるか知りたいですNow。私はどこでも検索しましたが、実際には何も見つかりません。

DateDiffどういうわけか、-functionと-functionを一緒に使わなければならないと思いWeekDayます。

シナリオは次のとおりです。

曜日によって変数varWeekDayがあります。例：1/2/3/4/5/6/7

varStartTimeそして、時刻を含む別の変数：hh：mm

varStopTimeまた、時刻を含む最後の変数：hh：mm

if varWeekday = Weekday(now, 2) and varStartTime < formatdatetime(now, 4) then
  .... Write how long time till start in hours / minutes
elseif varWeekday = Weekday(now, 2) and varStartTime >= formatdatetime(now, 4) and varStopTime < formatdatetime(now, 4) then
  response.write("Already started!")
else
  .... Write how long time till start in days / hours / minutes
end if

「どのくらいの時間」は次のようになります：「今から2日3時間27分」

同じ出力が特定の日時から生成される必要があります。例：2012年6月8日23時55分は「今から1日13分」

私は本当にあなたたちが助けることができることを願っています！:)

4

1 に答える 1

1

開始時刻と終了時刻で何が必要かを完全には理解していませんでしたが、このスクリプトは、現在から特定の曜日の開始までの時間の長さを示します。

<%
Dim varNow : varNow = Now()
Dim varWeekday : varWeekday = 7 'This is the weekday to look for (1 is Sunday, 7 is Saturday)

'This next line sets the time to the start of the day
Dim varThisDate : varThisDate = DateSerial(Year(varNow), Month(varNow), Day(varNow))
Dim varThisWeekday
Do
    varThisDate = DateAdd("d", 1, varThisDate)
    varThisWeekday = Weekday(varThisDate)
    If varThisWeekday = varWeekday Then
        Exit Do
    End If
Loop

'These next lines just convert and display the remaining time into the different units
Response.Write("Until next " & WeekdayName(varWeekday) & "<br />")

Dim varSeconds : varSeconds = DateDiff("s", varNow, varThisDate)
Dim varDays : varDays = Int(varSeconds / 60 / 60 / 24)
varSeconds = varSeconds - (varDays * 24 * 60 * 60)
Dim varHours : varHours = Int(varSeconds / 60 / 60)
varSeconds = varSeconds - (varHours * 60 * 60)
Dim varMinutes : varMinutes = Int(varSeconds / 60)
varSeconds = varSeconds - (varMinutes * 60)

Response.Write("Days: " & varDays & "<br />")
Response.Write("Hours: " & varHours & "<br />")
Response.Write("Minutes: " & varMinutes & "<br />")
Response.Write("Seconds: " & varSeconds & "<br />")
%>
于 2012-08-06T05:05:09.750 に答える