10

これは、何年もの間ではないにしても、何ヶ月も私を悩ませてきたものです. 画像を Outlook メールに貼り付けると、境界線がありません。画像を右クリックしてFormat Pictureを選択すると、これらを追加できます。おそらく、これを行うためのツールもあるでしょう。私の質問は: 貼り付けられたすべての画像に境界線があることを確認する方法はありますか? Outlook 用の CSS スタイル シートがあれば、ここでそれを行うことができます。それともどこかに設定があるのでしょうか？

前もって感謝します！

4

2 に答える 2

7

画像に境界線を追加して中央に配置する Word 2010 マクロがあります。

Sub AddBlueBorderAndCenterImages()
    Dim oIshp As InlineShape
    Dim oshp As Shape

    For Each oIshp In ActiveDocument.InlineShapes 'in line with text
        With oIshp.Borders
            .OutsideLineStyle = wdLineStyleSingle
            .OutsideLineWidth = wdLineWidth025pt
            .OutsideColor = RGB(0, 112, 192)
        End With
        oIshp.Select
        Selection.ParagraphFormat.Alignment = wdAlignParagraphCenter
    Next oIshp

    For Each oshp In ActiveDocument.Shapes 'floating with text wraped around
        With oshp.Line
            .Style = msoLineSingle
            .Weight = 0.25
            .ForeColor.RGB = RGB(0, 112, 192)
        End With
    Next oshp

    Selection.HomeKey Unit:=wdStory 'go back to top of doc
End Sub

私はそれを Outlook に適応させようとしました。主なことは、Outlook アイテムから Word の ActiveDocument にアクセスしようとすることです。

したがって、ここに Outlook バージョンがあります (センタリングなし):

Sub AddBlueBorders()
    Set insp = Application.ActiveInspector
    If insp.CurrentItem.Class = olMail Then
        Set mail = insp.CurrentItem
        If insp.EditorType = olEditorWord Then
            Set wordActiveDocument = mail.GetInspector.WordEditor

            For Each oIshp In wordActiveDocument.InlineShapes 'in line with text
                With oIshp.Borders
                    .OutsideLineStyle = wdLineStyleSingle
                    '.OutsideLineWidth = wdLineWidth025pt ' error: one of the values passed to this method or property is out of range
                    .OutsideColor = RGB(0, 112, 192)
                End With
            Next oIshp

            For Each oshp In wordActiveDocument.Shapes 'floating with text wraped around
                With oshp.Line
                    .Style = msoLineSingle
                    .Weight = 0.25
                    .ForeColor.RGB = RGB(0, 112, 192)
                End With
            Next oshp

        'ElseIf insp.EditorType = olEditorHTML Then
        'Something else here, maybe using css?

        End If
    End If
End Sub

何らかの理由で、署名にある会社のロゴに境界線が追加されません。フッターまたはその他のドキュメント パーツにあるためです。

これはデフォルトではなく、画像がメールに貼り付けられたり追加されたりしても、自動的に画像に境界線を追加するわけではありません。このマクロをボタンまたはキー ショートカットに関連付ける必要があります。しかし、うまくいけば、4か月後でも役に立ちます。

http://en.allexperts.com/q/Microsoft-Word-1058/Word-resize-pictures.htmから漠然としたインスピレーション

于 2013-02-14T14:24:53.633 に答える
1

VBAマクロ（およびそれにキーのショートカット）を提供することを検討できます。これが画像の境界線でどのように機能するかはわかりませんが、電子メールテキストで選択した場合の簡単な例を次に示します。

Sub ChangeSelectedExample()
    Set insp = Application.ActiveInspector
    If insp.CurrentItem.Class = olMail Then
        Set mail = insp.CurrentItem
        If insp.EditorType = olEditorHTML Then
            txt = ActiveInspector.HTMLEditor.Selection.CreateRange.Text
                  ActiveInspector.HTMLEditor.Selection.CreateRange.Text = txt & "<hello world 1>"
        ElseIf insp.EditorType = olEditorWord Then
            txt = insp.CurrentItem.GetInspector.WordEditor.Application.Selection.Text
                  insp.CurrentItem.GetInspector.WordEditor.Application.Selection = txt & "<hello world 2>"
        Else
            MsgBox ("not supported mail format")
        End If
    Else
        MsgBox ("not supported view type")
    End If
End Sub
于 2012-09-23T14:37:09.783 に答える