0

私の目標は、ユーザーがいつすべてのキーボード ショートカットを切り取り、コピー、貼り付け、または選択したかを知り、それぞれに対して何らかの処理を行うことです。キープレスをリッスンしようとしましたが、コントロール キーが押されたときにいくつかのキーのみが起動されます (IE を除いて、ブラウザーでのみ機能するようです)。

次に、Flash ドキュメントを読んでいて、「現在フォーカスのあるオブジェクト」にディスパッチされるEvent.COPY、Event.PASTE、およびEvent.CUTイベントに遭遇しました。これらのイベントのドキュメント クラスにリスナーをアタッチし、stage.focus をドキュメント クラスに設定しましたが、イベント リスナーが呼び出されません。

これらのイベントを使用したことのある人はいますか? それらの使用方法の例はどこかにありますか?

注: これは Flash Player 10 にあります (内部 CS4 のもの ([ショートカットを無効にする] がオフになっているもの) とスタンドアロンのものの両方)。どのブラウザでも試したことはありません。

4

2 に答える 2

0

TextFieldsからそのようなイベントをキャプチャできないという制限に加えて（またはフォーカスがTextFieldにある場合）、stage.focusプロパティがリスナーをアタッチしたInteractiveObjectまたはその子のいずれかに実際に設定されていることを確認してください（テキストフィールドでない限り^^）。

フォーカスを設定するには、stage.focusプロパティを直接設定し、tabEnabledInteractiveObjectsをクリックまたはタブ移動する必要があることに注意してください。

于 2009-07-28T07:36:19.260 に答える
0

完全を期すために、「ホワイトリスト」のいくつかのオブジェクトにフォーカスを移動できるようにするために最終的に使用したクラスを次に示します。その後、ホワイトリストオブジェクトからフォーカスが失われたときにフォーカスをデフォルトオブジェクトに戻します(別のホワイトリスト オブジェクトに移動しない限り):


/*
Copyright (c) 2009, Cameron Desrochers
All rights reserved.

Redistribution and use in source and binary forms, with or without modification, are permitted
provided that the following conditions are met:

    * Redistributions of source code must retain the above copyright notice, this list of
      conditions and the following disclaimer.
    * Redistributions in binary form must reproduce the above copyright notice, this list
      of conditions and the following disclaimer in the documentation and/or other materials
      provided with the distribution.

THIS SOFTWARE IS PROVIDED BY THE COPYRIGHT HOLDERS AND CONTRIBUTORS "AS IS" AND 
ANY EXPRESS OR IMPLIED WARRANTIES, INCLUDING, BUT NOT LIMITED TO, THE IMPLIED 
WARRANTIES OF MERCHANTABILITY AND FITNESS FOR A PARTICULAR PURPOSE ARE 
DISCLAIMED. IN NO EVENT SHALL THE COPYRIGHT HOLDER OR CONTRIBUTORS BE LIABLE FOR 
ANY DIRECT, INDIRECT, INCIDENTAL, SPECIAL, EXEMPLARY, OR CONSEQUENTIAL DAMAGES 
(INCLUDING, BUT NOT LIMITED TO, PROCUREMENT OF SUBSTITUTE GOODS OR SERVICES; 
LOSS OF USE, DATA, OR PROFITS; OR BUSINESS INTERRUPTION) HOWEVER CAUSED AND ON 
ANY THEORY OF LIABILITY, WHETHER IN CONTRACT, STRICT LIABILITY, OR TORT 
(INCLUDING NEGLIGENCE OR OTHERWISE) ARISING IN ANY WAY OUT OF THE USE OF THIS 
SOFTWARE, EVEN IF ADVISED OF THE POSSIBILITY OF SUCH DAMAGE.
*/


package
{
    import fl.controls.ColorPicker;
    import flash.display.DisplayObject;
    import flash.display.InteractiveObject;
    import flash.display.DisplayObjectContainer;
    import flash.display.Sprite;
    import flash.display.Stage;
    import flash.events.Event;
    import flash.events.FocusEvent;
    import flash.events.MouseEvent;
    import flash.geom.Point;
    import flash.utils.Dictionary;



    public class FocusManager
    {
        public static var stage:Stage;
        public static var defaultFocalObject:DisplayObjectContainer;

        private static var _whiteList:Array = new Array();


        public static function init(stage:Stage, defaultFocalObject:DisplayObjectContainer):void
        {
            FocusManager.stage = stage;
            FocusManager.defaultFocalObject = defaultFocalObject;

            stage.addEventListener(MouseEvent.CLICK, onStageClicked);

            defaultFocalObject.addEventListener(FocusEvent.FOCUS_OUT, onObjectFocusOut);

            restoreDefaultFocus();
        }


        public static function restoreDefaultFocus():void
        {
            stage.focus = defaultFocalObject;
        }


        public static function addToWhiteList(object:InteractiveObject):void
        {
            if (Object(object).constructor == ColorPicker) {        // Special case
                // ColorPicker objects possess a textField that is for some reason not a child of the
                // ColorPicker, and so the textField has to be added separately.

                addToWhiteList(ColorPicker(object).textField);
            }

            _whiteList.push(object);

            object.addEventListener(FocusEvent.FOCUS_OUT, onObjectFocusOut);
            object.addEventListener(Event.REMOVED_FROM_STAGE, onObjectRemovedFromStage);
        }


        private static function onObjectFocusOut(e:FocusEvent):void
        {
            //trace('e.target:', e.target);
            //trace('e.relatedObject:', e.relatedObject);

            if ((e.relatedObject == null) || ((e.relatedObject !== defaultFocalObject) && (!whiteListContains(e.relatedObject)))) {
                // Object that is gaining focus is not in white-list, restore focus:

                //trace('restoring default focus');
                restoreDefaultFocus();
            }
        }


        private static function whiteListContains(object):Boolean
        {
            var inList:Boolean = false;

            for each (var listItem in _whiteList) {
                if ((object === listItem) || ((listItem.hasOwnProperty('contains')) && (listItem.contains(object)))) {
                    inList = true;
                    break;
                }
            }

            return inList;
        }


        private static function onObjectRemovedFromStage(e:Event):void
        {
            restoreDefaultFocus();
        }


        private static function onStageClicked(e:MouseEvent):void
        {
            var objectsUnderClick:Array = stage.getObjectsUnderPoint(new Point(stage.mouseX, stage.mouseY));

            var clickedOnWhiteListItem:Boolean = false;
            for each (var object in objectsUnderClick) {
                if (whiteListContains(object)) {
                    clickedOnWhiteListItem = true;
                    break;
                }
            }

            if (!clickedOnWhiteListItem) {
                restoreDefaultFocus();
            }
        }
    }
}

initドキュメント クラスのオブジェクトと、デフォルトでフォーカスを戻すオブジェクトを指定して静的メソッドを呼び出しstageます。addToWhitelist次に、静的メソッドを使用してホワイト リストにオブジェクトを追加します。

于 2009-08-11T19:48:21.610 に答える