0

日付としてフォーマットされたセルを検索するVBAコーディングを取得しようとしています。すべての日付フォーマットについて、その上の特定のテキストを再度検索し、日付セルがある行にコピーします。

説明のために、以下は私が対処しようとしている私のデータのサンプルです。日付としてフォーマットされている列Cのセルについて、コードで顧客番号（セルC2）と顧客名（D2）を見つけて、該当する行の列AとBにコピーすることを望んでいます。私のデータの顧客の多くが複数のバウチャーを持っているために問題が発生します。そのため、日付のあるセルの2行上になるようにハードコーディングすることはできません。私は理にかなっていると思います！

Customer account Name
1001010 Internal : Sales Admin (9900) 
Date         Voucher
12/7/2011    CINV00000980
1/26/2012    CINV00001011
2/9/2012     CINV00001050
3/6/2012     CINV00002003
3/13/2012    CINV00002067

現在、ネストされたDoループを使用しようとしています（以下を参照）が、明らかに機能していません。コードは実行されていますが、コピー/貼り付けは行われていません。 

Sub ARAging() 
   Dim row As Integer
    row = 2
    finalrow = ActiveSheet.UsedRange.Rows.Count
Do

    If Range(Cells(row, 3), Cells(row, 3)).NumberFormat = "dd/mm/yyyy" Then
        Do
        If Range(Cells(row, 3), Cells(row, 3)).Value = "Customer account" Then
        Range(Cells(row - 1, 3), Cells(row - 1, 4)).Select
            With Selection.Copy
            End With
        End If
        row = row - 1
        Loop Until Range(Cells(row, 3), Cells(row, 3)).Value = "Customer account"

        Range(Cells(row, 1), Cells(row, 2)).Select
            With Selection.Paste
            End With
    End If

row = row + 1

Loop Until row = finalrow
End Sub

どんな助けでもいただければ幸いです！

4

1 に答える 1

2

このコードはあなたが望むことをしていると思います。コードを説明するのに十分なコメントを含めたことを願っています。必要に応じて質問をして戻ってきてください。

' Option Explicit means every variable must be explicitly declared.  Without
' it a misspelt variable name becomes an implicit declaration.  This can be
' a very difficult error to find.
Option Explicit

Sub ARAging()

  ' On a 32-bit system, the native size is what Excel calls Long.  So integer
  ' variables are slower than long variables.

  ' My style is to start a variable name with its type and then add classifiers
  ' to identify its purpose.  This means that when I return to this macro in
  ' six or twelve months, I know what the variables are.  If you do not like my
  ' style, develop your own or develop one with colleagues.  Consistent names
  ' are a godsend during maintenence.
  Dim acctNumCust As String
  Dim rowCrnt As Long
  Dim rowFinal As Long

  With Worksheets("Sheet1")
    ' I avoid ActiveSheet unless I want the user to be able to run the macro
    ' against a worksheet of their choice.

    acctNumCust = ""
    rowFinal = .UsedRange.Rows.Count
    For rowCrnt = 2 To rowFinal

        ' In .Cells(R,C), C can be a number or a column code.
        ' If I am accessing a single cell, I do not need to make it into
        ' a range since .Cells(R,C) is a range.

      If .Cells(rowCrnt, "C").Value = "Customer account" Then

        ' Since I know column C is "Customer account", I do not need to
        ' save it.  Save the value of column 4 in a variable not the
        ' scratchpad.
        acctNumCust = .Cells(rowCrnt, "D").Value

        ' I do not like testing for the formatting.  What if the user changes
        ' it to dd-mmm-yy?

      ElseIf IsDate(.Cells(rowCrnt, "C").Value) Then
        .Cells(rowCrnt, "A").Value = "Customer account"
        .Cells(rowCrnt, "B").Value = acctNumCust

      Else

        Call MsgBox("Cell C" & rowCrnt & " is neither """ & _
                                    "Customer account"" nor a date", vbOKOnly)

      End If

    Next rowCrnt

  End With  ' Worksheets("Sheet1")

End Sub
于 2012-09-20T20:25:45.177 に答える