0

画像とラベルを含むリストのitemRendererを実装したいと思います。リストのデータプロバイダーは、バックエンドから取得したオブジェクトのリストです。

public class Object {
private String label;

private byte[] content;

}

私のアイテムレンダラー：

<s:MXDataGridItemRenderer xmlns:fx="http://ns.adobe.com/mxml/2009" 
                      xmlns:s="library://ns.adobe.com/flex/spark" 
                      xmlns:mx="library://ns.adobe.com/flex/mx">
<s:layout>
    <s:HorizontalLayout/>
</s:layout>
<mx:Image source="{data.content}"/>
<s:Label text="{data.label}"/>

壊れた画像しかありません。誰もがこの問題を解決する理由と方法を知っていましたか。よろしくお願いします

4

1 に答える 1

0

http://help.adobe.com/en_US/FlashPlatform/reference/actionscript/3/spark/components/Image.html#source

  • BitmapまたはBitmapDataインスタンス。
  • DisplayObjectのサブクラスを表すクラス。
  • BitmapFillはクラスをインスタンス化し、そのビットマップレンダリングを作成します。DisplayObjectのインスタンス。BitmapFillは、それをビットマップにコピーして埋めます。
  • 外部画像ファイルの名前。

spark.components.Imageは、ByteArrayインスタンスをソースとして使用できません。したがって、それをビットマップインスタンスに変換する必要があります。

このようなもの：

<?xml version="1.0"?>
<s:MXDataGridItemRenderer xmlns:fx="http://ns.adobe.com/mxml/2009" xmlns:s="library://ns.adobe.com/flex/spark">

    <fx:Script><![CDATA[
        private var _bytesLoader:Loader;

        override public function set data(value:Object):void
        {
            super.data = value;

            _loadBytes(data.bytes as ByteArray);
        }

        private function _loadBytes(bytes:ByteArray):void
        {
            _destroyBytesLoader();

            if (!bytes)
            {
                return;
            }

            _createBytesLoader();
            try
            {
                _bytesLoader.loadBytes(bytes);
            }
            catch (e:*)
            {
                _destroyBytesLoader();
            }
        }

        private function _createBytesLoader():void
        {
            _bytesLoader = new Loader();
            _bytesLoader.contentLoaderInfo.addEventListener(Event.COMPLETE, _bytesLoader_completeHandler);
            _bytesLoader.contentLoaderInfo.addEventListener(IOErrorEvent.IO_ERROR, _bytesLoader_errorHandler);
            _bytesLoader.contentLoaderInfo.addEventListener(AsyncErrorEvent.ASYNC_ERROR, _bytesLoader_errorHandler);
        }

        private function _destroyBytesLoader():void
        {
            if (!_bytesLoader)
            {
                return;
            }

            _bytesLoader.contentLoaderInfo.removeEventListener(Event.COMPLETE, _bytesLoader_completeHandler);
            _bytesLoader.contentLoaderInfo.removeEventListener(IOErrorEvent.IO_ERROR, _bytesLoader_errorHandler);
            _bytesLoader.contentLoaderInfo.removeEventListener(AsyncErrorEvent.ASYNC_ERROR, _bytesLoader_errorHandler);

            try
            {
                _bytesLoader.unload();
            }
            catch (e:*){}

            _bytesLoader = null;
        }

        private function _bytesLoader_completeHandler(event:Event):void
        {
            try
            {
                myImage.source = Bitmap(_bytesLoader.content).bitmapData.clone();
            }
            catch (e:*)
            {
            }
            _destroyBytesLoader();
        }

        private function _bytesLoader_errorHandler(event:Event):void
        {
            _destroyBytesLoader();
        }

        ]]></fx:Script>

    <s:layout>
        <s:HorizontalLayout />
    </s:layout>

    <s:Image id="myImage"/>
    <s:Label text="{data.label}" />

</s:MXDataGridItemRenderer>
于 2012-08-30T14:38:04.790 に答える