1

ちらつきの公開写真フィードから読み込んだ写真のサイズを変更しようとしています。写真を取得して子を追加して表示することはできますが、サイズを変更しようとすると、読み込まれず、エラーも発生しません。

コードは次のとおりです。

    public function onClick(e:MouseEvent):void{
        urlloader=new URLLoader();
        var req=new URLRequest("http://api.flickr.com/services/feeds/photos_public.gne" );
        var urlvars:URLVariables=new URLVariables();
        urlvars.format ="rss_200";
        urlvars.tags="cat";
        req.data=urlvars;
        urlloader.addEventListener(Event.COMPLETE, onXMLLoaded);
        urlloader.load(req);
    }
    public function onXMLLoaded(e:Event):void{
        trace(urlloader.data);
        var xml:XML = new XML (urlloader.data);
        urls=[];
        var mediaNS:Namespace=new Namespace("http://search.yahoo.com/mrss/" );
        for(var i:int =0; i<xml.channel.item.length();i++){
            urls.push(xml.channel.item[i].mediaNS::content.@url);
        }
        //trace(xml.channel.item[i].guid.height.mediaNS::content.@url);
        loadPhotos();
        trace(urls.length);
        trace(urls[1]);

    }
    public function loadPhotos():void{
        var ldr:Loader = new Loader();
        var req:URLRequest=new URLRequest(urls[1]);
        ldr.load(req);
        trace("image loaded");
        addChild(ldr);
        ldr.width=200;
        ldr.height=200;


    }
4

1 に答える 1

1

読み込みが完了したら、画像のサイズを変更する必要があります。現時点では、まだ読み込まれていない (幅と高さが 0,0 の) 画像のサイズを変更しようとしています。

Event.COMPLETEこれであなたを助けることができます、サンプル：

var request:URLRequest = new URLRequest("http://www.gravatar.com/avatar/e6420234b202a900e8d57d4e714aa184?s=128&d=identicon&r=PG");
var loader:Loader = new Loader();

loader.load(request);
loader.contentLoaderInfo.addEventListener(Event.COMPLETE, resizeImage);

function resizeImage(e:Event):void
{
    loader.width = 500;
    loader.height = 400;

    addChild(loader);
}
于 2012-09-18T05:14:21.657 に答える