3

スパース多項式を (係数、ペア) のリストとして表しています。例えば：

'((1 2) (3 6) (-20 48)) => x^2 + 3x^6 - 20x^48

私は Lisp の書式設定は初めてですが、係数の符号をテキストとして取得するなど、かなり気の利いたツールに出くわしまし(format nil "~:[+~;-~]" (> 0 coefficient))た (知っていますが、それはおそらく慣用的ではありません)。

ただし、単一の用語をフォーマットする場合、特定の表示上の問題があります。たとえば、次のすべてが true である必要があります。

(1 0) => 1x^0 => 1    (reducible)
(1 1) => 1x^1 => x    (reducible)
(1 2) => 1x^2 => x^2  (reducible)
(2 0) => 2x^0 => 2    (reducible)
(2 1) => 2x^1 => 2x   (reducable)
(2 2) => 2x^2 => 2x^2 (this one is okay)

if大規模な一連のマクロを使用せずにこれを行う方法があるかどうか疑問に思っていcondます-単一のformatパターンでこれを行う方法. すべてが機能しますが、用語を「整形」します（最後の行でFormatPolynomialHelper3これを行う必要があります）。

(defun FormatPolynomial (p)
    "Readably formats the polynomial p."
    ; The result of FormatPolynomialHelper1 is a list of the form (sign formatted),
    ; where 'sign' is the sign of the first term and 'formatted' is the rest of the
    ; formatted polynomial. We make this a special case so that we can print a sign
    ; attached to the first term if it is negative, and leave it out otherwise. So,
    ; we format the first term to be either '-7x^20' or '7x^20', rather than having
    ; the minus or plus sign separated by a space.
    (destructuring-bind (sign formatted-poly) (FormatPolynomialHelper1 p)
        (cond
            ((string= formatted-poly "") (format nil "0"))
            (t                           (format nil "~:[~;-~]~a" (string= sign "-") formatted-poly)))))

; Helpers

(defun FormatPolynomialHelper1 (p)
    (reduce #'FormatPolynomialHelper2 (mapcar #'FormatPolynomialHelper3 p) :initial-value '("" "")))

(defun FormatPolynomialHelper2 (t1 t2)
    ; Reduces ((sign-a term-a) (sign-b term-b)) => (sign-b "term-b sign-a term-a"). As
    ; noted, this accumulates the formatted term in the variable t2, beginning with an
    ; initial value of "", and stores the sign of the leading term in the variable t1.
    ; The sign of the leading term is placed directly before the accumulated formatted
    ; term, ensuring that the signs are placed correctly before their coefficient. The
    ; sign of the the leading term of the polynomial (the last term that is processed)
    ; is available to the caller for special-case formatting.
    (list
        (first t2)
        (format nil "~@{~a ~}" (second t2) (first t1) (second t1))))

(defun FormatPolynomialHelper3 (tm)
    ; Properly formats a term in the form "ax^b", excluding parts of the form if they
    ; evaluate to one. For example, 1x^3 => x^3, 2x^1 => 2x, and 3x^0 => 3). The list
    ; is in the form (sign formatted), denoting the sign of the term, and the form of
    ; the term state above (the coefficient have forced absolute value).
    (list
        (format nil "~:[+~;-~]" (> 0 (first tm)))
        (format nil "~a~@[x^~a~]" (abs (first tm)) (second tm))))

編集: 出力にロジックを含めてはならないことが正しく述べられています。おそらく、私の問題に対してあまりにも具体的な質問をしていたのでしょう。多項式を正しくフォーマットするロジックは次のとおりです。しかし、私はよりクリーンで、より読みやすく、より Lisp の慣用的なものを探しています (Lisp を書いてまだ 3 日目です)。

(defun FormatPolynomialHelper3 (tm)
    ; Properly formats a term in the form "ax^b", excluding parts of the form if they
    ; evaluate to one. For example, 1x^3 => x^3, 2x^1 => 2x, and 3x^0 => 3). The list
    ; is in the form (sign formatted), denoting the sign of the term, and the form of
    ; the term state above (the coefficient have forced absolute value).
    (list
        (format nil "~:[+~;-~]"   (> 0 (first tm)))
        (cond
            ((= 0 (second tm))      (format nil "~a" (abs (first tm))))
            ((= 1 (abs (first tm))) (cond
                ((= 1 (second tm))  (format nil "x"))
                (t                  (format nil "x^~a" (second tm)))))
            ((= 1 (second tm))      (format nil "~ax" (abs (first tm))))
            (t                      (format nil "~ax^~a" (abs (first tm)) (second tm))))))
4

1 に答える 1

5

答え:

FORMAT私はこのロジックをステートメントに入れません。コードを暗号化するか、自分でメンテナンス作業を増やしたい場合のみ。良い Lisp コードは自己文書化されています。FORMATステートメントは決して自己文書化されません。

印刷する前に、まず多項式を単純化します。たとえば、ゼロが掛けられたすべての項を削除します。

((0 10) (1 2)) -> ((1 2))

COND次に、乗数が 1 の場合は、通常のステートメントまたはステートメントでテストできますCASE。

また、自作のデータ構造で 、 、 を使用しないようにしてください。多項式のコンポーネントは、ほとんどの場合、実装の詳細をほとんど隠している自己文書化関数によってアクセスする必要があります。CARCDRFIRSTSECOND

私はそれなしでそれを書きますFORMAT:

コード例:

(defun term-m (term)
  (first term))

(defun term-e (term)
  (second term))

(defun simplify-polynomial (p)
  (remove-if #'zerop (sort p #'> :key #'term-e)
             :key #'term-m))

(defun write-term (m e start-p stream)
  ; sign or operator
  (cond ((and (minusp m) start-p)
         (princ "-" stream))
        ((not start-p)
         (princ (if (plusp m) " + " " - ") stream)))
  ; m
  (cond ((not (= (abs m) 1))
         (princ (abs m) stream)))
  (princ "x" stream)
  ; e
  (cond ((not (= 1 e))
         (princ "^" stream)
         (princ e stream))))

(defun write-polynomial (p &optional (stream *standard-output*))
  (loop for (m e) in (simplify-polynomial p)
        for start-p = t then nil
        do (write-term m e start-p stream)))

使用例：

CL-USER 14 > (write-polynomial '((1 2) (3 6) (-20 48)))
-20x^48 + 3x^6 + x^2
于 2012-09-08T06:38:00.773 に答える