0

2 つの関数を呼び出すストアド プロシージャを作成します。

エラーが発生します：

メッセージ 4104、レベル 16、状態 1、プロシージャ Add_Translation、行 25
マルチパート識別子 ".word" をバインドできませんでした。

これは私のストアドプロシージャです：

ALTER PROCEDURE [dbo].[Add_Translation]
   @english nvarchar(70), 
   @kurdish nvarchar(70),
   @english_category int,
   @kurdish_category int,
   @result int out
AS
BEGIN
    SET NOCOUNT ON;

    if @english is not null and @kurdish is not null and @english_category is not null and @kurdish_category is not null
    begin
        declare @intEnId int=-1;
        exec @intEnId = Check_English_word @text = @english;

        declare @identityEnglish int;
        declare @identityKurdish int;

        if @intEnId = -1
        begin
            insert into english_table values(@english, @english_category);
            set @identityEnglish = SCOPE_IDENTITY();
        end
        else
        begin
            set @identityEnglish = (select e.english_id from english_table e where UPPER(.word)=UPPER(@english)); 
        end

        declare @intKuId int=-1;
        exec @intKuId=Check_Kurdish_Word @word=@kurdish;

        if @intKuId =-1
        begin
            insert into kurdish_table values(@kurdish, @kurdish_category);

            set @identityKurdish = SCOPE_IDENTITY();
        end
        else
        begin
            set @identityKurdish = (select k.kurdish_id from kurdish_table k where upper(k.word)=upper(@kurdish));
        end

        declare @translated int =0;

        exec @translated = Check_Translation @english_id = @identityEnglish, @kurdish_id = @identityKurdish;

            if @translated=0
        begin
            insert into transactions values(@identityEnglish, @identityKurdish);
            set @result = 1;
        end
        else
        begin
            set @result = 2;
        end
    end
    else
    begin
        set @result = 0;
    end
END

最初の関数は次のとおりです。

ALTER FUNCTION [dbo].[Check_English_word] 
(
@text nvarchar(70) 
)
RETURNS int
AS
BEGIN

    DECLARE @Result int
    set @Result=-1;

    if @text is not null
    begin

        SELECT @Result = e.english_id 
            from english_table e 
            where UPPER(e.word) = UPPER(@text); 
    end

    RETURN @Result
END

2 番目の関数:

ALTER FUNCTION [dbo].[Check_Kurdish_Word] 
(
@word nvarchar(70) 
)
RETURNS int
AS
BEGIN
    DECLARE @Result int
    set @Result=-1;

if @word is not null
    begin
        SELECT @Result = k.kurdish_id 
            from kurdish_table k  
            where UPPER(k.word) = UPPER(@word); 
    end

    RETURN @Result
END
4

1 に答える 1

1

eこの行にがありません

        set @identityEnglish=(select e.english_id from english_table e 
              where UPPER(.word)=UPPER(@english));

に変更します

        set @identityEnglish=(select e.english_id from english_table e 
              where UPPER(e.word)=UPPER(@english));

また、挿入時に列を指定することをお勧めします。つまり、

insert into english_table values(@english,@englsih_category);

する必要があります

insert into english_table (word, category) values(@english,@englsih_category);
于 2012-08-30T10:58:39.800 に答える