15

テーブル列の行タイプのタイプによって作成された連想配列があります。

例を挙げると、次のようになります (テーブル名は異なりますが、構造は同じです)。

これはテーブルの DDL です

CREATE TABLE employees
  (
     id     NUMBER,
     name   VARCHAR2(240),
     salary NUMBER
  );

私の手順は次のとおりです。

DECLARE
    TYPE table_of_emp
      IS TABLE OF employees%ROWTYPE INDEX BY BINARY_INTEGER;
    emp TABLE_OF_EMP;
BEGIN
    IF emp IS NULL THEN
      dbms_output.Put_line('Null associative array');
    ELSE
      dbms_output.Put_line('Not null');
    END IF;
END;

これにより、「Null連想配列」が出力されるはずです。ただし、if条件は失敗し、実行は else 部分にジャンプします。

ここでfor、コレクションの値を出力するためにループを挿入すると

DECLARE
    TYPE table_of_emp
      IS TABLE OF employees%ROWTYPE INDEX BY BINARY_INTEGER;
    emp TABLE_OF_EMP;
BEGIN
    IF emp IS NULL THEN
      dbms_output.Put_line('Null associative array');
    ELSE
      dbms_output.Put_line('Not null');

      FOR i IN emp.first..emp.last LOOP
          dbms_output.Put_line('Emp name: '
                               || Emp(i).name);
      END LOOP;
    END IF;
END;

次に、プログラムユニットは for ループ行を参照して例外を発生させます

ORA-06502: PL/SQL: 数値または値のエラーです

これは、null 連想配列が原因であると推測されます。null連想配列が原因でエラーが発生していますか?

では、なぜ最初のチェックが失敗するのでしょうか? 私は何を間違っていますか？

データベース サーバーは Oracle 11g EE (バージョン 11.2.0.3.0 64 ビット) です。

4

2 に答える 2

14

これにより、「Null連想配列」が出力されるはずです。連想配列の場合、その仮定は間違っています。宣言時には存在しますが、空です。他のタイプの PL/SQL コレクションの場合は正しいでしょう。

初期化するまで、NESTED TABLEまたはVARRAYはアトミック NULL です。コレクション自体は null であり、その要素ではありません。ネストした表またはVARRAYを初期化するには、コレクション型と同じ名前のシステム定義関数であるコンストラクタを使用します。この関数は、渡された要素からコレクションを構築します。

varray およびネストされたテーブル変数ごとにコンストラクタを明示的に呼び出す必要があります。3 番目の種類のコレクションである連想配列は、コンストラクターを使用しません。コンストラクターの呼び出しは、関数呼び出しが許可されている場所であればどこでも許可されます。コレクションの初期化と参照

比較：

SQL> declare
  2      type varchar2_100_aa is table of varchar2(100) index by binary_integer;
  3      test varchar2_100_aa;
  4  begin
  5      test(1) := 'Hello';
  6      dbms_output.put_line(test(1));
  7  end;
  8  /
Hello

PL/SQL procedure successfully completed.

SQL> declare
  2      type varchar2_100_va is varray(100) of varchar2(100);
  3      test varchar2_100_va;
  4  begin
  5      test(1) := 'Hello';
  6      dbms_output.put_line(test(1));
  7  end;
  8  /
declare
*
ERROR at line 1:
ORA-06531: Reference to uninitialized collection
ORA-06512: at line 5

正しく行われた変数配列:

SQL> declare
  2      type varchar2_100_va is varray(10) of varchar2(100);
  3      test varchar2_100_va;
  4  begin
  5      test := varchar2_100_va(); -- not needed on associative array
  6      test.extend; -- not needed on associative array
  7      test(1) := 'Hello';
  8      dbms_output.put_line(test(1));
  9  end;
 10  /
Hello

PL/SQL procedure successfully completed.

連想配列は空firstでlastnullであるため、2番目の例の結果は次のようになりますORA-06502: PL/SQL: Numeric or value error。

SQL> declare
  2      type varchar2_100_aa is table of varchar2(100) index by binary_integer;
  3      test varchar2_100_aa;
  4  begin
  5      dbms_output.put_line(test.count);
  6      dbms_output.put_line(coalesce(to_char(test.first), 'NULL'));
  7      dbms_output.put_line(coalesce(to_char(test.last), 'NULL'));
  8      test(1) := 'Hello';
  9      dbms_output.new_line;
 10      dbms_output.put_line(test.count);
 11      dbms_output.put_line(coalesce(to_char(test.first), 'NULL'));
 12      dbms_output.put_line(coalesce(to_char(test.last), 'NULL'));
 13  end;
 14  /
0
NULL
NULL

1
1
1

PL/SQL procedure successfully completed.

編集また、連想配列はまばらになる可能性があることに注意してください。firstとの間の数値をループすると、lastまばらなコレクションに対して例外が発生します。代わりに and を次のように使用firstしnextます: ( Lastandprevを逆方向にループします。)

SQL> declare
  2      type varchar2_100_aa is table of varchar2(100) index by binary_integer;
  3      test varchar2_100_aa;
  4      i binary_integer;
  5  begin
  6      test(1) := 'Hello';
  7      test(100) := 'Good bye';
  8      dbms_output.put_line(test.count);
  9      dbms_output.put_line(coalesce(to_char(test.first), 'NULL'));
 10      dbms_output.put_line(coalesce(to_char(test.last), 'NULL'));
 11      dbms_output.new_line;
 12  --
 13      i := test.first;
 14      while (i is not null) loop
 15          dbms_output.put_line(to_char(i, '999')  || ' - ' || test(i));
 16          i := test.next(i);
 17      end loop;
 18  end;
 19  /
2
1
100

   1 - Hello
 100 - Good bye

PL/SQL procedure successfully completed.
于 2012-09-13T19:04:21.970 に答える
5

最初のチェックが失敗する理由についてはお答えしません。私はそのようなことを考えたことは一度もありませんでした.エラーが発生しないことに非常に驚いています.

ループで例外が発生する理由は、既に指摘したように、インデックスemp.firstが存在しないためです。

null をチェックするのではなく、このインデックスの存在を実際にチェックする必要があります。.exists(i)構文を使用してできること:

if not emp.exists(emp.first) then
   dbms_output.put_line('Nothing in here.');
end if;
于 2012-09-13T18:02:51.907 に答える