9

いくつかのArbitraryインスタンスを作成しているときに、次の非常に機械的なパターンでいくつかの関数を実装しました。

type A = Arbitrary -- to cut down on the size of the annotations below
shrink1 :: (A a          ) => (a           -> r) -> (a           -> [r])
shrink2 :: (A a, A b     ) => (a -> b      -> r) -> (a -> b      -> [r])
shrink3 :: (A a, A b, A c) => (a -> b -> c -> r) -> (a -> b -> c -> [r])

shrink1 f a     = [f a'     | a' <- shrink a]
shrink2 f a b   = [f a' b   | a' <- shrink a] ++ [f a b'   | b' <- shrink b]
shrink3 f a b c = [f a' b c | a' <- shrink a] ++ [f a b' c | b' <- shrink b] ++ [f a b c' | c' <- shrink c]

私はこれらの関数を手作業で書きましたがshrink7、それで十分だと思います。しかし、私はどうしようもありません。これは合理的に自動化できるのでしょうか。次のようなソリューションのボーナスポイント：

  • を可能にしますshrink0 f = []
  • すべての収縮器を生成します
  • 型クラスのハッカーがたくさんあります、私はそれが大好きです
  • インコヒーレント/決定不能/重複インスタンスなどの恐ろしい拡張機能をスキップします
  • ケーキを持って食べさせてくれます。渡すときにカレーをかけたり、、、、に適用するときにカレーfを塗ったりする必要はありません。shrinkX fabc
4

2 に答える 2

9

これはコンパイルされます、私はそれがうまくいくことを願っています：

{-# LANGUAGE TypeFamilies #-}
import Test.QuickCheck

class Shrink t where
  type Inp t :: *
  shrinkn :: Inp t -> t
  (++*) :: [Inp t] -> t -> t

instance Shrink [r] where
  type Inp [r] = r
  shrinkn _ = []
  (++*) = (++) 

instance (Arbitrary a, Shrink s) => Shrink (a -> s) where
  type Inp (a -> s) = a -> Inp s
  shrinkn f a = [ f a' | a' <- shrink a ] ++* shrinkn (f a)
  l ++* f = \b -> map ($ b) l ++* f b

(++*)縮小を実装するためだけです。

型クラスのハッカーが比較的不足していることをお詫びします。[r]は型再帰の適切な停止条件を提供するため、ハッカーは必要ありません。

于 2012-08-18T00:35:35.103 に答える
2

この場合、恐ろしい拡張機能を回避できるとは思えませんが、それ以外の場合は次のようになります。

{-# LANGUAGE MultiParamTypeClasses, FlexibleInstances, TypeFamilies,
 UndecidableInstances, IncoherentInstances #-}

import Test.QuickCheck

class Shrinkable a r where
    shrinkn :: a -> r

instance (Shrinkable [a -> b] r) => Shrinkable (a -> b) r where
    shrinkn f = shrinkn [f]

instance (Arbitrary a, Shrinkable [b] r1, r ~ (a -> r1)) => Shrinkable [a -> b] r where
    shrinkn fs@(f:_) a =
        let fs' = [f a | f <- fs]
        in shrinkn $ fs' ++ [f a' | a' <- shrink a]

instance (r ~ [a]) => Shrinkable [a] r where
    shrinkn (_:vs) = vs

instance (r ~ [a]) => Shrinkable a r where
    shrinkn e = []

サンプル関数に対してテストするためのいくつかのQuickcheckプロパティを次に示します。

prop0 a = shrinkn a == []

prop1 a = shrink1 not a == shrinkn not a 

prop2 a b = shrink2 (++) a b == shrinkn (++) a b 

f3 a b c = if a then b + c else b * c 
prop3 a b c = shrink3 f3 a b c == shrinkn f3 a b c
于 2012-08-18T07:08:08.130 に答える