4

残念ながら、フィルターは GPU モードでは機能しません (ドロップ シャドウ、グロー)。これらの効果をこのモードでテキストに使用する機会を探しています。どんなアドバイスでも歓迎します。

4

3 に答える 3

6

Astraport が言及しているように、を使用してテキストを更新するたびに、テキスト フィールドを bitmapData に描画する必要がありますbitmapData.draw()。

を使用textField.getBoundsして必要な bitmapData のサイズを決定すると、結果として得られる境界の四角形には、フィルターによる余分なサイズが含まれません (たとえば、DropShadowFilter は、「距離」と「ぼかし」に応じて、特定のピクセルだけテキスト ボックスの側面を突き出します。 ')。ビットマップを描画するときにフィルターを確実に含めるには、 を使用bitmapData.generateFilterRect()して正しいサイズの四角形を取得する必要もあります。

コード スニペット (テストされていませんが、一般的な考え方):

// Remember the transform matrix of the text field
var offset : Matrix = myTextField.transform.matrix.clone();
// Get the bounds of just the textfield (does not include filters)
var tfBounds : Rectangle = myTextField.getBounds( myTextField.parent );     
// Create a bitmapData that is used just to calculate the size of the filters
var tempBD : BitmpaData = new BitmapData( Math.ceil(tfBounds.width), Math.ceil(tfBounds.height) );
// Make a copy of the textField bounds. We'll adjust this with the filters
var finalBounds : rectangle = tfBounds.clone();
// Step through each filter in the textField and adjust our bounds to include them all
var filterBounds : rectangle;
for each (var filter : BitmapFilter in myTextField.filters) {
    filterBounds = tempBD.generateFilterRect( tfBounds, filter );
    finalBounds.left = Math.min( finalBounds.left, filterBounds.left );
    finalBounds.right = Math.max( finalBounds.right, filterBounds.right );
    finalBounds.top = Math.min( finalBounds.top, filterBounds.top );
    finalBounds.bottom = Math.max( finalBounds.bottom, filterBounds.bottom );
}

// Now draw the textfield to a new bitmpaData
var textFieldBD : BitmpaData = new BitmapData( Math.ceil(finalBounds.width), math.ceil(finalBounds.height) );
offset.tx = -finalBounds.x;
offset.ty = -finalBounds.y;
textFieldBD.draw( myTextField.parent, offset, myTextField.transform.colorTransform );

// Create a bitmap and add the bitmap data. Note: normally you would create a
// bitmap once and just update the bitmpaData
var bitmap : Bitmap = new Bitmap();
myTextField.parent.addChild( bitmap );

// Position the bitmap in same place as textField
bitmap.bitmapData = textFieldBD;
bitmap.x = myTextField.x - finalBounds.x;
bitmap.y = myTextField.y - finalBounds.y;
myTextField.visible = false;
于 2013-05-29T09:58:40.903 に答える
2

ANYDisplayObjectをBitmap- に変換する方法は次のとおりです。AIR GPU モバイルでフィルター効果を「復元」するのに役立ちrendermodeます。これはPixelthis、修正、最適化、およびテストされた のソリューションです。

    // => 'bitmap' must belong to the same parent as 'obj'. 'obj' should be invisible.
    static public function Update(obj:DisplayObject, bitmap:Bitmap):void {
        //trace("CacheToBmp",obj.name);

        // Remember the transform matrix of the text field
        var offset:Matrix = obj.transform.matrix.clone();
        // Get the bounds of just the textfield (does not include filters)
        var bounds:Rectangle = obj.getBounds(obj);
        // Create a bitmapData that is used just to calculate the size of the filters
        var tempBD:BitmapData = new BitmapData( Math.ceil(bounds.width), Math.ceil(bounds.height), false );
        bounds.width = obj.width;
        bounds.height = obj.height;
        // Make a copy of the textField bounds. We'll adjust this with the filters
        var finalBounds:Rectangle = new Rectangle(0,0,bounds.width,bounds.height);

        // Step through each filter in the textField and adjust our bounds to include them all
        var filterBounds:Rectangle;
        for each (var filter:BitmapFilter in obj.filters) {
            filterBounds = tempBD.generateFilterRect( tempBD.rect, filter );
            finalBounds = finalBounds.union(filterBounds);
        }
        finalBounds.offset(bounds.x,bounds.y);
        finalBounds.x = Math.floor(finalBounds.x);
        finalBounds.y = Math.floor(finalBounds.y);
        finalBounds.width = Math.ceil(finalBounds.width);
        finalBounds.height = Math.ceil(finalBounds.height);

        // Now draw the textfield to a new bitmpaData
        var data:BitmapData = new BitmapData( finalBounds.width, finalBounds.height, false, 0 );
        offset.tx = -finalBounds.x;
        offset.ty = -finalBounds.y;
        data.drawWithQuality( obj, offset, obj.transform.colorTransform, obj.blendMode, null, true, StageQuality.HIGH );
        bitmap.bitmapData = data;

        // Position the bitmap in same place as 'obj'
        bitmap.x = obj.transform.matrix.tx + finalBounds.x;
        bitmap.y = obj.transform.matrix.ty + finalBounds.y;
    }
于 2013-12-12T15:21:41.847 に答える
0

基本的な考え方は、フィルターを通常どおり適用してから、表示オブジェクトをビットマップデータに描画し、ビットマップをステージに追加することです。例については、 http://forums.adobe.com/message/3934192を参照してください。

これを適用するテキストが静的な場合は簡単に実行できるはずですが、この動的なテキストを適用する場合 (たとえば、頻繁に変更されるスコア カウンターや、ユーザーが編集可能なテキスト) を想像します。面倒になり始めるかもしれませんが、他の解決策は知りません。

于 2012-09-13T13:55:35.130 に答える