3

このようなVisualStudio2008のウィンドウマネージャーはありますか？私はそれが本当に好きで、Visual Studio 2005で使用したのはそれだけで、Visual Studio 2008で動作するはずの場所を見ましたが、そうではありません。Visual Studio 2008の多くのインストールで試しましたが、設定を記憶していません。ウィンドウのレイアウトをすばやく簡単に変更できるのが本当に気に入りました。今のところ、設定を手動でインポートおよびエクスポートするだけですが、それは即時のプロセスではありません。

それを機能させるために私は何をしなければなりませんか？

4

4 に答える 4

2

ウィンドウ レイアウトを一覧表示および切り替える機能を提供する私のブログ投稿、Visual Studio でのツール レイアウトの保存と変更を確認できます。

于 2010-09-09T02:22:48.723 に答える
1

CodePlexでRWに連絡する必要があります。彼はそれがVisualStudio2008で機能していると主張しています。このアイテムをチェックしてください。

于 2008-09-24T02:28:49.260 に答える
1

次のマクロは、あなたのためにトリックを行うかもしれません. 上記の WindowManager を実行し、Visual Studio 2008 で動作するように再コンパイルしましたが、それでも少し不安定であることがわかりました。また、私は WindowManager の「Auto Apply Layouts」機能を使用していないため、これらのマクロは、デュアル モニターの作業からラップトップのみの作業に切り替えるのに最適です。

Sub DualMonitorConfiguration_Save()
    SaveWindowConfiguration("Dual Monitor Layout")
End Sub

Sub DualMonitorConfiguration_Load()
    LoadWindowConfiguration("Dual Monitor Layout")
End Sub

Sub LaptopOnlyConfiguration_Save()
    SaveWindowConfiguration("Laptop Only Layout")
End Sub

Sub LaptopOnlyConfiguration_Load()
    LoadWindowConfiguration("Laptop Only Layout")
End Sub

Private Sub SaveWindowConfiguration(ByVal configName As String)
    Dim selectedConfig As WindowConfiguration
    selectedConfig = FindWindowConfiguration(configName)
    If selectedConfig Is Nothing Then
        selectedConfig = DTE.WindowConfigurations.Add(configName)
    End If

    selectedConfig.Update()
    DTE.StatusBar.Text = "Window configuration saved: " & configName
End Sub

Sub LoadWindowConfiguration(ByVal configName As String)
    Dim selectedConfig As WindowConfiguration
    selectedConfig = FindWindowConfiguration(configName)
    If selectedConfig Is Nothing Then
        MsgBox("Window Configuration """ & configName & """ not found.")
    Else
        selectedConfig.Apply()
        DTE.StatusBar.Text = "Window configuration applied: " & configName
    End If
End Sub

Private Function FindWindowConfiguration(ByVal name As String) As WindowConfiguration
    Dim selectedLayout As WindowConfiguration

    For Each config As WindowConfiguration In DTE.WindowConfigurations
        If config.Name = name Then
            Return config
        End If
    Next

    Return Nothing
End Function
于 2008-12-03T17:32:42.407 に答える
1

あなたの質問は、あなたが尋ねたのとまったく同じページで回答されました:-)

記録のために：

これを 2008 で機能させるには、新しい HostApplication 要素を WindowManager2005.AddIn ファイルに追加します。通常、このファイルは "%APPDATA%\Microsoft\MSEnvShared\Addins" にあります。新しい要素のバージョンを 9.0 (VS 2008) に変更すると、2008 と 2005 の両方で動作するはずです。

<HostApplication>
  <Name>Microsoft Visual Studio</Name>
  <Version>9.0</Version>
</HostApplication>
于 2008-12-03T17:39:33.453 に答える