7

動的T-SQLの一部を生成して実行するストアドプロシージャがあります。これは、一度構築されると、次のようになります。

SELECT 
    tblUsers.strUserName AS [Username]
    ,tblUsers.strEmail AS [Email]
    ,tblUserAuditLog.strIpAddress AS [IP Address]
    ,tblUserAuditLog.dtAuditTimeStamp AS [Timestamp]
    ,tblUserAuditLog.strAuditLogAction AS [Action]
    ,tblUserAuditLog.strLogDetails AS [Details]
FROM         
    tblUserAuditLog 
        LEFT OUTER JOIN tblUsers 
        ON tblUserAuditLog.intUserIdFK = tblUsers.intUserId
WHERE 
    tblUsers.strUserName = 'a12jun'
    AND tblUserAuditLog.dtAuditTimeStamp >= '2012-08-10'

このクエリは、開発環境で数千行を返す可能性があり、ライブではかなり多くの行を返します。

実際に結果を返す前に、動的クエリが返す行数を確認したいので、その数が制限を超えている場合は、「クエリを絞り込む」エラーメッセージを返すことができます。

私は次のようなSQLの別の部分を生成しようとしました：

DECLARE @sqlrowcount NVARCHAR(MAX);
SET @sqlrowcount = 'SELECT COUNT(*) FROM (' + @sql + ') AS TEMP';
EXEC(@sqlrowcount);

IF @@ROWCOUNT > @limit BEGIN .... END

@sql動的クエリはどこにありますか。次に、レコード数を値とする1つのレコードを返すため、EXEC(@sqlrowcount)常にが返されることに恥ずかしいことに気づきました。1

たとえば、結果を一時テーブルに書き込まずに、これを行う（比較的）エレガントな方法はありますか？

4

3 に答える 3

6

一方通行;

--base sql
declare @sql  nvarchar(255) = N'select * from master.dbo.spt_values'

--count wrapper
declare @sqlb nvarchar(255) = N'set @count=(select count(*) from (' + @sql + ') T)'

declare @count int
exec sp_executesql @sqlb, N'@count int output', @count output

select 'rows=',@count

制限を適用するために使用することもできますTOP。同じステートメントを2回実行することは、あまり効率的ではありません。

于 2012-08-30T16:14:44.680 に答える
2

発生している問題は、execステートメントが前の@@ rowcount値を保持することです。この場合、setステートメントから1になります（すべてのsetステートメントによって@@ rowcountが1になります）。executeは独自のバッチを作成するため、これが必要です。

値を取得する最良の方法は、出力パラメーターでsp_executesqlを使用することです。これは次のようになります。

declare @numRows int
declare @sql nvarchar(max)
set @sql = N'Select @numRows= count(*) from dbo.temp'

exec sp_executesql @sql, N'@numRows int output', @numRows output

--Put your if statement here using @numRows

これは、カウントから値を返すための出力パラメーターを持つsp_executesqlの機能を使用します。

私がすべての深刻なSQLプログラムに推奨する一般的な動的クエリの詳細についての1つの良い情報源は、sp_executesqlをパラメーター化する方法と、他のいくつかの関連トピックと一緒にしたいと思う理由を説明する動的SQLの呪いと祝福です。

于 2012-08-30T16:40:46.500 に答える
0 
Declare @Rowcount int
SELECT @RowCount = count(1) 
FROM         
dbo.tblUserAuditLog 
    LEFT OUTER JOIN dbo.tblUsers 
    ON dbo.tblUserAuditLog.intUserIdFK = dbo.tblUsers.intUserId


SELECT tblUsers.strUserName AS [Username]
    ,tblUsers.strEmail AS [Email]
    ,tblUserAuditLog.strIpAddress AS [IP Address]
    ,tblUserAuditLog.dtAuditTimeStamp AS [Timestamp]
    ,tblUserAuditLog.strAuditLogAction AS [Action]
    ,tblUserAuditLog.strLogDetails AS [Details]
    , @RowCount
FROM         
dbo.tblUserAuditLog 
    LEFT OUTER JOIN dbo.tblUsers 
    ON dbo.tblUserAuditLog.intUserIdFK = dbo.tblUsers.intUserId
于 2012-08-30T18:01:57.537 に答える