0

xslt 2.0を使用して、あるxml形式を別のxml形式に変換したい。次に、コンテキストノードの次の直後の:: node（）要素を取得したい。たとえば、

これは私のxmlドキュメントです： 

<?xml version="1.0" encoding="UTF-8" standalone="yes"?>
        <w:document xmlns:w="http://schemas.openxmlformats.org/wordprocessingml/2006/main"
                    xmlns:v="urn:schemas-microsoft-com:vml">
        <w:body>
      <w:p>para1</w:p>   <!-- assume this as context node  -->
      <w:tbl>table data 1</w:tbl>
      <w:tbl>table data 2</w:tbl>
      <w:p>para2</w:p>
      <w:tbl>table data 3</w:tbl>
      <w:tbl>table data 4</w:tbl>
      <w:tbl>table data 5</w:tbl>
      <w:tbl>table data 6</w:tbl>
      <w:p>para3</w:p>
   </w:body>
  </w:document>

したがって、上記のxmlファイルに記載されているコンテキストノードに従って、テーブルデータ1とテーブルデータ2のみを選択します。

たとえば、コンテキストノードがpara2の場合、テーブルデータ3、テーブルデータ4、テーブルデータ5、およびテーブルデータ6のみを選択します。

だから、私はこのようにxsltを書いた、

<xsl:for-each select="following::node()/self::w:tbl">
     <xsl:choose>
         <xsl:when test="self::w:tbl">
             <xsl:apply-templates select="self::w:tbl"></xsl:apply-templates>
          </xsl:when>                                             
     </xsl:choose>                                         
</xsl:for-each>

しかし、それは間違った結果を生み出しました...

この問題から抜け出すために私を導いてください...

4

3 に答える 3

1

便利な関数は次のとおりです。

<xsl:function name="f:adjacently-following" as="element()*">
  <xsl:param name="start" as="element()"/>
  <xsl:param name="elementName" as="xs:QName"/>
  <xsl:variable name="next" select="$start/following-sibling::*[1]"/>
  <xsl:if test="node-name($next) = $elementName">
      <xsl:sequence select="$next, f:adjacently-following($next, $elementName)"/>
  </xsl:if>
</xsl:function>

その後、あなたは呼び出すことができますf:adjacently-following(., xs:QName('w:tbl'))

于 2012-09-04T08:01:27.477 に答える
1

w:p要素に配置されていると仮定すると、最初の最も前のw:pが現在の要素である次のすべてのw:tbl兄弟を取得できます。

<xsl:apply-templates 
   select="following-sibling::w:tbl
     [generate-id(preceding-sibling::w:p[1]) = generate-id(current())]" />

これは、 xsl:keyを使用して少し整理できます。次のキーを定義するとします。

<xsl:key name="tbl" match="w:tbl" use="generate-id(preceding-sibling::w:p[1])" />

次に、次のようなw:tbl要素を取得できます。

<xsl:apply-templates select="key('tbl', generate-id())" />

たとえば、次の XSLT があるとします。

<xsl:stylesheet version="1.0" xmlns:xsl="http://www.w3.org/1999/XSL/Transform"
   xmlns:w="http://schemas.openxmlformats.org/wordprocessingml/2006/main" 
   xmlns:v="urn:schemas-microsoft-com:vml" exclude-result-prefixes="w v">
   <xsl:output method="xml" indent="yes"/>

   <xsl:key name="tbl" match="w:tbl" use="generate-id(preceding-sibling::w:p[1])" />

   <xsl:template match="w:body">
      <xsl:apply-templates select="w:p[1]" />
   </xsl:template>

   <xsl:template match="w:p">
      <xsl:apply-templates select="key('tbl', generate-id())" />
   </xsl:template>   

   <xsl:template match="w:tbl">
      <table><xsl:value-of select="." /></table>
   </xsl:template>
</xsl:stylesheet>

サンプル XML に適用すると、次のように出力されます。

<table>table data 1</table>
<table>table data 2</table>

これは XSLT1.0 ソリューションであることに注意してください。XSLT2.0 でのみ機能する他の方法があるかもしれません。

于 2012-09-04T06:30:05.947 に答える
1

この XSLT 2.0 スタイルシート...

<xsl:stylesheet version="2.0"
  xmlns:xsl="http://www.w3.org/1999/XSL/Transform"
  xmlns:w="http://schemas.openxmlformats.org/wordprocessingml/2006/main"
  xmlns:v="urn:schemas-microsoft-com:vml"
  exclude-result-prefixes="xsl w v">
<xsl:output method="xml" indent="yes"/>
<xsl:strip-space elements="*"/>

<xsl:template match="/">
 <root>
   <xsl:for-each-group select="w:document/w:body/(w:p|w:tbl)" group-starting-with="w:p" >
    <p>
      <xsl:apply-templates select="current-group()" />
    </p>
   </xsl:for-each-group>
 </root>
</xsl:template>

<xsl:template match="w:tbl">
  <table>
    <xsl:value-of select="." />
  </table>
</xsl:template>

</xsl:stylesheet>

...この入力ドキュメントに適用すると...

<w:document xmlns:w="http://schemas.openxmlformats.org/wordprocessingml/2006/main" xmlns:v="urn:schemas-microsoft-com:vml">
    <w:body>
        <w:p>para1</w:p>
        <!-- assume this as context node -->
        <w:tbl>table data 1</w:tbl>
        <w:tbl>table data 2</w:tbl>
        <w:p>para2</w:p>
        <w:tbl>table data 3</w:tbl>
        <w:tbl>table data 4</w:tbl>
        <w:tbl>table data 5</w:tbl>
        <w:tbl>table data 6</w:tbl>
        <w:p>para3</w:p>
    </w:body>
</w:document>

...収量...

<root>
   <p>para1<table>table data 1</table>
      <table>table data 2</table>
   </p>
   <p>para2<table>table data 3</table>
      <table>table data 4</table>
      <table>table data 5</table>
      <table>table data 6</table>
   </p>
   <p>para3</p>
</root>
于 2012-09-04T08:23:37.443 に答える