1

XSL 変換を使用して、XML ドキュメント内の値の最初の出現のみを照合することは可能ですか?

f2 内のすべての値を出力したいのですが、f1 の内容の最初のインスタンスのみを出力します。

XML データ

    <doc> 
    <datum>
        <f1>A</f1>
        <f2>Monday</f2>
      </datum>
      <datum>
        <f1>A</f1>
        <f2>Tuesday</f2>
      </datum>
      <datum>
        <f1>B</f1>
        <f2>Wednesday</f2>
    </datum>
    </doc>

出力

      A
      -Monday
      -Tuesday
      B
      -Wednesday
4

1 に答える 1

2

I. これは、XSLT 1.0 の有名なMuenchian Grouping メソッドです。

<xsl:stylesheet version="1.0" xmlns:xsl="http://www.w3.org/1999/XSL/Transform">
 <xsl:output method="text"/>

 <xsl:key name="kDatumByF1" match="datum" use="f1"/>

 <xsl:template match=
   "datum[generate-id() = generate-id(key('kDatumByF1', f1)[1])]">
   <xsl:value-of select="concat('&#xA;', f1)"/>
   <xsl:apply-templates select="key('kDatumByF1', f1)/f2" mode="inGroup"/>
 </xsl:template>

 <xsl:template match="f2" mode="inGroup">
   - <xsl:value-of select="."/>
 </xsl:template>
 <xsl:template match="text()"/>
</xsl:stylesheet>

この変換が提供された XML ドキュメントに適用されると、次のようになります。

<doc>
    <datum>
        <f1>A</f1>
        <f2>Monday</f2>
    </datum>
    <datum>
        <f1>A</f1>
        <f2>Tuesday</f2>
    </datum>
    <datum>
        <f1>B</f1>
        <f2>Wednesday</f2>
    </datum>
</doc>

必要な正しい結果が生成されます。

A
   - Monday
   - Tuesday
B
   - Wednesday

Ⅱ．XSLT 2.0 ソリューション、使用xsl:for-each-group

<xsl:stylesheet version="2.0" xmlns:xsl="http://www.w3.org/1999/XSL/Transform">
    <xsl:output method="text"/>

 <xsl:template match="/*">
     <xsl:for-each-group select="datum" group-by="f1">
     <xsl:sequence select="'&#xA;', f1"/>
     <xsl:apply-templates select="current-group()/f2"/>
     </xsl:for-each-group>
 </xsl:template>

  <xsl:template match="f2">
   - <xsl:value-of select="."/>
 </xsl:template>
</xsl:stylesheet>
于 2012-08-13T05:02:30.353 に答える