xslt - カンマ区切りの文字列に基づいて複数の要素ブロックを作成するXSLT

Question

編集：私は解決策を持っていますが、もっと良い方法があると確信しています。下記を参照してください。

ソースXML：

<?xml version="1.0"?>
<reservations>
  <reservation>
    <id>1</id>
    <guestId>1111</guestId>
    <!-- other fields -->
  </reservation>
  <reservation>
    <id>2</id>
    <guestId>2222,3333,4444</guestId>
    <!-- other fields -->
  </reservation>
</reservations>

期待される出力：

<?xml version="1.0" encoding="UTF-8"?>
<reservations>
  <reservation>
    <id>1</id>
    <csvGuestString>1111</csvGuestString>
    <guestId>1111</guestId>
    <!-- other fields -->
  </reservation>
  <reservation>
    <id>2</id>
    <csvGuestString>2222,3333,4444</csvGuestString>
    <guestId>2222</guestId>
    <!-- other fields -->
  </reservation>
  <reservation>
    <id>2</id>
    <csvGuestString>2222,3333,4444</csvGuestString>
    <guestId>3333</guestId>
    <!-- other fields -->
  </reservation>
  <reservation>
    <id>2</id>
    <csvGuestString>2222,3333,4444</csvGuestString>
    <guestId>4444</guestId>
    <!-- other fields -->
  </reservation>
</reservations>

ルール：

1. <reservation>ゲストを持つ要素n（のコンマ区切り値で定義<guestId>）の場合、次のguestId値を使用するたびに、その要素をその子孫とともに何度も複製<reservation>します。n
2. 元の要素の値を保持し、新しい要素<guestId>に配置する必要があります。<csvGuestString>
3. XSLT1.0で実行する必要があります。
4. トークン化にEXSLTを使用するのは完全に合理的です。

私がこれまでに持っているもの（それは機能しますが、それが最も効率的な解決策であるかどうかの手がかりはありません）：

<?xml version="1.0"?>
<xsl:stylesheet
  xmlns:xsl="http://www.w3.org/1999/XSL/Transform"
  xmlns:exsl="http://exslt.org/common" 
  exclude-result-prefixes="exsl"
  version="1.0">

  <xsl:output method="xml" omit-xml-declaration="no" indent="yes"/>
  <xsl:strip-space elements="*"/>

  <xsl:variable name="vTokenName" select="'token'"/>
  <xsl:variable name="vDoc" select="/"/>

  <xsl:template match="node()|@*">
    <xsl:copy>
      <xsl:apply-templates select="node()|@*"/>
    </xsl:copy>
  </xsl:template>

  <xsl:template match="guestId">
    <csvGuestString>
      <xsl:apply-templates />
    </csvGuestString>   
  </xsl:template>

  <xsl:template match="reservation">
    <xsl:variable name="vGuestRtfPass1">
      <xsl:call-template name="tokenize">
        <xsl:with-param name="text" select="guestId"/>
        <xsl:with-param name="delimiter" select="','"/>
      </xsl:call-template>
    </xsl:variable>

    <xsl:apply-templates select="exsl:node-set($vGuestRtfPass1)/*" mode="pass2">
      <xsl:with-param name="pPosition" select="position()"/>
    </xsl:apply-templates>
  </xsl:template>

  <xsl:template match="token" mode="pass2">
    <xsl:param name="pPosition" />

    <reservation>
      <xsl:apply-templates select="$vDoc/*/reservation[$pPosition]/*" />
        <guestId>
          <xsl:apply-templates />   
        </guestId>
    </reservation>
  </xsl:template>

  <xsl:template name="tokenize">
    <xsl:param name="text"/>
    <xsl:param name="delimiter" select="' '"/>
    <xsl:choose>
      <xsl:when test="contains($text,$delimiter)">
        <xsl:element name="{$vTokenName}">
          <xsl:value-of select="substring-before($text,$delimiter)"/>
        </xsl:element>
        <xsl:call-template name="tokenize">
          <xsl:with-param name="text" select="substring-after($text,$delimiter)"/>
          <xsl:with-param name="delimiter" select="$delimiter"/>
        </xsl:call-template>
      </xsl:when>
      <xsl:when test="$text">
        <xsl:element name="{$vTokenName}">
          <xsl:value-of select="$text"/>
        </xsl:element>
      </xsl:when>
    </xsl:choose>
  </xsl:template>

</xsl:stylesheet>

いつものように、あなたの援助に感謝します。

Answer 1

tokenize()拡張関数を使用する必要はありません。この変換は、xxx:node-set()拡張機能を備えたXSLTプロセッサで実行できます。

<xsl:stylesheet version="1.0" xmlns:xsl="http://www.w3.org/1999/XSL/Transform"
 xmlns:ext="http://exslt.org/common" exclude-result-prefixes="ext">
 <xsl:output omit-xml-declaration="yes" indent="yes"/>
 <xsl:strip-space elements="*"/>

 <xsl:template match="@*|node()" name="identity">
  <xsl:copy>
    <xsl:apply-templates select="@*|node()"/>
  </xsl:copy>
 </xsl:template>

 <xsl:template match="reservation/guestId">
   <xsl:call-template name="identity"/>
  <csvGuestString><xsl:value-of select="."/></csvGuestString>
 </xsl:template>

 <xsl:template match="reservation[contains(guestId, ',')]" name="explode">
   <xsl:param name="pCurrent" select="."/>
   <xsl:param name="pLastId" select="substring-before($pCurrent/guestId, ',')"/>

   <xsl:variable name="vrtfResult">
     <xsl:apply-templates select="$pCurrent" mode="explode"/>
   </xsl:variable>
   <xsl:copy-of select="$vrtfResult"/>

   <xsl:variable name="vResult" select="ext:node-set($vrtfResult)/*"/>

   <xsl:if test="contains(substring-after($vResult/csvGuestString, $vResult/guestId), ',')">
     <xsl:call-template name="explode">
       <xsl:with-param name="pCurrent" select="$vResult"/>
       <xsl:with-param name="pLastId" select="$vResult/guestId"/>
     </xsl:call-template>
   </xsl:if>
 </xsl:template>

 <xsl:template match="node()" mode="explode">
  <xsl:call-template name="identity"/>
 </xsl:template>

 <xsl:template match="reservation" mode="explode">
  <xsl:copy>
   <xsl:apply-templates select="node()" mode="explode"/>
  </xsl:copy>
 </xsl:template>

 <xsl:template match="guestId[contains(.,',')]" mode="explode">
  <csvGuestString><xsl:value-of select="."/></csvGuestString>
  <guestId><xsl:value-of select="substring-before(., ',')"/></guestId>
 </xsl:template>

 <xsl:template match="guestId" mode="explode">
  <guestId>
    <xsl:value-of select="substring-before(substring-after(concat(../csvGuestString, ','), concat(current(),',')), ',')"/>
  </guestId>
 </xsl:template>
</xsl:stylesheet>

この変換が提供されたXMLドキュメントに適用される場合：

<reservations>
  <reservation>
    <id>1</id>
    <guestId>1111</guestId>
    <!-- other fields -->
  </reservation>
  <reservation>
    <id>2</id>
    <guestId>2222,3333,4444</guestId>
    <!-- other fields -->
  </reservation>
</reservations>

必要な正しい結果が生成されます。

<reservations>
  <reservation>
    <id>1</id>
    <guestId>1111</guestId>
    <csvGuestString>1111</csvGuestString>
    <!-- other fields -->
  </reservation>
  <reservation>
    <id>2</id>
    <csvGuestString>2222,3333,4444</csvGuestString>
    <guestId>2222</guestId>
    <!-- other fields -->
  </reservation>
  <reservation>
    <id>2</id>
    <csvGuestString>2222,3333,4444</csvGuestString>
    <guestId>3333</guestId>
    <!-- other fields -->
  </reservation>
  <reservation>
    <id>2</id>
    <csvGuestString>2222,3333,4444</csvGuestString>
    <guestId>4444</guestId>
    <!-- other fields -->
  </reservation>
</reservations>

Answer 2

tokenizeEXSLT文字列関数のメソッドを使用する：

<xsl:stylesheet version="1.0" xmlns:xsl="http://www.w3.org/1999/XSL/Transform"
  xmlns:str="http://exslt.org/strings"
  exclude-result-prefixes="str">

<xsl:strip-space elements="*"/>
<xsl:output indent="yes"/>

<xsl:template match="@* | node()">
  <xsl:copy>
    <xsl:apply-templates select="@* | node()"/>
  </xsl:copy>
</xsl:template>

<xsl:template match="reservation">
  <xsl:variable name="this" select="."/>
  <xsl:for-each select="str:tokenize(guestId, ',')" >
    <xsl:apply-templates select="$this" mode="copy">
      <xsl:with-param name="id" select="."/>
    </xsl:apply-templates>
  </xsl:for-each>
</xsl:template>

<xsl:template match="reservation" mode="copy">
  <xsl:param name="id"/>
  <xsl:copy>
    <xsl:apply-templates select="@*"/>
    <xsl:apply-templates select="node()">
      <xsl:with-param name="id" select="$id"/>
    </xsl:apply-templates>
  </xsl:copy>
</xsl:template>

<xsl:template match="reservation/guestId">
  <xsl:param name="id"/>
  <csvGuestString>
    <xsl:value-of select="."/>
  </csvGuestString>
  <guestId>
    <xsl:value-of select="$id"/>
  </guestId>
</xsl:template>

</xsl:stylesheet>

このようにして、xsltprocは入力サンプルをに変換します

<reservations>
  <reservation>
    <id>1</id>
    <csvGuestString>1111</csvGuestString>
    <guestId>1111</guestId>
    <!-- other fields -->
  </reservation>
  <reservation>
    <id>2</id>
    <csvGuestString>2222,3333,4444</csvGuestString>
    <guestId>2222</guestId>
    <!-- other fields -->
  </reservation>
  <reservation>
    <id>2</id>
    <csvGuestString>2222,3333,4444</csvGuestString>
    <guestId>3333</guestId>
    <!-- other fields -->
  </reservation>
  <reservation>
    <id>2</id>
    <csvGuestString>2222,3333,4444</csvGuestString>
    <guestId>4444</guestId>
    <!-- other fields -->
  </reservation>
</reservations>