51

遠近法によって歪んだ四角形の 2D 画像が与えられた場合:

ここに画像の説明を入力

形がもともと長方形だったことは知っていますが、元の大きさはわかりません。

この画像の角のピクセル座標がわかっている場合、元の比率、つまり長方形の商 (幅/高さ) を計算するにはどうすればよいですか?

(背景: 目標は、長方形のドキュメントの写真を自動的に歪ませることです。エッジ検出はおそらくハフ変換で行われます)

アップデート：

与えられた情報で幅と高さの比率を決定できるかどうかについて、いくつかの議論がありました。たとえば、上に示した四角形に 1:4 の長方形を投影する方法が思いつかないので、それは可能であるに違いないと私の素朴な考えでした。比率は明らかに 1:1 に近いので、数学的に決定する方法があるはずです。しかし、私の直感的な推測を超える証拠はありません。

以下に示す議論をまだ完全には理解していませんが、ここで欠落しているという暗黙の仮定がいくつかあるに違いないと思います。

しかし、何時間も検索した後、ようやく問題に関連するいくつかの論文を見つけました。そこで使用されている数学を理解するのに苦労していますが、これまでのところ成功していません。特に最初の論文では、残念ながらコード例と非常に緻密な数学がなく、私がやりたかったことを正確に説明しているようです。

  • Zhengyou Zhang、Li-Wei He、「ホワイトボード スキャンと画像処理」 http://research.microsoft.com/en-us/um/people/zhang/papers/tr03-39.pdf p.11

    「遠近歪みのため、長方形の画像は四角形に見えます。しかし、空間では長方形であることがわかっているため、カメラの焦点距離と長方形の縦横比の両方を推定できます。」

  • ROBERT M. HARALICK 「四角形の透視投影からのカメラ パラメータの決定」 http://portal.acm.org/citation.cfm?id=87146

    「3D 空間でサイズと位置が不明な長方形の 2D 透視投影を使用して、長方形の平面図に対するカメラのルック アングル パラメータを決定する方法を示します。」

4

10 に答える 10

29

論文を読んだ後、私の質問に答えようとする私の試みは次のとおりです

私はしばらく SAGE で方程式を操作し、C スタイルのこの疑似コードを思いつきました。


// in case it matters: licensed under GPLv2 or later
// legend:
// sqr(x)  = x*x
// sqrt(x) = square root of x

// let m1x,m1y ... m4x,m4y be the (x,y) pixel coordinates
// of the 4 corners of the detected quadrangle
// i.e. (m1x, m1y) are the cordinates of the first corner, 
// (m2x, m2y) of the second corner and so on.
// let u0, v0 be the pixel coordinates of the principal point of the image
// for a normal camera this will be the center of the image, 
// i.e. u0=IMAGEWIDTH/2; v0 =IMAGEHEIGHT/2
// This assumption does not hold if the image has been cropped asymmetrically

// first, transform the image so the principal point is at (0,0)
// this makes the following equations much easier
m1x = m1x - u0;
m1y = m1y - v0;
m2x = m2x - u0;
m2y = m2y - v0;
m3x = m3x - u0;
m3y = m3y - v0;
m4x = m4x - u0;
m4y = m4y - v0;


// temporary variables k2, k3
double k2 = ((m1y - m4y)*m3x - (m1x - m4x)*m3y + m1x*m4y - m1y*m4x) /
            ((m2y - m4y)*m3x - (m2x - m4x)*m3y + m2x*m4y - m2y*m4x) ;

double k3 = ((m1y - m4y)*m2x - (m1x - m4x)*m2y + m1x*m4y - m1y*m4x) / 
            ((m3y - m4y)*m2x - (m3x - m4x)*m2y + m3x*m4y - m3y*m4x) ;

// f_squared is the focal length of the camera, squared
// if k2==1 OR k3==1 then this equation is not solvable
// if the focal length is known, then this equation is not needed
// in that case assign f_squared= sqr(focal_length)
double f_squared = 
    -((k3*m3y - m1y)*(k2*m2y - m1y) + (k3*m3x - m1x)*(k2*m2x - m1x)) / 
                      ((k3 - 1)*(k2 - 1)) ;

//The width/height ratio of the original rectangle
double whRatio = sqrt( 
    (sqr(k2 - 1) + sqr(k2*m2y - m1y)/f_squared + sqr(k2*m2x - m1x)/f_squared) /
    (sqr(k3 - 1) + sqr(k3*m3y - m1y)/f_squared + sqr(k3*m3x - m1x)/f_squared) 
) ;

// if k2==1 AND k3==1, then the focal length equation is not solvable 
// but the focal length is not needed to calculate the ratio.
// I am still trying to figure out under which circumstances k2 and k3 become 1
// but it seems to be when the rectangle is not distorted by perspective, 
// i.e. viewed straight on. Then the equation is obvious:
if (k2==1 && k3==1) whRatio = sqrt( 
    (sqr(m2y-m1y) + sqr(m2x-m1x)) / 
    (sqr(m3y-m1y) + sqr(m3x-m1x))


// After testing, I found that the above equations 
// actually give the height/width ratio of the rectangle, 
// not the width/height ratio. 
// If someone can find the error that caused this, 
// I would be most grateful.
// until then:
whRatio = 1/whRatio;

更新：これらの方程式がどのように決定されたかは次のとおりです。

以下はSAGEのコードです。http://www.sagenb.org/home/pub/704/からオンラインでアクセスできます。(Sage は方程式を解くのに非常に便利で、どのブラウザーでも使用できます。チェックしてみてください)

# CALCULATING THE ASPECT RATIO OF A RECTANGLE DISTORTED BY PERSPECTIVE

#
# BIBLIOGRAPHY:
# [zhang-single]: "Single-View Geometry of A Rectangle 
#  With Application to Whiteboard Image Rectification"
#  by Zhenggyou Zhang
#  http://research.microsoft.com/users/zhang/Papers/WhiteboardRectification.pdf

# pixel coordinates of the 4 corners of the quadrangle (m1, m2, m3, m4)
# see [zhang-single] figure 1
m1x = var('m1x')
m1y = var('m1y')
m2x = var('m2x')
m2y = var('m2y')
m3x = var('m3x')
m3y = var('m3y')
m4x = var('m4x')
m4y = var('m4y')

# pixel coordinates of the principal point of the image
# for a normal camera this will be the center of the image, 
# i.e. u0=IMAGEWIDTH/2; v0 =IMAGEHEIGHT/2
# This assumption does not hold if the image has been cropped asymmetrically
u0 = var('u0')
v0 = var('v0')

# pixel aspect ratio; for a normal camera pixels are square, so s=1
s = var('s')

# homogenous coordinates of the quadrangle
m1 = vector ([m1x,m1y,1])
m2 = vector ([m2x,m2y,1])
m3 = vector ([m3x,m3y,1])
m4 = vector ([m4x,m4y,1])


# the following equations are later used in calculating the the focal length 
# and the rectangle's aspect ratio.
# temporary variables: k2, k3, n2, n3

# see [zhang-single] Equation 11, 12
k2_ = m1.cross_product(m4).dot_product(m3) / m2.cross_product(m4).dot_product(m3)
k3_ = m1.cross_product(m4).dot_product(m2) / m3.cross_product(m4).dot_product(m2)
k2 = var('k2')
k3 = var('k3')

# see [zhang-single] Equation 14,16
n2 = k2 * m2 - m1
n3 = k3 * m3 - m1


# the focal length of the camera.
f = var('f')
# see [zhang-single] Equation 21
f_ = sqrt(
         -1 / (
          n2[2]*n3[2]*s^2
         ) * (
          (
           n2[0]*n3[0] - (n2[0]*n3[2]+n2[2]*n3[0])*u0 + n2[2]*n3[2]*u0^2
          )*s^2 + (
           n2[1]*n3[1] - (n2[1]*n3[2]+n2[2]*n3[1])*v0 + n2[2]*n3[2]*v0^2
          ) 
         ) 
        )


# standard pinhole camera matrix
# see [zhang-single] Equation 1
A = matrix([[f,0,u0],[0,s*f,v0],[0,0,1]])


#the width/height ratio of the original rectangle
# see [zhang-single] Equation 20
whRatio = sqrt (
               (n2*A.transpose()^(-1) * A^(-1)*n2.transpose()) / 
               (n3*A.transpose()^(-1) * A^(-1)*n3.transpose())
              )

によって決定される C コードの簡略化された方程式

print "simplified equations, assuming u0=0, v0=0, s=1"
print "k2 := ", k2_
print "k3 := ", k3_
print "f  := ", f_(u0=0,v0=0,s=1)
print "whRatio := ", whRatio(u0=0,v0=0,s=1)

    simplified equations, assuming u0=0, v0=0, s=1
    k2 :=  ((m1y - m4y)*m3x - (m1x - m4x)*m3y + m1x*m4y - m1y*m4x)/((m2y
    - m4y)*m3x - (m2x - m4x)*m3y + m2x*m4y - m2y*m4x)
    k3 :=  ((m1y - m4y)*m2x - (m1x - m4x)*m2y + m1x*m4y - m1y*m4x)/((m3y
    - m4y)*m2x - (m3x - m4x)*m2y + m3x*m4y - m3y*m4x)
    f  :=  sqrt(-((k3*m3y - m1y)*(k2*m2y - m1y) + (k3*m3x - m1x)*(k2*m2x
    - m1x))/((k3 - 1)*(k2 - 1)))
    whRatio :=  sqrt(((k2 - 1)^2 + (k2*m2y - m1y)^2/f^2 + (k2*m2x -
    m1x)^2/f^2)/((k3 - 1)^2 + (k3*m3y - m1y)^2/f^2 + (k3*m3x -
    m1x)^2/f^2))

print "Everything in one equation:"
print "whRatio := ", whRatio(f=f_)(k2=k2_,k3=k3_)(u0=0,v0=0,s=1)

    Everything in one equation:
    whRatio :=  sqrt(((((m1y - m4y)*m2x - (m1x - m4x)*m2y + m1x*m4y -
    m1y*m4x)/((m3y - m4y)*m2x - (m3x - m4x)*m2y + m3x*m4y - m3y*m4x) -
    1)*(((m1y - m4y)*m3x - (m1x - m4x)*m3y + m1x*m4y - m1y*m4x)/((m2y -
    m4y)*m3x - (m2x - m4x)*m3y + m2x*m4y - m2y*m4x) - 1)*(((m1y -
    m4y)*m3x - (m1x - m4x)*m3y + m1x*m4y - m1y*m4x)*m2y/((m2y - m4y)*m3x
    - (m2x - m4x)*m3y + m2x*m4y - m2y*m4x) - m1y)^2/((((m1y - m4y)*m2x -
    (m1x - m4x)*m2y + m1x*m4y - m1y*m4x)*m3y/((m3y - m4y)*m2x - (m3x -
    m4x)*m2y + m3x*m4y - m3y*m4x) - m1y)*(((m1y - m4y)*m3x - (m1x -
    m4x)*m3y + m1x*m4y - m1y*m4x)*m2y/((m2y - m4y)*m3x - (m2x - m4x)*m3y
    + m2x*m4y - m2y*m4x) - m1y) + (((m1y - m4y)*m2x - (m1x - m4x)*m2y +
    m1x*m4y - m1y*m4x)*m3x/((m3y - m4y)*m2x - (m3x - m4x)*m2y + m3x*m4y
    - m3y*m4x) - m1x)*(((m1y - m4y)*m3x - (m1x - m4x)*m3y + m1x*m4y -
    m1y*m4x)*m2x/((m2y - m4y)*m3x - (m2x - m4x)*m3y + m2x*m4y - m2y*m4x)
    - m1x)) + (((m1y - m4y)*m2x - (m1x - m4x)*m2y + m1x*m4y -
    m1y*m4x)/((m3y - m4y)*m2x - (m3x - m4x)*m2y + m3x*m4y - m3y*m4x) -
    1)*(((m1y - m4y)*m3x - (m1x - m4x)*m3y + m1x*m4y - m1y*m4x)/((m2y -
    m4y)*m3x - (m2x - m4x)*m3y + m2x*m4y - m2y*m4x) - 1)*(((m1y -
    m4y)*m3x - (m1x - m4x)*m3y + m1x*m4y - m1y*m4x)*m2x/((m2y - m4y)*m3x
    - (m2x - m4x)*m3y + m2x*m4y - m2y*m4x) - m1x)^2/((((m1y - m4y)*m2x -
    (m1x - m4x)*m2y + m1x*m4y - m1y*m4x)*m3y/((m3y - m4y)*m2x - (m3x -
    m4x)*m2y + m3x*m4y - m3y*m4x) - m1y)*(((m1y - m4y)*m3x - (m1x -
    m4x)*m3y + m1x*m4y - m1y*m4x)*m2y/((m2y - m4y)*m3x - (m2x - m4x)*m3y
    + m2x*m4y - m2y*m4x) - m1y) + (((m1y - m4y)*m2x - (m1x - m4x)*m2y +
    m1x*m4y - m1y*m4x)*m3x/((m3y - m4y)*m2x - (m3x - m4x)*m2y + m3x*m4y
    - m3y*m4x) - m1x)*(((m1y - m4y)*m3x - (m1x - m4x)*m3y + m1x*m4y -
    m1y*m4x)*m2x/((m2y - m4y)*m3x - (m2x - m4x)*m3y + m2x*m4y - m2y*m4x)
    - m1x)) - (((m1y - m4y)*m3x - (m1x - m4x)*m3y + m1x*m4y -
    m1y*m4x)/((m2y - m4y)*m3x - (m2x - m4x)*m3y + m2x*m4y - m2y*m4x) -
    1)^2)/((((m1y - m4y)*m2x - (m1x - m4x)*m2y + m1x*m4y -
    m1y*m4x)/((m3y - m4y)*m2x - (m3x - m4x)*m2y + m3x*m4y - m3y*m4x) -
    1)*(((m1y - m4y)*m3x - (m1x - m4x)*m3y + m1x*m4y - m1y*m4x)/((m2y -
    m4y)*m3x - (m2x - m4x)*m3y + m2x*m4y - m2y*m4x) - 1)*(((m1y -
    m4y)*m2x - (m1x - m4x)*m2y + m1x*m4y - m1y*m4x)*m3y/((m3y - m4y)*m2x
    - (m3x - m4x)*m2y + m3x*m4y - m3y*m4x) - m1y)^2/((((m1y - m4y)*m2x -
    (m1x - m4x)*m2y + m1x*m4y - m1y*m4x)*m3y/((m3y - m4y)*m2x - (m3x -
    m4x)*m2y + m3x*m4y - m3y*m4x) - m1y)*(((m1y - m4y)*m3x - (m1x -
    m4x)*m3y + m1x*m4y - m1y*m4x)*m2y/((m2y - m4y)*m3x - (m2x - m4x)*m3y
    + m2x*m4y - m2y*m4x) - m1y) + (((m1y - m4y)*m2x - (m1x - m4x)*m2y +
    m1x*m4y - m1y*m4x)*m3x/((m3y - m4y)*m2x - (m3x - m4x)*m2y + m3x*m4y
    - m3y*m4x) - m1x)*(((m1y - m4y)*m3x - (m1x - m4x)*m3y + m1x*m4y -
    m1y*m4x)*m2x/((m2y - m4y)*m3x - (m2x - m4x)*m3y + m2x*m4y - m2y*m4x)
    - m1x)) + (((m1y - m4y)*m2x - (m1x - m4x)*m2y + m1x*m4y -
    m1y*m4x)/((m3y - m4y)*m2x - (m3x - m4x)*m2y + m3x*m4y - m3y*m4x) -
    1)*(((m1y - m4y)*m3x - (m1x - m4x)*m3y + m1x*m4y - m1y*m4x)/((m2y -
    m4y)*m3x - (m2x - m4x)*m3y + m2x*m4y - m2y*m4x) - 1)*(((m1y -
    m4y)*m2x - (m1x - m4x)*m2y + m1x*m4y - m1y*m4x)*m3x/((m3y - m4y)*m2x
    - (m3x - m4x)*m2y + m3x*m4y - m3y*m4x) - m1x)^2/((((m1y - m4y)*m2x -
    (m1x - m4x)*m2y + m1x*m4y - m1y*m4x)*m3y/((m3y - m4y)*m2x - (m3x -
    m4x)*m2y + m3x*m4y - m3y*m4x) - m1y)*(((m1y - m4y)*m3x - (m1x -
    m4x)*m3y + m1x*m4y - m1y*m4x)*m2y/((m2y - m4y)*m3x - (m2x - m4x)*m3y
    + m2x*m4y - m2y*m4x) - m1y) + (((m1y - m4y)*m2x - (m1x - m4x)*m2y +
    m1x*m4y - m1y*m4x)*m3x/((m3y - m4y)*m2x - (m3x - m4x)*m2y + m3x*m4y
    - m3y*m4x) - m1x)*(((m1y - m4y)*m3x - (m1x - m4x)*m3y + m1x*m4y -
    m1y*m4x)*m2x/((m2y - m4y)*m3x - (m2x - m4x)*m3y + m2x*m4y - m2y*m4x)
    - m1x)) - (((m1y - m4y)*m2x - (m1x - m4x)*m2y + m1x*m4y -
    m1y*m4x)/((m3y - m4y)*m2x - (m3x - m4x)*m2y + m3x*m4y - m3y*m4x) -
    1)^2))



# some testing:
# - choose a random rectangle, 
# - project it onto a random plane,
# - insert the corners in the above equations,
# - check if the aspect ratio is correct.

from sage.plot.plot3d.transform import rotate_arbitrary

#redundandly random rotation matrix
rand_rotMatrix = \
           rotate_arbitrary((uniform(-5,5),uniform(-5,5),uniform(-5,5)),uniform(-5,5)) *\
           rotate_arbitrary((uniform(-5,5),uniform(-5,5),uniform(-5,5)),uniform(-5,5)) *\
           rotate_arbitrary((uniform(-5,5),uniform(-5,5),uniform(-5,5)),uniform(-5,5))

#random translation vector
rand_transVector = vector((uniform(-10,10),uniform(-10,10),uniform(-10,10))).transpose()

#random rectangle parameters
rand_width =uniform(0.1,10)
rand_height=uniform(0.1,10)
rand_left  =uniform(-10,10)
rand_top   =uniform(-10,10)

#random focal length and principal point
rand_f  = uniform(0.1,100)
rand_u0 = uniform(-100,100)
rand_v0 = uniform(-100,100)

# homogenous standard pinhole projection, see [zhang-single] Equation 1
hom_projection = A * rand_rotMatrix.augment(rand_transVector)

# construct a random rectangle in the plane z=0, then project it randomly 
rand_m1hom = hom_projection*vector((rand_left           ,rand_top            ,0,1)).transpose()
rand_m2hom = hom_projection*vector((rand_left           ,rand_top+rand_height,0,1)).transpose()
rand_m3hom = hom_projection*vector((rand_left+rand_width,rand_top            ,0,1)).transpose()
rand_m4hom = hom_projection*vector((rand_left+rand_width,rand_top+rand_height,0,1)).transpose()

#change type from 1x3 matrix to vector
rand_m1hom = rand_m1hom.column(0)
rand_m2hom = rand_m2hom.column(0)
rand_m3hom = rand_m3hom.column(0)
rand_m4hom = rand_m4hom.column(0)

#normalize
rand_m1hom = rand_m1hom/rand_m1hom[2]
rand_m2hom = rand_m2hom/rand_m2hom[2]
rand_m3hom = rand_m3hom/rand_m3hom[2]
rand_m4hom = rand_m4hom/rand_m4hom[2]

#substitute random values for f, u0, v0
rand_m1hom = rand_m1hom(f=rand_f,s=1,u0=rand_u0,v0=rand_v0)
rand_m2hom = rand_m2hom(f=rand_f,s=1,u0=rand_u0,v0=rand_v0)
rand_m3hom = rand_m3hom(f=rand_f,s=1,u0=rand_u0,v0=rand_v0)
rand_m4hom = rand_m4hom(f=rand_f,s=1,u0=rand_u0,v0=rand_v0)

# printing the randomly choosen values
print "ground truth: f=", rand_f, "; ratio=", rand_width/rand_height

# substitute all the variables in the equations:
print "calculated: f= ",\
f_(k2=k2_,k3=k3_)(s=1,u0=rand_u0,v0=rand_v0)(
  m1x=rand_m1hom[0],m1y=rand_m1hom[1],
  m2x=rand_m2hom[0],m2y=rand_m2hom[1],
  m3x=rand_m3hom[0],m3y=rand_m3hom[1],
  m4x=rand_m4hom[0],m4y=rand_m4hom[1],
),"; 1/ratio=", \
1/whRatio(f=f_)(k2=k2_,k3=k3_)(s=1,u0=rand_u0,v0=rand_v0)(
  m1x=rand_m1hom[0],m1y=rand_m1hom[1],
  m2x=rand_m2hom[0],m2y=rand_m2hom[1],
  m3x=rand_m3hom[0],m3y=rand_m3hom[1],
  m4x=rand_m4hom[0],m4y=rand_m4hom[1],
)

print "k2 = ", k2_(
  m1x=rand_m1hom[0],m1y=rand_m1hom[1],
  m2x=rand_m2hom[0],m2y=rand_m2hom[1],
  m3x=rand_m3hom[0],m3y=rand_m3hom[1],
  m4x=rand_m4hom[0],m4y=rand_m4hom[1],
), "; k3 = ", k3_(
  m1x=rand_m1hom[0],m1y=rand_m1hom[1],
  m2x=rand_m2hom[0],m2y=rand_m2hom[1],
  m3x=rand_m3hom[0],m3y=rand_m3hom[1],
  m4x=rand_m4hom[0],m4y=rand_m4hom[1],
)

# ATTENTION: testing revealed, that the whRatio 
# is actually the height/width ratio, 
# not the width/height ratio
# This contradicts [zhang-single]
# if anyone can find the error that caused this, I'd be grateful

    ground truth: f= 72.1045134124554 ; ratio= 3.46538779959142
    calculated: f=  72.1045134125 ; 1/ratio= 3.46538779959
    k2 =  0.99114614987 ; k3 =  1.57376280159
于 2009-08-03T15:03:19.953 に答える
7

アップデート

アップデートを読み、最初のリファレンス（ホワイトボードのスキャンと画像の強調）を確認した後、欠落しているポイントがどこにあるかがわかります。

問題の入力データは、4倍（A、B、C、D）であり、投影された画像の中心Oです。この記事では、u0 = v0=0という仮定に対応しています。この点を追加すると、問題は長方形のアスペクト比を取得するのに十分に制約されます。

次に、問題を次のように言い換えます。Z= 0平面に4つ（A、B、C、D）がある場合、目の位置E（0,0、h）、h> 0、および3D平面Pを次のように見つけます。 Pへの（A、B、C、D）の投影は長方形です。

PはEによって決定されることに注意してください。平行四辺形を取得するには、Pに（EU）および（EV）への平行四辺形が含まれている必要があります。ここでU =（AB）x（CD）およびV =（AD）x（BC）です。

実験的に、この問題には、長方形のw / h比の一意の値に対応する、一般に1つの一意の解決策があるようです。

代替テキスト 代替テキスト

前の投稿

いいえ、投影から長方形の比率を決定することはできません。

一般的なケースでは、Z = 0平面の4つの非同一線上の点の4倍（A、B、C、D）は、無限に多くの幅/高さの比率を持つ無限に多くの長方形の投影です。

（AB）と（CD）とVの交点である2つの消失点U、（AD）と（BC）の交点、および2つの対角線（AC）と（BD）の交点である点Iについて考えてみます。ABCDとして投影するには、中心Iの平行四辺形が、点Iを通る（UV）に平行な線を含む平面上にある必要があります。そのような平面の1つに、ABCDに投影される多くの長方形があります。

Cabri3Dで行われたこれらの2つの画像を参照してください。2つのケースでは、ABCDは変更されておらず（灰色のZ = 0平面上）、長方形を含む青色の平面も変更されていません。部分的に隠されている緑色の線は（UV）線であり、表示されている緑色の線はそれに平行で、Iを含んでいます。

代替テキスト 代替テキスト

于 2009-07-28T17:59:38.407 に答える
1

なぜ結果が w/h ではなく h/w になるのかという質問について: 上記の式 20 の式が正しいかどうか疑問に思っています。投稿は：

       whRatio = sqrt (
            (n2*A.transpose()^(-1) * A^(-1)*n2.transpose()) / 
            (n3*A.transpose()^(-1) * A^(-1)*n3.transpose())
           )

それを OpenCV で実行しようとすると、例外が発生します。しかし、式 20 のように見える次の式を使用すると、すべてが正しく機能します。

        whRatio = sqrt (
            (n2.transpose()*A.transpose()^(-1) * A^(-1)*n2) /
            (n3.transpose()*A.transpose()^(-1) * A^(-1)*n3)
           )
于 2012-03-13T20:20:43.350 に答える
1

この回答で幅/高さを決定できますその影の座標で長方形の3D座標を計算しますか? . 長方形が交点の対角線上で回転すると仮定すると、幅と高さが計算されます。しかし、仮定の影面と実際の影面の間の距離を変更すると、長方形の比例は計算された幅/高さと同じになります!

于 2015-04-03T05:38:47.610 に答える
1

サイズは実際には必要ありません。プロポーションも必要ありません。そして、彼がドキュメントの写真/スキャンを使用していることを考えると、どちらの面が上であるかを知ることは無関係です. 彼がそれらの裏側をスキャンしようとしているとは思えません。

「角交差」は、遠近感を補正する方法です。これは役立つかもしれません：

2D で透視補正グリッドを描画する方法

于 2009-07-28T15:01:37.520 に答える
0

Dropbox のテクニカル ブログには、スキャナー アプリの問題をどのように解決したかについての詳細な記事があります。

https://blogs.dropbox.com/tech/2016/08/fast-document-rectification-and-enhancement/

ドキュメントの修正

入力ドキュメントは物理的な世界では長方形であると想定していますが、カメラに正確に向いていない場合、画像の角は一般的な凸状の四角形になります。したがって、最初の目標を達成するには、キャプチャ プロセスによって適用された幾何学的変換を元に戻す必要があります。この変換は、カメラの焦点距離 (内部パラメーター) などに加えて、ドキュメントに対するカメラの視点 (いわゆる外部パラメーター) に依存します。キャプチャ シナリオの図を次に示します。

幾何学的変換を元に戻すには、まず上記のパラメーターを決定する必要があります。きれいに対称なカメラ (非点収差、スキューなどがない) を仮定すると、このモデルの未知数は次のようになります。

  • ドキュメントに対するカメラの 3D 位置 (自由度 3)、
  • ドキュメントに対するカメラの 3D 方向 (自由度 3)、
  • ドキュメントの寸法 (自由度 2)、および
  • カメラの焦点距離 (自由度 1)。

反対に、検出された 4 つのドキュメント コーナーの x 座標と y 座標は、実質的に 8 つの制約を与えます。制約 (8) よりも未知数 (9) の方が多いように見えますが、未知数は完全に自由な変数ではありません。同じ写真を取得するために、ドキュメントを物理的にスケーリングし、カメラから離れた場所に配置することを想像できます。この関係は追加の制約を課すため、完全に制約されたシステムを解決する必要があります。(私たちが解く実際の連立方程式には、他にもいくつかの考慮事項が含まれます。関連するウィキペディアの記事は、https: //en.wikipedia.org/wiki/Camera_resectioningに適切な要約を示しています)

パラメータが復元されたら、キャプチャ プロセスによって適用された幾何学的変換を元に戻して、きれいな長方形の画像を取得できます。ただし、これには時間がかかる可能性があります。出力ピクセルごとに、ソース イメージ内の対応する入力ピクセルの値を検索する必要があります。もちろん、GPU は、仮想空間でのテクスチャのレンダリングなどのタスク向けに特別に設計されています。ビュー変換が存在します — これはたまたま、先ほど解いたカメラ変換の逆です! — これにより、完全な入力画像をレンダリングし、修正されたドキュメントを取得できます。(これを確認する簡単な方法は、携帯電話の画面に完全な入力画像が表示されたら、画面上のドキュメント領域の投影が直線的に見えるように携帯電話を傾けて移動できることに注意することです)。

最後に、縮尺に関してあいまいさがあったことを思い出してください。たとえば、ドキュメントがレター サイズの紙 (8.5 インチ x 11 インチ) なのかポスター ボード (17 インチ x 22 インチ) なのかはわかりません。出力画像のサイズは? このあいまいさを解決するために、入力画像の四角形内のピクセル数をカウントし、このピクセル数と一致するように出力解像度を設定します。アイデアは、画像をあまりアップサンプルまたはダウンサンプルしたくないということです。

于 2017-01-12T20:32:18.313 に答える
0

「カメラ」の距離を知らずに、この長方形の幅を知ることは不可能です。

5 cm の距離から見た小さな長方形は、数メートル離れたところから見た巨大な長方形と同じように見えます。

于 2009-07-28T14:31:51.500 に答える
0

これらの 2 つの消失点と、水平線より下の 3 番目の点 (つまり、水平線の長方形と同じ側) で直角二等辺三角形を描きます。その 3 番目の点が原点になり、消失点への 2 本の線が軸になります。原点から消失点までの距離を pi/2 とします。次に、四角形の辺を消失点から軸まで延長し、それらが軸と交差する場所をマークします。軸を選び、2 つのマークから原点までの距離を測定し、それらの距離を x->tan(x) に変換すると、その差がその辺の「真の」長さになります。もう一方の軸についても同じことを行います。これら 2 つの長さの比率をとれば完了です。

于 2009-07-28T16:42:54.973 に答える
-1

より多くの情報が必要です。変換された図は、任意の視点から任意の平行四辺形に由来する可能性があります。

そのため、最初に何らかのキャリブレーションを行う必要があると思います。

編集：私が間違っていると言った人のために、同じ投影につながる長方形/カメラの無限の組み合わせがあるという数学的な証明を次に示します。

問題を単純化するために (必要なのは辺の比率だけなので)、長方形が次の点で定義されていると仮定しましょう: R=[(0,0),(1,0),(1,r),(0,r)](この単純化は、アフィン空間で問題を同等のものに変換することと同じです)。

変換されたポリゴンは次のように定義されます。T=[(tx0,ty0),(tx1,ty1),(tx2,ty2),(tx3,ty3)]

M = [[m00,m01,m02],[m10,m11,m12],[m20,m21,m22]]を満たす変換行列が存在する(Rxi,Ryi,1)*M=wi(txi,tyi,1)'

上記の式を点について展開すると、

私たちは得るためR_0に：m02-tx0*w0 = m12-ty0*w0 = m22-w0 = 0

私たちは得るためR_1に：m00-tx1*w1 = m10-ty1*w1 = m20+m22-w1 = 0

私たちは得るためR_2に：m00+r*m01-tx2*w2 = m10+r*m11-ty2*w2 = m20+r*m21+m22-w2 = 0

そして、次のR_3ようになります。m00+r*m01-tx3*w3 = m10+r*m11-ty3*w3 = m20 + r*m21 + m22 -w3 = 0

これまでのところ、12 個の方程式、14 個の未知の変数 (行列から 9 個、 から 4 個wi、比 1r個) があり、残りは既知の値です (txiとtyiが与えられます)。

システムが過少に指定されていなかったとしても、未知数の一部がそれら自体 (rおよびmi0製品) 間で乗算され、システムが非線形になります (各製品に新しい名前を割り当てる線形システムに変換できますが、それでも終了します13 の未知数、そのうち 3 つは無限解に拡張されています)。

推論や数学に欠陥がある場合は、お知らせください。

于 2009-07-28T15:00:12.470 に答える