1

私が読んだすべてのドキュメントによると、ActiveDirectoryにクエリを実行するときの結果セットの最大サイズは1000レコードです。1000を超える必要がある場合は、ページをめくって1000を超えるレコードを取得するために、Net :: LDAP :: Control::Pagedを使用するように指示されます。何らかの理由で、ページコントロールを使用しているにもかかわらず、まだ1000レコードしか返されていません。私は他の人が運がなくてもうまく使っていると主張しているのと同じコードを使っています。ここで何かが足りませんか？ADサーバーへの管理アクセス権がないため、構成を変更することはできません。以下に関連するコードを貼り付けたので、私が間違ったことを指摘できます。

#!perl -w

use strict;
use Net::LDAP;
use Net::LDAP::Control::Paged;
use Net::LDAP::Constant qw( LDAP_CONTROL_PAGED );

my $LDAPServer      = "<LDAP SERVER ADDRESS>";
my $base        = "<BASE DN>";
my $user                = "<LDAP USER>";
my $pass                = "<PASSWORD>";
my $page                = Net::LDAP::Control::Paged->new(size => 1000) or die $!;
my $errorConnectionStr  = "";
my $ldap;
my $mesg;
my $cookie;

$ldap = Net::LDAP->new($LDAPServer);
$mesg = $ldap->bind($user, password => $pass, version => 3);

open(OUT,">users.csv");
print OUT "sAMAccountName,sn,givenName\n";

my $filter = "(&(objectClass=person)(!(userAccountControl:1.2.840.113556.1.4.803:=2))(!(objectClass=computer)))";
my @attribs = ("sn", "givenName", "sAMAccountName", "distinguishedName");

my @args = (
        base    => $base,
        scope   => 'sub',
        filter  => $filter,
        attrs   => @attribs,
        pagesize => 1000,
        control => [$page]
);

while(1) {
    $mesg = $ldap->search(@args) or die $!;

    while (my $entry = $mesg->pop_entry()) {
        my $print = 1;

        my $dn = $entry->dn();
        my $uid = $entry->get_value('sAMAccountName');
        my $ln = $entry->get_value('sn');
        my $fn = $entry->get_value('givenName');

        if($dn =~ m/.*Resources.*/) {
            $print = 0;
        }

        if(defined($uid) && defined($ln) && defined($fn)) {
            if($print == 1) {
                print OUT "$uid,$ln,$fn\n";
            }
        }
    }

    my ($resp) = $mesg->control(LDAP_CONTROL_PAGED) or last;
    $cookie = $resp->cookie or last;
    $page->cookie($cookie);
}

if($cookie) {
    print "Abnormal exit\n";
    $page->cookie($cookie);
    $page->size(0);
    $ldap->search(@args);
}

close(OUT);
$ldap->unbind;
4

3 に答える 3

1

が必要attrs => \@attrs,です@args。バックスラッシュがないと、奇数の要素 ('attrs'および配列の 4 つの要素) が補間され、検索メソッドはpagesize引数を認識しません。

于 2014-04-29T12:11:29.820 に答える
0

初めて使用しましたが、ここで動作します。私の検索は非常に単純です (コンテナー内のすべてのオブジェクトを表示します)。800 グループのページで 11.5k グループをリストしています。私のコードはあなたのものとほとんど同じです (Net::LDAP::Control::Paged の man ページの例とあなたのものを混ぜたものです)、検索でページサイズを指定していないことを除いて:

while (1) {
   my $mesg = $x->{ldap}->search(base => $x->{config}->{gbase},
                                scope => 'sub',
                              control => [$page],
                               filter => 'cn=*',
                                attrs => \@attrs,
   );
   die "LDAP error: server says ",$mesg->error,"\n" if $mesg->code;

   foreach my $entry ( $mesg->entries ) {
      my $cn   = $entry->get_value('cn');
      my $desc = $entry->get_value('description');
      print "$cn - $desc\n";
   }

   # Get cookie from paged control
   my($resp)  = $mesg->control( LDAP_CONTROL_PAGED )  or last;
   $cookie    = $resp->cookie or last;

   # Set cookie in paged control
   $page->cookie($cookie);
}
于 2013-11-22T20:19:33.357 に答える