1

次の XML の例をどのように進めるのが最善なのか、少し行き詰まっています。

<Story>
<Content para="div"><local>This is some (normal) text to start with.</local></Content>
<Content para="div"><local>Connect something (</local></Content>
<Content para="div"><local><refnr value="58236"/></local></Content>
<Content para="div"><local>) to something else (</local></Content>
<Content para="div"><local><refnr value="58237"/></local></Content>
<Content para="div"><local>), and make sure it's connected to this (</local></Content>
<Content para="div"><local><refnr value="58239"/></local></Content>
<Content para="div"><local>).</local></Content>
<Content para="div"><local>If that's ok do the same with this (</local></Content>
<Content para="div"><local><refnr value="58238"/></local></Content>
<Content para="div"><local>) also.</local></Content>
<Content para="div"><local>This is some normal text.</local></Content>
<Content para="div"><local>This also.</local></Content>
</Story>

取得したい出力は次のとおりです。

<Story>
<Content para="div"><local>This is some (normal) text to start with.</local></Content>
<Content para="div"><local>Connect something (<refnr value="58236"/>) to something else (<refnr value="58237"/>), and make sure it's connected to this (<refnr value="58239"/>).</local></Content>
<Content para="div"><local>If that's ok do the same with this (<refnr value="58238"/>) also.</local></Content>
<Content para="div"><local>This is some normal text.</local></Content>
<Content para="div"><local>This also.</local></Content>
</Story>

または、それを「コード化」するには: 開き括弧で終わる [Content para=div][local] ノードは、最後の閉じ括弧を含むノードまで、次の [Content para=div][local] ノードとマージする必要があります。および文の終わり (終了ドットで識別)。私はいくつかのことを行うことができましたが、それは過度に複雑で遅くなり、必要な結果が得られませんでした. xslt2 を使用したアドバイスはありますか?

4

2 に答える 2

1

この XSLT 2.0 変換(XSLT 1.0 に簡単に変換できます):

<xsl:stylesheet version="2.0" xmlns:xsl="http://www.w3.org/1999/XSL/Transform">
 <xsl:output omit-xml-declaration="yes" indent="yes"/>

 <xsl:template match="/*">
  <Story>
   <xsl:apply-templates select="Content[1]/local"/>
  </Story>
 </xsl:template>

 <xsl:template match="Content/local[not(ends-with(., '('))]">
  <Content para="div"><local><xsl:apply-templates/></local></Content>
  <xsl:apply-templates select="../following-sibling::Content[1]"/>
 </xsl:template>

 <xsl:template match="Content/local[ends-with(., '(')]">
  <Content para="div"><local><xsl:apply-templates/>
   <xsl:apply-templates mode="inGroup" select="../following-sibling::Content[1]"/>
  </local></Content>

  <xsl:apply-templates select=
   "../following-sibling::Content
             [local[starts-with(.,')') and ends-with(.,'.')]][1]
               /following-sibling::Content[1]"/>
 </xsl:template>

 <xsl:template match="Content/local" mode="inGroup">
    <xsl:apply-templates/>
    <xsl:apply-templates mode="#current"
         select="../following-sibling::Content[1]"/>
 </xsl:template>

 <xsl:template mode="inGroup" match="Content/local[starts-with(.,')') and ends-with(.,'.')]">
  <xsl:apply-templates/>
 </xsl:template>

 <xsl:template match="refnr"><xsl:copy-of select="."/></xsl:template>
</xsl:stylesheet>

提供された XML ドキュメントに適用した場合:

<Story>
 <Content para="div"><local>This is some (normal) text to start with.</local></Content>
 <Content para="div"><local>Connect something (</local></Content>
 <Content para="div"><local><refnr value="58236"/></local></Content>
 <Content para="div"><local>) to something else (</local></Content>
 <Content para="div"><local><refnr value="58237"/></local></Content>
 <Content para="div"><local>), and make sure it's connected to this (</local></Content>
 <Content para="div"><local><refnr value="58239"/></local></Content>
 <Content para="div"><local>).</local></Content>
 <Content para="div"><local>If that's ok do the same with this (</local></Content>
 <Content para="div"><local><refnr value="58238"/></local></Content>
 <Content para="div"><local>) also.</local></Content>
 <Content para="div"><local>This is some normal text.</local></Content>
 <Content para="div"><local>This also.</local></Content>
</Story>

必要な正しい結果が生成されます。

<Story>
   <Content para="div">
      <local>This is some (normal) text to start with.</local>
   </Content>
   <Content para="div">
      <local>Connect something (<refnr value="58236"/>) to something else (<refnr value="58237"/>), and make sure it's connected to this (<refnr value="58239"/>).</local>
   </Content>
   <Content para="div">
      <local>If that's ok do the same with this (<refnr value="58238"/>) also.</local>
   </Content>
   <Content para="div">
      <local>This is some normal text.</local>
   </Content>
   <Content para="div">
      <local>This also.</local>
   </Content>
</Story
于 2012-09-01T21:46:51.037 に答える
1

2 つのアプローチをネストする必要があると思います。

<xsl:stylesheet
  xmlns:xsl="http://www.w3.org/1999/XSL/Transform"
  version="2.0">

<xsl:output indent="yes"/>

<xsl:template match="Story">
  <xsl:copy>
    <xsl:for-each-group select="Content" group-adjacent="contains(., '(') or contains(., ')') or boolean(self::Content[local[refnr]])">
      <xsl:choose>
        <xsl:when test="current-grouping-key()">
          <xsl:for-each-group select="current-group()" group-ending-with="Content[local[ends-with(., '.')]]">
            <Content para="div">
              <local>
                <xsl:copy-of select="current-group()/local/node()"/>
              </local>
            </Content>
          </xsl:for-each-group>
        </xsl:when>
        <xsl:otherwise>
          <xsl:copy-of select="current-group()"/>
        </xsl:otherwise>
      </xsl:choose>
    </xsl:for-each-group>
  </xsl:copy>
</xsl:template>

</xsl:stylesheet>

そのスタイルシートとサンプル入力を使用して、投稿した結果を取得します。refnrただし、使用した条件が実際の入力に対して単純すぎるかどうかはわかりません。たとえば、要素を含む「通常の」テキストがあるかどうかを報告してください。

[編集] matchesas in

<xsl:stylesheet
  xmlns:xsl="http://www.w3.org/1999/XSL/Transform"
  version="2.0">

<xsl:output indent="yes"/>

<xsl:template match="Story">
  <xsl:copy>
    <xsl:for-each-group select="Content" 
      group-adjacent="not(matches(., '\(.*\)')) 
                       or boolean(self::Content[local[refnr]])">
      <xsl:choose>
        <xsl:when test="current-grouping-key()">
          <xsl:for-each-group select="current-group()" group-ending-with="Content[local[ends-with(., '.')]]">
            <Content para="div">
              <local>
                <xsl:copy-of select="current-group()/local/node()"/>
              </local>
            </Content>
          </xsl:for-each-group>
        </xsl:when>
        <xsl:otherwise>
          <xsl:copy-of select="current-group()"/>
        </xsl:otherwise>
      </xsl:choose>
    </xsl:for-each-group>
  </xsl:copy>
</xsl:template>

</xsl:stylesheet>

編集された入力サンプルは、必要に応じて変換されていると思います。もちろん、たとえば<Content para="div"><local>Connect (foo) something (</local></Content>、そのアプローチも単純すぎます。

于 2012-09-01T17:21:03.610 に答える