0

Windows スケジューラで自動実行するプログラムがあります。このプログラムは、昨日の日付を使用するストアド プロシージャを実行し、データベースに対してクエリを実行して、前日の結果を取得します。このクエリは、結果を気にしないため、1 日を通して特定の期間を除外します。ただし、日曜日は営業時間が異なるため、日曜日のクエリを変更したいと考えています...「日曜日」の場合、別の方法でクエリを実行する方法はありますか? 以下は私のストアドプロシージャです：

CREATE PROCEDURE [dbo].[sp_Open_Close_Report_1] AS
declare   @dtNow         datetime ,   @dtToday       datetime ,   @dtFrom        datetime ,   @dtThru        datetime ,   @dtExcludeFrom datetime ,   @dtExcludeThru datetime, @dtExcludeEOD datetime 
set @dtNow         = getdate() 
set @dtToday       = convert(datetime,convert(varchar,@dtNow,112),112) 
set @dtFrom        = dateadd(day,-1,@dtToday) -- start-of-day yesterday 
set @dtThru        = dateadd(ms,-3,@dtToday)  -- end-of-day yesterday (e.g., 2012-06-17 23:59:59.997) 
set @dtExcludeFrom = convert(datetime, convert(char(10),@dtFrom,120) + ' 05:30:00.000' , 120 ) 
set @dtExcludeThru = convert(datetime, convert(char(10),@dtFrom,120) + ' 06:15:00.000' , 120 ) 
set @dtExcludeEOD = convert(datetime, convert(char(10),@dtFrom,120) + ' 08:00:00.000' , 120 ) 


SELECT Store_Id , DM_Corp_Received_Date, Register_Transaction_Type 
FROM Register_Till_Count_Tb 
WHERE (Register_Transaction_Type    =  'SOD' and store_ID = '12345'
AND DM_Corp_Received_date     between @dtFrom        
and @dtThru   
AND DM_Corp_Received_date not between @dtExcludeFrom 
and @dtExcludeThru) or (Register_Transaction_Type = 'EOD' and Store_ID='12345'
AND DM_Corp_Received_date Between @dtFrom and @dtThru)

日曜日の@DTExcludeFrom は 6:30 で、 7: @dtexcludeThru15 です。

4

2 に答える 2

2

文字列をいじるのではなく、すべてを日時 (または int) として保持して、さらに多くの計算を行います。

declare   @dtNow         datetime ,   @dtToday       datetime ,   @dtFrom        datetime ,   @dtThru        datetime ,   @dtExcludeFrom datetime ,   @dtExcludeThru datetime, @dtExcludeEOD datetime 
set @dtNow         = getdate() 
set @dtToday       = DATEADD(day,DATEDIFF(day,0,@dtNow),0)
set @dtFrom        = dateadd(day,-1,@dtToday)

declare @Sunday int
set @Sunday = CASE WHEN DATEPART(weekday,@dtFrom) = DATEPART(weekday,'20120805') THEN 1 ELSE 0 END
set @dtExcludeFrom = DATEADD(minute,330 + @Sunday * 60,@dtFrom)
set @dtExcludeThru = DATEADD(minute,375 + @Sunday * 60,@dtFrom)
set @dtExcludeEOD = DATEADD(minute,480,@dtFrom)

そして、あなたのクエリでは、以下を持っているのではなく:

column between @dtFrom and @dtThru

使用する：

column >= @dtFrom and column < @dtToday
于 2012-08-10T13:35:00.283 に答える
0

datenameと関数を見てくださいdatepart。ステートメントを使用ifして、その日の内容に基づいてさまざまなロジックを実行できます。日曜日に実行すると、次の結果が得られます。

select datename(dw, getdate()) -- Sunday
select datepart(dw, getdate()) -- 1
于 2012-08-10T13:28:23.330 に答える