0

次のようなfile1.xmlなど、2つのxmlファイルがあります。

<?xml version="1.0"?>
<root >
    <text id='a'>This is to be replaced</text>
    <note>This should not be touched</note>
    <text id='b'>This is intact</text>
</root>

file2.xmlは次のとおりです。

<?xml version="1.0"?>
<root >
    <text id='a'>Replacement Text</text>
    <note>This is a personal note</note>
</root>

次の形式の出力 xml ファイルが必要です。

output.xml

<?xml version="1.0"?>
<root>
    <text id='a'>Replacement Text</text>
    <note>This should not be touched</note>
    <text id='b'>This is intact</text>
</root>

必要な出力を得るために xsl を手伝ってください。これは宿題ではなく、xslt を理解しようとしています。

4

2 に答える 2

1

この変換：

<xsl:stylesheet version="1.0" xmlns:xsl="http://www.w3.org/1999/XSL/Transform">
 <xsl:output omit-xml-declaration="yes" indent="yes"/>
 <xsl:strip-space elements="*"/>

 <xsl:variable name="vReps" select="document('file:///c:/temp/delete/file2.xml')/*/*[1]"/>

 <xsl:template match="node()|@*">
     <xsl:copy>
       <xsl:apply-templates select="node()|@*"/>
     </xsl:copy>
 </xsl:template>

 <xsl:template match="text[@id='a']/text()">
  <xsl:value-of select="$vReps"/>
 </xsl:template>
</xsl:stylesheet>

このXMLドキュメント（提供されたfile1.xml）に適用した場合：

<root>
    <text id='a'>This is to be replaced</text>
    <note>This should not be touched</note>
    <text id='b'>This is intact</text>
</root>

提供されたfile2.xmlを次の場所に配置しc:\temp\delete\file2.xmlます。

<root>
    <text id='a'>Replacement Text</text>
    <note>This is a personal note</note>
</root>

必要な正しい結果を生成します。

<root>
   <text id="a">Replacement Text</text>
   <note>This should not be touched</note>
   <text id="b">This is intact</text>
</root>

説明：

  1. IDルールの使用とオーバーライド。

  2. 標準のXSLT関数の使用document()。

于 2012-09-13T13:10:07.967 に答える
1

XSLT プロセッサのバージョンがわからない場合は、この変換を実行して結果を報告してください...

<xsl:stylesheet version = "1.0" 
  xmlns:xsl="http://www.w3.org/1999/XSL/Transform"
  xmlns:msxsl="urn:schemas-microsoft-com:xslt"> 
<xsl:output method = "text" /> 
<xsl:template match = "/" > 
 <xsl:text>Version :  </xsl:text><xsl:value-of select = "system-property('xsl:version')" /><xsl:text >&#x0A;</xsl:text> 
 <xsl:text>Vendor  :  </xsl:text><xsl:value-of select = "system-property('xsl:vendor')" /><xsl:text >&#x0A;</xsl:text> 
 <xsl:text>URL     :  </xsl:text><xsl:value-of select = "system-property('xsl:vendor-url')" /><xsl:text >&#x0A;</xsl:text> 
 <xsl:text>MS ver  :  </xsl:text><xsl:value-of select = "system-property('msxsl:version')" /><xsl:text >&#x0A;</xsl:text> 
 </xsl:template> 
</xsl:stylesheet>

XSLT 1.0 ソリューション

これはテストされていませんが、動作するはずです...

<xsl:stylesheet version="1.0" xmlns:xsl="http://www.w3.org/1999/XSL/Transform">
<xsl:output method="xml" indent="yes" omit-xml-declaration="yes" />
<xsl:strip-space elements="*" />
<xsl:param name="url-of-file2" />
<xsl:variable name="file2" select="document($url-of-file2)" />  

<xsl:template match="@*|node()" name="ident">
 <xsl:copy>
  <xsl:apply-templates select="@*|node()"/>
 </xsl:copy>
</xsl:template>

<xsl:template match="*[@id]">
  <xsl:variable name="ele" select="name()" />
  <xsl:variable name="id" select="@id" />
  <xsl:variable name="replacement-node" select="($file2//*[name()=$ele][@id=$id])[1]" />
  <xsl:choose>
    <xsl:when test="$replacement-node">
     <xsl:copy>
      <xsl:apply-templates select="@*"/>
      <xsl:copy-of select="$replacement-node/text()"/>
      <xsl:apply-templates select="*|comment()|processing-instruction()"/>
     </xsl:copy>
    </xsl:when>
  <xsl:otherwise><xsl:call-template name="ident" /></xsl:otherwise>
  </xsl:choose>
</xsl:template>

</xsl:stylesheet>
于 2012-09-13T07:26:08.983 に答える