0

これが私のテーブルです

MYTABLE(ID NUMBER(10),
        DATATYPE VARCHAR2(2 BYTE),
        XMLDATA LONG
)

注1：このテーブルを変更することはできません注2：Oracle10gを使用しています

これがXMLDATAのサンプルです

<myxml version="1">
  <node1>
   <child1>value to get</child1>
  </node1>
</myxml>

xmltype（）を試しましたが、LONGタイプでは機能しません（ORA-00997 LONGタイプの不正使用）。たぶん、XMLDATA値を新しいテーブルにコピーしてCLOBに変換してから、xmltypeに変換してEXTRACTVALUE（）を使用する必要がありますか？

'値を抽出して'を取得するための最良の方法は何ですか？

4

1 に答える 1

4

以下は、任意の長さのLONGからCLOBを出力することになっているコードです。の本体をにダンプMY_TRIGGERしdbms_outputます。それが機能する場合は、必要に応じてそれを解析できるはずです。

DECLARE
    c_chunk_limit CONSTANT   INTEGER := 100;

    v_cur                    INTEGER := DBMS_SQL.open_cursor;
    v_offset                 INTEGER;
    v_chunk                  VARCHAR2(32767);
    v_chunk_size             INTEGER;
BEGIN
    DBMS_SQL.parse(
        v_cur,
        'SELECT trigger_body FROM dba_triggers WHERE trigger_name = ''MY_TRIGGER''',
        DBMS_SQL.native
    );

    DBMS_SQL.define_column_long(v_cur, 1);  -- 1 here represents the column position in the select list the long is column#1

    IF DBMS_SQL.execute_and_fetch(v_cur) > 0
    THEN
        v_offset   := 0;

        LOOP
            DBMS_SQL.column_value_long(
                v_cur,
                1,  -- 1 here represents the column position in the select list the long is column#1
                c_chunk_limit,
                v_offset,
                v_chunk,
                v_chunk_size
            );

            EXIT WHEN v_chunk_size = 0;

            v_offset   := v_offset + v_chunk_size;
            DBMS_OUTPUT.put_line(v_chunk);
        END LOOP;
    END IF;

    DBMS_SQL.close_cursor(v_cur);
END;
/
于 2009-08-01T03:35:18.610 に答える