5

以下は完全に機能します（Delphi 7）：

procedure TMainForm.SayIt(s:string); // s is the string to be spoken
var
voice: OLEVariant;
begin
  memo1.setfocus;
  voice := CreateOLEObject ('SAPI.SpVoice');
  voice.Voice := voice.GetVoices.Item(combobox1.ItemIndex); // current voice selected
  voice.volume := tbVolume.position;
  voice.rate := tbRate.position;
  voice.Speak (s, SVSFDefault);
end;

上記は「同期」モード ( SVSFDefaultフラグ) で動作しますが、非同期モードでサウンドを再生しようとしてフラグをSVSFlagsAsyncに変更すると、サウンドは生成されません。エラー メッセージは表示されませんが、スピーカーからは何も再生されません。

問題は何ですか？Delphi の Imports フォルダに SpeechLib_TLB ユニットがあります。

編集：これはWindows XPにあります

ありがとう、ブルーノ。

4

1 に答える 1

7

SVSFlagsAsyncフラグを使用すると、音声ストリームは内部バッファーにキューイングされ、音声サービスによって実行されるのを待機します。したがって、どちらを発行するかは音声オブジェクトの有効期間に関連していると思います。インスタンスはサウンドを実行する前に破棄されます。

WaitUntilDone回避策として、メソッドを使用してサウンドを待つことができます

  voice.Speak (s, SVSFlagsAsync);
  repeat  Sleep(100); until  voice.WaitUntilDone(10);

voiceまたは、フォーム定義で変数を宣言します。

  TMainForm = class(TForm)
    Button1: TButton;
    procedure Button1Click(Sender: TObject);
    procedure FormCreate(Sender: TObject);
    procedure FormDestroy(Sender: TObject);
  private
    { Private declarations }
  public
    { Public declarations }
   voice: OLEVariant;
   procedure SayIt(const s:string);
  end;

var
  MainForm: TMainForm;

implementation

uses
   ComObj;

{$R *.dfm}
procedure TMainForm.SayIt(const s:string); // s is the string to be spoken
const
  SVSFDefault = 0;
  SVSFlagsAsync = 1;
  SVSFPurgeBeforeSpeak= 2;
begin
  memo1.setfocus;
  voice.Voice := voice.GetVoices.Item(combobox1.ItemIndex); // current voice selected
  voice.volume := tbVolume.position;
  voice.rate := tbRate.position;
  voice.Speak (s, SVSFlagsAsync {or SVSFPurgeBeforeSpeak});
end;


procedure TMainForm.Button1Click(Sender: TObject);
begin
  SayIt('Hello');
end;

procedure TMainForm.FormCreate(Sender: TObject);
begin
  voice := CreateOLEObject('SAPI.SpVoice');
end;

procedure TMainForm.FormDestroy(Sender: TObject);
begin
  voice  := Unassigned;
end;

end.

追加の注意として、遅延バインディングを使用しているため、SpeechLib_TLB ユニットは必要ありません。

于 2012-08-25T17:52:41.227 に答える