2

私は次のxmlを持っています

<EMPLS>
 <EMPL>
    <NAME>110</NAME>
    <REMARK>R1</REMARK>
  </EMPL>
 <EMPL>
    <NAME>111</NAME>
    <REMARK>R1</REMARK>
    <REMARK>R2</REMARK>
    <REMARK>R3</REMARK>
  </EMPL>
</EMPLS>

また、xml を次の形式に変換する必要があります。

<EMPLS>
 <EMPL>
    <NAME>110</NAME>
    <REMARK>R1</REMARK>
  </EMPL>
 <EMPL>
    <NAME>111</NAME>
    <REMARK>R1 R2 R3</REMARK>
  </EMPL>
</EMPLS>

私は xsl を初めて使用します。これを達成する方法を教えてください。

4

1 に答える 1

0

I この XSLT 1.0 変換:

<xsl:stylesheet version="1.0" xmlns:xsl="http://www.w3.org/1999/XSL/Transform">
 <xsl:output omit-xml-declaration="yes" indent="yes"/>
 <xsl:strip-space elements="*"/>

 <xsl:key name="kChildByName" match="EMPL/*"
  use="concat(generate-id(..), '+', name())"/>

 <xsl:template match="node()|@*">
     <xsl:copy>
       <xsl:apply-templates select="node()|@*"/>
     </xsl:copy>
 </xsl:template>

  <xsl:template match="EMPL/*" priority="0"/>

 <xsl:template match=
 "EMPL/*
     [generate-id()
     =
      generate-id(key('kChildByName',
                       concat(generate-id(..), '+', name())
                      )[1]
                  )
      ]">
  <xsl:copy>
   <xsl:for-each select="key('kChildByName',
                             concat(generate-id(..), '+', name())
                         )">
    <xsl:if test="not(position()=1)"><xsl:text> </xsl:text></xsl:if>
    <xsl:value-of select="."/>
   </xsl:for-each>
  </xsl:copy>
 </xsl:template>
 <xsl:template match="EMPL/*" priority="0"/>
</xsl:stylesheet>

提供された XML ドキュメントに適用した場合(多数の不正を修正):

<EMPLS>
 <EMPL>
    <NAME>110</NAME>
    <REMARK>R1</REMARK>
  </EMPL>
 <EMPL>
    <NAME>111</NAME>
    <REMARK>R1</REMARK>
    <REMARK>R2</REMARK>
    <REMARK>R3</REMARK>
  </EMPL>
</EMPLS>

必要な正しい結果が生成されます。

<EMPLS>
   <EMPL>
      <NAME>110</NAME>
      <REMARK>R1</REMARK>
   </EMPL>
   <EMPL>
      <NAME>111</NAME>
      <REMARK>R1 R2 R3</REMARK>
   </EMPL>
</EMPLS>

説明:

  1. アイデンティティ ルールの適切な使用とオーバーライド。

  2. Muenchian Grouping メソッドと複合キーの適切な使用。

Ⅱ．XSLT 2.0 ソリューション:

<xsl:stylesheet version="2.0"   xmlns:xsl="http://www.w3.org/1999/XSL/Transform">
    <xsl:output omit-xml-declaration="yes" indent="yes"/>

 <xsl:template match="node()|@*">
     <xsl:copy>
       <xsl:apply-templates select="node()|@*"/>
     </xsl:copy>
 </xsl:template>

 <xsl:template match="EMPL">
  <xsl:copy>
    <xsl:for-each-group select="*" group-by="name()">
     <xsl:copy>
       <xsl:value-of select="current-group()" separator=" "/>
     </xsl:copy>
    </xsl:for-each-group>
  </xsl:copy>
 </xsl:template>
</xsl:stylesheet>

説明:

  1. の適切な使用<xsl:for-each-group>。

  2. 機能の適切な使用current-group()。

于 2012-09-07T11:57:16.697 に答える