2

私のxmlは次のようになります。

<units>
    <unit>
        <unitnum></unitnum>
        <Year></Year>
        <Qty></Qty>
    </unit>
</units>

可能なすべての年をキャプチャするキーを作成します。このような：

<xsl:key name="yr" match="//Year/text()" use="." />

次に、キーを for-each ループして一意の年を取得します。私の最終的な目標は、次のように数量を合計することです。

<xsl:for-each select="//Year/text()[generate-id()=generate-id(key('yr',.)[1])]">
     <li>
        <xsl:variable name="varjobyear" select="."/>
        <xsl:value-of select="$varjobyear"/> - sum -
        <xsl:value-of select="sum(//unit[Year=$varjobyear]/Qty)"/>
     </li>
</xsl:for-each>

何らかの理由で、私の出力は次のようになります。

2010 - sum - 0
2011 - sum - 0
2012 - sum - 0

しかし、私が望むのは、これらの 0 が各年の数量の実際の合計になることです。

私の推測では、述語 [Year=$varjobyear] に何か問題があると思われますが、それが何であるかはわかりません。[Year=string($varjobyear)] と [Year=number($varjobyear)] も試しました。

私は何を間違っていますか？ありがとう！

4

1 に答える 1

1

あなたはこのようなものが欲しい：

<xsl:stylesheet version="1.0" xmlns:xsl="http://www.w3.org/1999/XSL/Transform">
 <xsl:output omit-xml-declaration="yes" indent="yes"/>
 <xsl:strip-space elements="*"/>

 <xsl:key name="kYearByVal" match="Year" use="."/>

 <xsl:template match="Year[generate-id()=generate-id(key('kYearByVal',.)[1])]">
  <li>
    <xsl:value-of select="concat(., ' - sum - ', sum(key('kYearByVal',.)/../Qty))"/>
  </li>
 </xsl:template>

 <xsl:template match="text()"/>
</xsl:stylesheet>

この変換が次の XML ドキュメントに適用される場合:

<units>
    <unit>
        <unitnum>12</unitnum>
        <Year>1922</Year>
        <Qty>3</Qty>
    </unit>
    <unit>
        <unitnum>13</unitnum>
        <Year>1922</Year>
        <Qty>8</Qty>
    </unit>
    <unit>
        <unitnum>14</unitnum>
        <Year>1999</Year>
        <Qty>5</Qty>
    </unit>
    <unit>
        <unitnum>15</unitnum>
        <Year>1999</Year>
        <Qty>7</Qty>
    </unit>
    <unit>
        <unitnum>16</unitnum>
        <Year>2003</Year>
        <Qty>3</Qty>
    </unit>
</units>

必要な正しい結果が生成されます。

<li>1922 - sum - 11</li>
<li>1999 - sum - 12</li>
<li>2003 - sum - 3</li>
于 2012-09-11T13:10:49.400 に答える